Adding blacksmithy.

code/_helpers/visual_filters.dm

@@ -3,13 +3,16 @@
 // All of this ported from TG.
 // And then ported to Nebula from Polaris.
 /atom/movable
-	var/list/filter_data // For handling persistent filters
+	VAR_PRIVATE/list/filter_data // For handling persistent filters
 
 // Defining this for future proofing and ease of searching for erroneous usage.
 /image/proc/add_filter(filter_name, priority, list/params)
 	filters += filter(arglist(params))
 	return TRUE
 
+/atom/movable/proc/has_filter(filter_name)
+	return (name in filter_data)
+
 /atom/movable/proc/add_filter(filter_name, priority, list/params, force_update = FALSE)
 
 	// Check if we already have a filter and hence don't need to rebuild filters.

code/game/objects/__objs.dm

@@ -415,3 +415,30 @@
 	if(dumped_reagents && last_loc && !QDELETED(last_loc) && last_loc.reagents?.total_volume)
 		last_loc.reagents.handle_update()
 		HANDLE_REACTIONS(last_loc.reagents)
+
+// Used by HE pipes and forging bars/billets. Defaults are for HE pipes.
+/obj/proc/animate_heat_glow(icon_temperature, scale_sub = 500, scale_div = 1500, scale_max = 2000, skip_filter = FALSE)
+
+	var/scale = max((icon_temperature - scale_sub) / scale_div, 0)
+	var/h_r = heat2color_r(icon_temperature)
+	var/h_g = heat2color_g(icon_temperature)
+	var/h_b = heat2color_b(icon_temperature)
+
+	var/base_color = get_color()
+	var/b_r = HEX_RED(base_color)
+	var/b_g = HEX_GREEN(base_color)
+	var/b_b = HEX_BLUE(base_color)
+
+	if(icon_temperature < scale_max)
+		h_r = b_r + (h_r - b_r)*scale
+		h_g = b_g + (h_g - b_g)*scale
+		h_b = b_b + (h_b - b_b)*scale
+
+	var/scale_color = rgb(h_r, h_g, h_b)
+	var/list/animate_targets = get_above_oo() + src
+	for (var/thing in animate_targets)
+		var/atom/movable/AM = thing
+		animate(AM, color = scale_color, time = 2 SECONDS, easing = SINE_EASING)
+	if(!skip_filter)
+		animate_filter("glow", list(color = scale_color, time = 2 SECONDS, easing = LINEAR_EASING))
+	set_light(min(3, scale*2.5), min(3, scale*2.5), scale_color)

code/game/objects/effects/effect_system.dm

@@ -107,12 +107,16 @@ steam.start() -- spawns the effect
 /obj/effect/sparks/struck
 	spark_sound = "light_bic"
 
+/obj/effect/sparks/silent
+	spark_sound = null
+
 /obj/effect/sparks/Initialize()
 	. = ..()
 	// this is 2 seconds so that it doesn't appear to freeze after its last move, which ends up making it look like timers are broken
 	// if you change the number of or delay between moves in spread(), this may need to be changed
 	QDEL_IN(src, 2 SECONDS)
-	playsound(loc, spark_sound, 100, 1)
+	if(spark_sound)
+		playsound(loc, spark_sound, 100, 1)
 	set_light(lit_light_range, lit_light_power, lit_light_color)
 	if(isturf(loc))
 		var/turf/T = loc
@@ -140,6 +144,9 @@ steam.start() -- spawns the effect
 /datum/effect/effect/system/spark_spread
 	var/spark_type = /obj/effect/sparks
 
+/datum/effect/effect/system/spark_spread/silent
+	spark_type = /obj/effect/sparks/silent
+
 /datum/effect/effect/system/spark_spread/non_electrical
 	spark_type = /obj/effect/sparks/struck
 

code/game/objects/items/__item.dm

@@ -391,6 +391,9 @@
 	if(drying_wetness > 0 && drying_wetness != initial(drying_wetness))
 		desc_comp += "\The [src] is [get_dryness_text()]."
 
+	if(check_rights(R_DEBUG, 0, user))
+		to_chat(user, "\The [src] has a temperature of [temperature]K.")
+
 	return ..(user, distance, "", jointext(desc_comp, "<br/>"))
 
 /obj/item/check_mousedrop_adjacency(var/atom/over, var/mob/user)

code/game/objects/items/crafting/barrel_rim.dm

@@ -0,0 +1,8 @@
+// Stub for forging. TODO barrel crafting.
+/obj/item/barrel_rim
+	name                = "barrel rim"
+	desc                = "A circular brace used to hold a barrel together."
+	icon_state          = ICON_STATE_WORLD
+	icon                = 'icons/obj/items/barrel_rim.dmi'
+	material            = /decl/material/solid/metal/iron
+	material_alteration = MAT_FLAG_ALTERATION_ALL

code/game/objects/items/weapons/material/knives.dm

@@ -101,7 +101,7 @@
 
 //random stuff
 /obj/item/knife/hook
-	name = "meat hook"
+	name = "hook"
 	desc = "A sharp, metal hook what sticks into things."
 	icon = 'icons/obj/items/weapon/knives/hook.dmi'
 	sharp = FALSE

code/game/objects/structures/_structure_materials.dm

@@ -3,6 +3,7 @@
 	var/decl/material/reinf_material
 	var/material_alteration
 	var/dismantled
+	var/name_prefix
 
 /obj/structure/get_material()
 	RETURN_TYPE(/decl/material)
@@ -37,10 +38,14 @@
 
 /obj/structure/proc/update_material_name(var/override_name)
 	var/base_name = override_name || initial(name)
+	var/new_name
 	if(istype(material) && (material_alteration & MAT_FLAG_ALTERATION_NAME))
-		SetName("[material.adjective_name] [base_name]")
+		new_name = "[material.adjective_name] [base_name]"
 	else
-		SetName(base_name)
+		new_name = base_name
+	if(name_prefix)
+		new_name = "[name_prefix] [new_name]"
+	SetName(new_name)
 
 /obj/structure/proc/update_material_desc(var/override_desc)
 	var/base_desc = override_desc || initial(desc)

code/game/objects/structures/fires.dm

@@ -202,6 +202,9 @@
 		else
 			to_chat(user, "\The [src] is empty.")
 
+	if(check_rights(R_DEBUG, 0, user))
+		to_chat(user, "\The [src] has a temperature of [temperature]K, an effective burn temperature of [get_effective_burn_temperature()]K and a fuel value of [fuel].")
+
 /obj/structure/fire_source/attack_hand(var/mob/user)
 
 	var/list/removable_atoms = get_removable_atoms()

code/modules/atmospherics/he_pipes.dm

@@ -93,24 +93,7 @@
 		//fancy radiation glowing
 		if(pipe_air.temperature && (icon_temperature > 500 || pipe_air.temperature > 500)) //start glowing at 500K
 			if(abs(pipe_air.temperature - icon_temperature) > 10)
-				icon_temperature = pipe_air.temperature
-				var/scale = max((icon_temperature - 500) / 1500, 0)
-
-				var/h_r = heat2color_r(icon_temperature)
-				var/h_g = heat2color_g(icon_temperature)
-				var/h_b = heat2color_b(icon_temperature)
-
-				if(icon_temperature < 2000) //scale up overlay until 2000K
-					h_r = 64 + (h_r - 64)*scale
-					h_g = 64 + (h_g - 64)*scale
-					h_b = 64 + (h_b - 64)*scale
-				var/scale_color = rgb(h_r, h_g, h_b)
-				var/list/animate_targets = get_above_oo() + src
-				for (var/thing in animate_targets)
-					var/atom/movable/AM = thing
-					animate(AM, color = scale_color, time = 2 SECONDS, easing = SINE_EASING)
-				animate_filter("glow", list(color = scale_color, time = 2 SECONDS, easing = LINEAR_EASING))
-				set_light(min(3, scale*2.5), min(3, scale*2.5), scale_color)
+				animate_heat_glow(pipe_air.temperature)
 		else
 			set_light(0, 0)
 

code/modules/crafting/stack_recipes/recipes_soft.dm

@@ -44,6 +44,12 @@
 	result_type                 = /obj/item/stack/material/brick
 	test_result_type            = /obj/item/stack/material/brick/clay
 
+/decl/stack_recipe/soft/bar
+	name                        = "bar"
+	name_plural                 = "bars"
+	result_type                 = /obj/item/stack/material/bar
+	test_result_type            = /obj/item/stack/material/bar/wax
+
 /decl/stack_recipe/soft/stack/spawn_result(mob/user, location, amount, decl/material/mat, decl/material/reinf_mat, paint_color, spent_type, spent_amount = 1)
 	var/obj/item/stack/S = ..()
 	if(istype(S))

code/modules/materials/_materials.dm

@@ -371,6 +371,8 @@ INITIALIZE_IMMEDIATE(/obj/effect/gas_overlay)
 	/// Assoc weighted list of gemstone material types to weighting.
 	var/list/gemstone_types
 
+	var/forgable = FALSE // Can this material be forged in bar/billet form?
+
 // Placeholders for light tiles and rglass.
 /decl/material/proc/reinforce(var/mob/user, var/obj/item/stack/material/used_stack, var/obj/item/stack/material/target_stack, var/use_sheets = 1)
 	if(!used_stack.can_use(use_sheets))
@@ -444,6 +446,7 @@ INITIALIZE_IMMEDIATE(/obj/effect/gas_overlay)
 		burn_product                 = null
 		vapor_products               = null
 		compost_value                = 0
+		forgable                     = FALSE
 	else if(isnull(temperature_damage_threshold))
 		var/new_temperature_damage_threshold = max(melting_point, boiling_point, heating_point)
 		// Don't let the threshold be lower than the ignition point.

code/modules/materials/definitions/solids/materials_solid_metal.dm

@@ -20,6 +20,7 @@
 	icon_reinf = 'icons/turf/walls/reinforced_metal.dmi'
 	exoplanet_rarity_gas = MAT_RARITY_NOWHERE
 	tensile_strength = 0.8 // metal wire is probably better than plastic?
+	forgable = TRUE
 
 /decl/material/solid/metal/uranium
 	name = "uranium"

code/modules/materials/material_sheets_mapping.dm

@@ -122,11 +122,15 @@ STACK_SUBTYPES(titanium,       "titanium",                      solid/metal/tita
 STACK_SUBTYPES(cotton,         "cotton",                        solid/organic/cloth,         thread,           null)
 STACK_SUBTYPES(dried_gut,      "dried gut",                     solid/organic/leather/gut,   thread,           null)
 
+STACK_SUBTYPES(iron,           "iron",                          solid/metal/iron,            bar,              null)
+STACK_SUBTYPES(copper,         "copper",                        solid/metal/copper,          bar,              null)
+
 STACK_SUBTYPES(chipboard_oak,      "oak chipboard",      solid/organic/wood/chipboard,          sheet,         null)
 STACK_SUBTYPES(chipboard_maple,    "maple chipboard",    solid/organic/wood/chipboard/maple,    sheet,         null)
 STACK_SUBTYPES(chipboard_mahogany, "mahogany chipboard", solid/organic/wood/chipboard/mahogany, sheet,         null)
 STACK_SUBTYPES(chipboard_ebony,    "ebony chipboard",    solid/organic/wood/chipboard/ebony,    sheet,         null)
 STACK_SUBTYPES(chipboard_walnut,   "walnut chipboard",   solid/organic/wood/chipboard/walnut,   sheet,         null)
 STACK_SUBTYPES(chipboard_yew,      "yew chipboard",      solid/organic/wood/chipboard/yew,      sheet,         null)
 
+
 #undef STACK_SUBTYPES

code/modules/materials/material_stack_nail.dm

@@ -0,0 +1,16 @@
+/obj/item/stack/material/nail
+	name                = "nails"
+	singular_name       = "nail"
+	plural_name         = "nails"
+	icon_state          = "nail"
+	plural_icon_state   = "nail-mult"
+	max_icon_state      = "nail-max"
+	stack_merge_type    = /obj/item/stack/material/nail
+	crafting_stack_type = /obj/item/stack/material/nail
+	icon                = 'icons/obj/items/stacks/nails.dmi'
+	is_spawnable_type   = TRUE
+	matter_multiplier   = 0.05 // 20 per standard sheet
+	material            = /decl/material/solid/metal/iron
+
+/obj/item/stack/material/nail/twelve
+	amount              = 12

maps/modpack_testing/modpack_testing.dm

@@ -24,6 +24,7 @@
 	#include "../../mods/content/shackles/_shackles.dme"
 	#include "../../mods/content/supermatter/_supermatter.dme"
 	#include "../../mods/content/xenobiology/_xenobiology.dme"
+	#include "../../mods/content/blacksmithy/_blacksmithy.dme"
 	#include "../../mods/content/item_sharpening/_item_sharpening.dme"
 
 	#include "../../mods/gamemodes/cult/_cult.dme"

maps/shaded_hills/shaded_hills.dm

@@ -7,6 +7,7 @@
 	#include "../../mods/species/drakes/_drakes.dme" // include before _fantasy.dme so overrides work
 	#include "../../mods/content/item_sharpening/_item_sharpening.dme"
 	#include "../../mods/content/fantasy/_fantasy.dme"
+	#include "../../mods/content/blacksmithy/_blacksmithy.dme"
 
 	#include "areas/_areas.dm"
 	#include "areas/downlands.dm"

mods/content/blacksmithy/_blacksmithy.dm

@@ -0,0 +1,3 @@
+/decl/modpack/blacksmithy
+	name = "Blacksmithy"
+

mods/content/blacksmithy/_blacksmithy.dme

@@ -0,0 +1,14 @@
+#ifndef MODPACK_BLACKSMITHY
+#define MODPACK_BLACKSMITHY
+// BEGIN_INCLUDE
+#include "_blacksmithy.dm"
+#include "anvil.dm"
+#include "bars.dm"
+#include "billet.dm"
+#include "boulder.dm"
+#include "forge_fire.dm"
+#include "forging_action.dm"
+#include "forging_step.dm"
+#include "tongs.dm"
+// END_INCLUDE
+#endif

mods/content/blacksmithy/anvil.dm

@@ -0,0 +1,86 @@
+/obj/structure/anvil
+	name                = "anvil"
+	desc                = "A heavy block of material used as support for hammering things into shape."
+	icon                = 'icons/obj/structures/anvil.dmi'
+	icon_state          = ICON_STATE_WORLD
+	anchored            = TRUE
+	density             = TRUE
+	opacity             = FALSE
+	atom_flags          = ATOM_FLAG_CLIMBABLE
+	w_class             = ITEM_SIZE_STRUCTURE //_LARGE
+	material            = /decl/material/solid/metal/iron
+	max_health          = 1000
+	structure_flags     = STRUCTURE_FLAG_SURFACE
+	material_alteration = MAT_FLAG_ALTERATION_ALL
+
+/obj/structure/anvil/on_update_icon()
+	. = ..()
+	icon_state = initial(icon_state)
+	switch(get_health_percent())
+		if(0 to 0.35)
+			icon_state = "[icon_state]-damage-heavy"
+		if(0.35 to 0.65)
+			icon_state = "[icon_state]-damage-light"
+
+/obj/structure/anvil/attackby(obj/item/used_item, mob/user, click_params)
+
+	// Put the hammer on the forge.
+	if(!user.check_intent(I_FLAG_HARM) && istype(used_item, /obj/item/tool/hammer/forge))
+		if(user.try_unequip(used_item, get_turf(src)))
+			auto_align(used_item, click_params)
+		return TRUE
+
+	// Put the bar onto the anvil (need to do this to avoid repairs in ..())
+	if(istype(used_item, /obj/item/stack/material/bar))
+		var/obj/item/stack/material/bar/bar = used_item
+		if(used_item.material != material || current_health >= get_max_health())
+			if(bar.get_amount() > 1)
+				bar = bar.split(1)
+			if(bar.loc == user)
+				user.try_unequip(bar, get_turf(src))
+			else
+				bar.dropInto(get_turf(src))
+			auto_align(bar, click_params)
+			return TRUE
+
+	// Place a partially worked billet onto the anvil.
+	if(istype(used_item, /obj/item/billet))
+		if(used_item.loc == user)
+			user.try_unequip(used_item, get_turf(src))
+		else
+			used_item.dropInto(get_turf(src))
+		auto_align(used_item, click_params)
+		return TRUE
+
+	// Put the bar from tongs onto the anvil.
+	if(istype(used_item, /obj/item/tongs))
+		var/obj/item/tongs/tongs = used_item
+		if(tongs.holding_bar)
+			return attackby(tongs.holding_bar, user)
+
+	. = ..()
+
+// Chipped out of a boulder with a pick.
+/obj/structure/anvil/boulder
+	name_prefix         = "crude"
+	icon                = 'icons/obj/structures/anvil_crude.dmi'
+	desc                = "A crude anvil chipped out of a chunk of stone. It probably won't last very long."
+	material            = /decl/material/solid/stone/granite
+	max_health          = 500
+
+/obj/structure/anvil/boulder/Initialize(ml, _mat, _reinf_mat)
+	. = ..()
+	if(prob(50))
+		set_icon('icons/obj/structures/anvil_crude_alt.dmi')
+
+// Improvised with spaceman materials.
+/obj/structure/anvil/improvised
+	name_prefix         = "improvised"
+	icon                = 'icons/obj/structures/anvil_improvised.dmi'
+	desc                = "A anvil roughly improvised out of scrap metal. It probably won't last very long."
+	material            = /decl/material/solid/metal/steel
+	max_health          = 500
+
+/decl/stack_recipe/steel/furniture
+	result_type       = /obj/structure/anvil/improvised
+	difficulty        = MAT_VALUE_HARD_DIY