feat(hm-modules): add hyfetch

home/isabel/programs/configs/cli/hyfetch.nix

@@ -1,14 +1,34 @@
 {
   lib,
   pkgs,
+  self,
   ...
 }: let
   inherit (lib) ldTernary;
 in {
-  home.packages = [pkgs.hyfetch];
+  imports = [self.homeManagerModules.hyfetch];
+  disabledModules = ["programs/hyfetch.nix"];
 
-  xdg.configFile = {
-    "neofetch/config.conf".text = ''
+  programs.hyfetch = {
+    enable = true;
+
+    settings = {
+      preset = "lesbian";
+      mode = "rgb";
+      light_dark = "dark";
+      lightness = 0.56;
+      color_align = {
+        mode = "horizontal";
+        custom_colors = [];
+        fore_back = null;
+      };
+      backend = "neofetch";
+      distro = null;
+      pride_month_shown = [];
+      pride_month_disable = false;
+    };
+
+    neofetchConfig = ''
       print_info() {
       prin " \n \n ╭───────┤ $(color 5)${ldTernary pkgs " NixOS" " MacOS"} $(color 15)├───────╮"
       info " " kernel
@@ -53,23 +73,5 @@ in {
       crop_offset="center" # northwest north northeast west center east southwest south southeast
       gap=1 # num -num
     '';
-
-    "hyfetch.json".text = ''
-      {
-          "preset": "lesbian",
-          "mode": "rgb",
-          "light_dark": "dark",
-          "lightness": 0.56,
-          "color_align": {
-              "mode": "horizontal",
-              "custom_colors": [],
-              "fore_back": null
-          },
-          "backend": "neofetch",
-          "distro": null,
-          "pride_month_shown": [],
-          "pride_month_disable": false
-      }
-    '';
   };
 }

modules/extra/home-manager/default.nix

@@ -1,6 +1,7 @@
 {
   imports = [
     ./gtklock.nix
+    ./hyfetch.nix
     ./swaync.nix
   ];
 }

modules/extra/home-manager/hyfetch.nix

@@ -0,0 +1,67 @@
+{
+  lib,
+  pkgs,
+  config,
+  ...
+}: let
+  inherit (lib) mkEnableOption mkPackageOption mkOption mkIf types;
+
+  cfg = config.programs.hyfetch;
+
+  settingsFormat = pkgs.formats.json {};
+in {
+  options.programs.hyfetch = {
+    enable = mkEnableOption "hyfetch";
+
+    package = mkPackageOption pkgs "hyfetch" {};
+
+    settings = mkOption {
+      default = {};
+      type = settingsFormat.type;
+      description = ''
+        Configuration written to {file}`$XDG_CONFIG_HOME/hyfetch.json`.
+        See https://github.com/hykilpikonna/hyfetch/blob/master/docs/hyfetch.1 for more help.
+      '';
+      example = lib.literalExpression ''
+        {
+            preset = "lesbian";
+            mode = "rgb";
+            light_dark = "dark";
+            lightness = 0.56;
+            color_align = {
+                mode = "horizontal";
+                custom_colors = [];
+                fore_back = null;
+            };
+            backend = "neofetch";
+            distro = null;
+            pride_month_shown = [];
+            pride_month_disable = false;
+        };
+      '';
+    };
+
+    neofetchConfig = mkOption {
+      default = {};
+      type = with types; nullOr (either path lines);
+      description = ''
+        Configuration written to {file}`$XDG_CONFIG_HOME/neofetch/config.conf`.
+        See https://github.com/dylanaraps/neofetch/blob/master/neofetch.1 for more help/
+      '';
+    };
+  };
+
+  config = mkIf cfg.enable {
+    home.packages = [cfg.package];
+
+    xdg.configFile = {
+      "hyfetch.json" = mkIf (cfg.settings != {}) {source = settingsFormat.generate "hyfetch.json" cfg.settings;};
+      "neofetch/config.conf" = mkIf (cfg.neofetchConfig != {}) {
+        source =
+          if builtins.isPath cfg.neofetchConfig || lib.isStorePath cfg.neofetchConfig
+          then cfg.neofetchConfig
+          else pkgs.writeText "neofetch/config.conf" cfg.neofetchConfig;
+      };
+    };
+  };
+}