gnome-text-editor: init module

Add styling for the GNOME Text Editor application. Use the Gedit
module's theme and override the HM and NixOS package to include it.
Use Home Manager's dconf to make the theme the default.

modules/gnome-text-editor/gnome-text-editor.nix

@@ -0,0 +1,29 @@
+{ config, lib, ... }:
+
+let
+  style = config.lib.stylix.colors {
+    template = ../gedit/template.mustache;
+    extension = "xml";
+  };
+in
+{
+  options.stylix.targets.gnome-text-editor.enable =
+    config.lib.stylix.mkEnableTarget "GNOME Text Editor" true;
+
+  config =
+    lib.mkIf
+      (config.stylix.enable && config.stylix.targets.gnome-text-editor.enable)
+      {
+        nixpkgs.overlays = [
+          (_: prev: {
+            gnome-text-editor = prev.gnome-text-editor.overrideAttrs (oldAttrs: {
+              postFixup =
+                (oldAttrs.postFixup or "")
+                + ''
+                  cp ${style} $out/share/gnome-text-editor/styles/stylix.xml
+                '';
+            });
+          })
+        ];
+      };
+}

modules/gnome-text-editor/hm.nix

@@ -0,0 +1,12 @@
+{ config, lib, ... }:
+
+{
+  imports = [ ./gnome-text-editor.nix ];
+
+  config =
+    lib.mkIf
+      (config.stylix.enable && config.stylix.targets.gnome-text-editor.enable)
+      {
+        dconf.settings."org/gnome/TextEditor".style-scheme = "stylix";
+      };
+}

modules/gnome-text-editor/nixos.nix

@@ -0,0 +1 @@
+import ./gnome-text-editor.nix

modules/gnome-text-editor/testbed.nix

@@ -0,0 +1,15 @@
+{ pkgs, ... }:
+
+let
+  package = pkgs.gnome-text-editor;
+
+in
+{
+  stylix.testbed.application = {
+    enable = true;
+    name = "org.gnome.TextEditor";
+    inherit package;
+  };
+
+  environment.systemPackages = [ package ];
+}