build.gradle

apply plugin: 'java'
apply plugin: 'java-library'

// use 11 compatibility to ensure we still work with base synthea
sourceCompatibility = '11'
targetCompatibility = '11'

repositories {
  mavenCentral()
  maven {
    url "https://oss.sonatype.org/content/repositories/snapshots"
  }
}

configurations {
  // we define a new configuration to list dependencies we need to include in the jar
  extraLibs
}

jar {
  from {
    configurations.extraLibs.collect { it.isDirectory() ? it : zipTree(it) }
  }
}

dependencies {
  // "implementation" dependencies will not be included in the jar
  // but can be referenced by this project
  // it is mandatory to reference synthea so that the appropriate interfaces are available
  implementation 'org.mitre.synthea:synthea:3.2.2-SNAPSHOT'

  // "extraLibs" dependencies will be repackaged inside our built jar
  // example:
  // extraLibs 'com.google.code.gson:gson:2.8.7'
  // WARNING: this may cause unexpected issues if the same library is used in synthea already,
  // especially if a different version is used. Refer to:
  // https://github.com/synthetichealth/synthea/blob/master/build.gradle
  // for the current set of libraries used in synthea

  configurations.api.extendsFrom(configurations.extraLibs)

  // Use JUnit test framework
  testImplementation 'junit:junit:4.13'
}