Add Typing/MacroCallArgumentTypeRestriction

spec/ameba/base_spec.cr

@@ -19,6 +19,7 @@ module Ameba::Rule
           Naming
           Performance
           Style
+          Typing
         ]
       end
     end

spec/ameba/rule/typing/macro_call_argument_type_restriction_spec.cr

@@ -0,0 +1,74 @@
+require "../../../spec_helper"
+
+module Ameba::Rule::Typing
+  describe MacroCallArgumentTypeRestriction do
+    subject = MacroCallArgumentTypeRestriction.new
+
+    it "passes if macro call args have type restrictions" do
+      expect_no_issues subject, <<-CRYSTAL
+        class Greeter
+          getter name : String?
+          class_getter age : Int32 = 0
+          setter tasks : Array(String) = [] of String
+          class_setter queue : Array(Int32)?
+          property task_mutex : Mutex = Mutex.new
+          class_property asdf : String
+
+          record Task,
+            var1 : String,
+            var2 : String = "asdf"
+        end
+        CRYSTAL
+    end
+
+    it "fails if a macro call arg doesn't have a type restriction" do
+      expect_issue subject, <<-CRYSTAL
+        class Greeter
+          getter name
+               # ^^^^ error: Argument should have a type restriction
+        end
+        CRYSTAL
+    end
+
+    it "fails if a record call arg doesn't have a type restriction" do
+      expect_issue subject, <<-CRYSTAL
+        class Greeter
+          record Task,
+            var1 : String,
+            var2 = "asdf"
+          # ^^^^ error: Argument should have a type restriction
+        end
+        CRYSTAL
+    end
+
+    it "fails if a top-level record call arg doesn't have a type restriction" do
+      expect_issue subject, <<-CRYSTAL
+        record Task,
+          var1 : String,
+          var2 = "asdf"
+        # ^^^^ error: Argument should have a type restriction
+        CRYSTAL
+    end
+
+    context "#default_value" do
+      rule = MacroCallArgumentTypeRestriction.new
+      rule.default_value = false
+
+      it "passes if a macro call arg with a default value doesn't have a type restriction" do
+        expect_no_issues rule, <<-CRYSTAL
+          class Greeter
+            getter name = "Kenobi"
+          end
+          CRYSTAL
+      end
+
+      it "passes if a top-level record call arg with default value doesn't have a type restriction" do
+        expect_no_issues rule, <<-CRYSTAL
+          record Task,
+            var1 : String,
+            var2 = "asdf"
+          CRYSTAL
+      end
+    end
+  end
+end

src/ameba/rule/typing/macro_call_argument_type_restriction.cr

@@ -0,0 +1,94 @@
+module Ameba::Rule::Typing
+  # A rule that enforces variable arguments to specific macros have a type restriction.
+  #
+  # For example, these are considered invalid:
+  #
+  # ```
+  # class Greeter
+  #   getter name
+  #
+  #   record Task,
+  #     var1 : String,
+  #     var2 = "asdf"
+  # end
+  # ```
+  #
+  # And these are considered valid:
+  #
+  # ```
+  # class Greeter
+  #   getter name : String?
+  #   class_getter age : Int32 = 0
+  #   setter tasks : Array(String) = [] of String
+  #   class_setter queue : Array(Int32)?
+  #   property task_mutex : Mutex = Mutex.new
+  #   class_property asdf : String
+
+  #   record Task,
+  #     var1 : String,
+  #     var2 : String = "asdf"
+  # end
+  # ```
+  #
+  # The `DefaultValue` configuration option controls whether this rule applies to
+  # call arguments that have a default value.
+  #
+  # YAML configuration example:
+  #
+  # ```
+  # Typing/MethodParamTypeRestriction:
+  #   Enabled: false
+  #   DefaultValue: true
+  #   MacroNames:
+  #    - getter
+  #    - getter?
+  #    - getter!
+  #    - class_getter
+  #    - class_getter?
+  #    - class_getter!
+  #    - setter
+  #    - setter?
+  #    - setter!
+  #    - class_setter
+  #    - class_setter?
+  #    - class_setter!
+  #    - property
+  #    - property?
+  #    - property!
+  #    - class_property
+  #    - class_property?
+  #    - class_property!
+  #    - record
+  # ```
+  class MacroCallArgumentTypeRestriction < Base
+    properties do
+      since_version "1.7.0"
+      description "Recommends that variable args to certain macros have type restrictions"
+      enabled false
+      default_value true
+      macro_names %w[
+        getter getter? getter! class_getter class_getter? class_getter!
+        setter setter? setter! class_setter class_setter? class_setter!
+        property property? property! class_property class_property? class_property!
+        record
+      ]
+    end
+
+    MSG = "Argument should have a type restriction"
+
+    def test(source, node : Crystal::Call)
+      return unless node.name.in?(macro_names)
+
+      node.args.each do |arg|
+        case arg
+        when Crystal::Assign
+          next unless default_value?
+
+          issue_for arg.target, MSG % node.name, prefer_name_location: true
+        when Crystal::Var, Crystal::Call
+          issue_for arg, MSG % node.name, prefer_name_location: true
+        end
+      end
+    end
+  end
+end