tectonic-with-biber: init wrapper

This is a simple `symlinkJoin` wrapper that bundles tectonic with an
appropriate version of biber. This is partially is recovered from:

  5aa8e9f

Also, add @bryango as maintainer.

Co-authored-by: Doron Behar <[email protected]>

pkgs/tools/typesetting/tectonic/wrapper.nix

@@ -0,0 +1,61 @@
+{ lib
+, makeBinaryWrapper
+, symlinkJoin
+, tectonic
+, biberVersions
+}:
+
+let
+
+  pname = "tectonic-with-biber";
+  biber = biberVersions.biber-for-tectonic;
+  inherit (biber) version;
+
+  ## manually construct `name` for `symlinkJoin`
+  name = "${pname}-${version}";
+
+  meta = tectonic.meta // {
+    inherit name;
+    description = "Modernized TeX/LaTeX engine, with biber for bibliography";
+    longDescription = ''
+      This package wraps tectonic with biber without triggering rebuilds.
+      The biber executable is exposed with a version suffix, such as
+      `biber-${version}`, to prevent conflict with the `biber` bundled with
+      texlive in nixpkgs. Example use:
+
+          let
+            pkgs = <...>; # import nixpkgs here
+          in pkgs.tectonic-with-biber.override {
+            biber = pkgs.biberVersions.biber_2_17;
+          }
+
+      This serves as a fix for:
+      - https://github.com/tectonic-typesetting/tectonic/issues/893
+    '';
+    maintainers = with lib.maintainers; [ bryango ];
+  };
+
+  ## produce the correct `meta.position` for `symlinkJoin`
+  pos = builtins.unsafeGetAttrPos "description" meta;
+
+in
+
+symlinkJoin {
+
+  inherit pname version name meta pos;
+
+  paths = [ tectonic ];
+  nativeBuildInputs = [ makeBinaryWrapper ];
+  passthru = { biber = biber; };
+
+  ## tectonic runs biber when it detects it needs to run it, see:
+  ## https://github.com/tectonic-typesetting/tectonic/releases/tag/tectonic%400.7.0
+  postBuild = ''
+    wrapProgram $out/bin/tectonic \
+      --prefix PATH : "${lib.getBin biber}/bin"
+    makeBinaryWrapper "${lib.getBin biber}/bin/biber" \
+      $out/bin/biber-${biber.version}
+  '';
+  ## the biber executable is exposed as `biber-${biber.version}`
+
+}

pkgs/top-level/all-packages.nix

@@ -25338,6 +25338,8 @@ with pkgs;
     harfbuzz = harfbuzzFull;
   };
 
+  tectonic-with-biber = callPackage ../tools/typesetting/tectonic/wrapper.nix { };
+
   tepl = callPackage ../development/libraries/tepl { };
 
   termbench-pro = callPackage ../development/libraries/termbench-pro { fmt = fmt_8; };