mu-editor: init at 1.1.0-alpha.2

maintainers/maintainer-list.nix

@@ -16627,6 +16627,15 @@
     githubId = 1312525;
     name = "Rongcui Dong";
   };
+  rookeur = {
+    email = "[email protected]";
+    github = "Rookeur";
+    githubId = 57438432;
+    name = "Adrien Langou";
+    keys = [{
+      fingerprint = "3B8F FC41 0094 2CB4 5A2A  7DF2 5A44 DA8F 9071 91B0";
+    }];
+  };
   roosemberth = {
     email = "[email protected]";
     matrix = "@roosemberth:orbstheorem.ch";

pkgs/applications/editors/mu/default.nix

@@ -0,0 +1,59 @@
+{ lib
+, python3
+, fetchFromGitHub
+, qt5
+}:
+
+let
+  py = python3.override {
+    packageOverrides = self: super: {
+      pyqt5 = super.pyqt5.override { withSerialPort = true; };
+    };
+  };
+in
+py.pkgs.buildPythonApplication rec {
+  pname = "mu-editor";
+  version = "1.1.0-alpha.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "mu-editor";
+    repo = "mu";
+    rev = version;
+    sha256 = "sha256-I38Jy1ArMUKtxCNnAFndA6fpUi0TJP+QJNlU1YzfYL8=";
+  };
+
+  nativeBuildInputs = [
+    py.pkgs.setuptools
+    py.pkgs.wheel
+    qt5.wrapQtAppsHook
+  ];
+
+  makeWrapperArgs = [ "\${qtWrapperArgs[@]}" ];
+
+  propagatedBuildInputs = with py.pkgs; [
+    pyqt5
+    qscintilla
+    pyqtchart
+    pycodestyle
+    pyflakes
+    pyserial
+    qtconsole
+    pgzero
+    appdirs
+    semver
+    nudatus
+    black
+    flask
+  ];
+
+  pythonImportsCheck = [ "mu" ];
+
+  meta = with lib; {
+    description = "A simple Python editor for beginner programmers";
+    homepage = "https://github.com/mu-editor/mu";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ rookeur ];
+    mainProgram = "mu-editor";
+  };
+}

pkgs/development/python-modules/nudatus/default.nix

@@ -0,0 +1,42 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, pytestCheckHook
+, setuptools
+, wheel
+}:
+
+buildPythonPackage rec {
+  pname = "nudatus";
+  version = "0.0.5";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "ZanderBrown";
+    repo = "nudatus";
+    rev = version;
+    sha256 = "sha256-yNFidirDkf624Zta8hcG/b/Q5RDzPtoCHEepSXdARXA=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+  ];
+
+  pytestFlagsArray = [
+    "tests/"
+  ];
+
+  pythonImportsCheck = [ "nudatus" ];
+
+  meta = with lib; {
+    description = "Strip comments from scripts, intended for use with MicroPython and other storage constrained environments";
+    homepage = "https://github.com/zanderbrown/nudatus";
+    license = licenses.mit;
+    maintainers = with maintainers; [ rookeur ];
+  };
+}

pkgs/development/python-modules/pgzero/default.nix

@@ -0,0 +1,57 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, unittestCheckHook
+, enum34
+, numpy
+, pygame
+, setuptools
+, wheel
+}:
+
+buildPythonPackage rec {
+  pname = "pgzero";
+  version = "1.2.1";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "lordmauve";
+    repo = "pgzero";
+    rev = version;
+    sha256 = "sha256-O3fQCs8lwyF42N2vmlJvkk/UqsNS3T4geDiHZj9lS3M=";
+  };
+
+  nativeBuildInputs = [
+    setuptools
+    wheel
+  ];
+
+  propagatedBuildInputs = [
+    enum34
+    numpy
+    pygame
+  ];
+
+  nativeCheckInputs = [
+    unittestCheckHook
+  ];
+
+  preCheck = ''
+    # skip flaky tests
+    rm -f test/test_sound_formats.py
+  '';
+
+  unittestFlagsArray = [
+    "test/"
+    "-v"
+  ];
+
+  pythonImportsCheck = [ "pgzero" ];
+
+  meta = with lib; {
+    description = "A zero-boilerplate 2D games framework";
+    homepage = "https://github.com/lordmauve/pgzero";
+    license = licenses.lgpl3Only;
+    maintainers = with maintainers; [ rookeur ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -10154,6 +10154,8 @@ with pkgs;
 
   mtail = callPackage ../servers/monitoring/mtail { };
 
+  mu-editor = libsForQt5.callPackage ../applications/editors/mu { };
+
   mujmap = callPackage ../applications/networking/mujmap {
     inherit (darwin.apple_sdk.frameworks) Security;
   };

pkgs/top-level/python-packages.nix

@@ -8652,6 +8652,8 @@ self: super: with self; {
 
   ntplib = callPackage ../development/python-modules/ntplib { };
 
+  nudatus = callPackage ../development/python-modules/nudatus { };
+
   nuitka = callPackage ../development/python-modules/nuitka { };
 
   nuheat = callPackage ../development/python-modules/nuheat { };
@@ -9397,6 +9399,8 @@ self: super: with self; {
 
   pgvector = callPackage ../development/python-modules/pgvector { };
 
+  pgzero = callPackage ../development/python-modules/pgzero { };
+
   phe = callPackage ../development/python-modules/phe { };
 
   phik = callPackage ../development/python-modules/phik { };