forked from rcaelers/workrave
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathconfigure.ac
1218 lines (993 loc) · 38.2 KB
/
configure.ac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
dnl Process this file with autoconf to produce a configure script.
dnl
dnl Copyright (C) 2001 - 2014 Rob Caelers & Raymond Penners
dnl
m4_define([workrave_major_version], [1])
m4_define([workrave_minor_version], [10])
m4_define([workrave_micro_version], [46])
m4_define([workrave_version_suffix], [])
m4_define([workrave_version],
workrave_major_version.workrave_minor_version.workrave_micro_version[]m4_ifset([workrave_version_suffix],-[workrave_version_suffix]))
m4_define([workrave_resource_version],
[workrave_major_version,workrave_minor_version,workrave_micro_version,0])
AC_PREREQ([2.67])
AC_INIT([workrave],
[workrave_version],
[https://github.com/rcaelers/workrave/issues],
[workrave],
[http://www.workrave.org])
AC_CANONICAL_HOST
AC_CANONICAL_TARGET
AC_CONFIG_SRCDIR([backend/include/ICore.hh])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_HEADER([config.h])
AM_INIT_AUTOMAKE([-Wall -Wno-portability foreign silent-rules tar-ustar subdir-objects])
dnl AM_SILENT_RULES([yes])
GNOME_SHELL_VERSION=3.26.1
AC_SUBST(GNOME_SHELL_VERSION)
if test -n "$WORKRAVE_GIT_VERSION"; then
AC_DEFINE_UNQUOTED(GIT_VERSION, "$WORKRAVE_GIT_VERSION", [GIT Version])
fi
dnl
dnl Command line options.
dnl
AC_ARG_ENABLE(app-gtk,
[AS_HELP_STRING([--disable-app-gtk],
[compile without Gtk support (NOT recommended)])])
AC_ARG_ENABLE(app-text,
[AS_HELP_STRING([--enable-app-text],
[compile with dummy text GUI support (NOT recommended)])])
AC_ARG_ENABLE(xml,
[AS_HELP_STRING([--disable-xml],
[compile without XML support])])
AC_ARG_ENABLE(gconf,
[AS_HELP_STRING([--enable-gconf],
[compile with Gnome gconf2 support])])
AC_ARG_ENABLE(gsettings,
[AS_HELP_STRING([--disable-gsettings],
[compile without GSettings support])])
AC_ARG_ENABLE(gnome3,
[AS_HELP_STRING([--disable-gnome3],
[compile without Gnome 3 support])])
AC_ARG_ENABLE(indicator,
[AS_HELP_STRING([--enable-indicator],
[compile with Unity/Ayatana indicator applet support])])
AC_ARG_ENABLE(xfce,
[AS_HELP_STRING([--enable-xfce],
[compile with preliminary XFCE applet support])])
AC_ARG_ENABLE(mate,
[AS_HELP_STRING([--enable-mate],
[compile with preliminary MATE applet support])])
AC_ARG_ENABLE(dbus,
[AS_HELP_STRING([--disable-dbus],
[compile without DBus support])])
AC_ARG_ENABLE(gstreamer,
[AS_HELP_STRING([--disable-gstreamer],
[compile without GStreamer audio support])])
AC_ARG_ENABLE(pulse,
[AS_HELP_STRING([--disable-pulse],
[compile without PulseAudio support])])
AC_ARG_ENABLE(debug,
[AS_HELP_STRING([--enable-debug],
[compile with debugging flags set])])
AC_ARG_ENABLE(distribution,
[AS_HELP_STRING([--disable-distribution],
[compile without support for distributed operation])])
AC_ARG_ENABLE(experimental,
[AS_HELP_STRING([--enable-experimental],
[compile with experimental features])])
AC_ARG_ENABLE(exercises,
[AS_HELP_STRING([--disable-exercises],
[compile without exercises support])])
AC_ARG_ENABLE(tests,
[AS_HELP_STRING([--enable-tests],
[compile with test code])])
AC_ARG_ENABLE(tracing,
[AS_HELP_STRING([--enable-tracing],
[compile with method call tracing])],
[test "x$enable_tracing" = "xyes" && enable_debug=yes])
AC_ARG_ENABLE(monitors,
[AS_HELP_STRING([--enable-monitors=LIST],
[comma separated list of activity monitors to use, currently support: record, screensaver, x11events (Unix Only) @<:@default=yes@:>@])])
case x"$target" in
xNONE | x)
target_or_host="$host" ;;
*)
target_or_host="$target" ;;
esac
dnl
dnl Checks for programs
dnl
AC_USE_SYSTEM_EXTENSIONS
AC_PROG_CC
AM_PROG_CC_C_O
AM_PROG_AR
AC_PROG_OBJC
AC_PROG_OBJCXX
AC_PROG_CXX
AC_PROG_CPP
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PROG_LIBTOOL
AC_CHECK_PROGS(M4, gm4 m4, m4)
AC_CHECK_PROGS(WINDRES, ${target_or_host}-windres,false)
dnl
dnl checks for compiler characteristics
dnl
AC_LANG([C++])
AC_REQUIRE_CPP
AC_C_INLINE
AC_C_CONST
AC_DEFUN([ADD_COMPILER_FLAG],[
AX_CHECK_COMPILE_FLAG([$1],[
CPPFLAGS="$CPPFLAGS $1"
])])
ADD_COMPILER_FLAG([-Wno-cast-function-type])
AX_CXX_COMPILE_STDCXX_11(ext, mandatory)
dnl
dnl Headers/Types/Functions
dnl
AC_HEADER_STDC
AC_CHECK_HEADERS([errno.h stdlib.h sys/time.h sys/select.h unistd.h])
AC_CHECK_MEMBER(MOUSEHOOKSTRUCT.hwnd,AC_DEFINE(HAVE_STRUCT_MOUSEHOOKSTRUCT,,[struct MOUSEHOOKSTRUCT]),, [#include <windows.h>])
AC_CHECK_MEMBER(MOUSEHOOKSTRUCTEX.mouseData,AC_DEFINE(HAVE_STRUCT_MOUSEHOOKSTRUCTEX,,[struct MOUSEHOOKSTRUCTEX]),, [#include <windows.h>])
have_ishelldispatch=no
AC_MSG_CHECKING([IShellDispatch])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <shlobj.h>]], [[ IShellDispatch* pShellDispatch = NULL; ]])],[have_ishelldispatch=yes
AC_DEFINE(HAVE_ISHELLDISPATCH, 1, "IShellDispatch")
AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
AC_CHECK_FUNCS([gettimeofday nanosleep select setlocale realpath])
have_extern_timezone_defined=no
AC_MSG_CHECKING([external timezone variable defined in time.h])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[ timezone += 1;
return 0;]])],[have_extern_timezone_defined=yes
AC_DEFINE(HAVE_EXTERN_TIMEZONE_DEFINED, 1, "External timezone")
AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
have_extern_timezone=no
AC_MSG_CHECKING([external timezone variable])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[ extern long timezone;
timezone += 1;
return 0;]])],[have_extern_timezone=yes
AC_DEFINE(HAVE_EXTERN_TIMEZONE, 1, "External timezone")
AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
dnl Update version and date.
AC_SUBST(VERSION)
ISODATE=`date +%Y-%m-%d`
AC_SUBST(ISODATE)
RESOURCE_VERSION=workrave_resource_version
AC_SUBST(RESOURCE_VERSION)
AC_CANONICAL_HOST
AC_PREFIX_PROGRAM(workrave)
dnl
dnl Checking target platform.
dnl
AC_MSG_CHECKING([for platform])
PLATFORM_OS_WINDOWS=no
PLATFORM_OS_MACOS=no
platform_os_unix=no
platform_variant_x11=no
case "$target_or_host" in
*-*mingw*|*-*-mingw*|*-*-cygwin*)
PLATFORM_OS_WINDOWS=yes
platform_os_name="Windows"
AC_DEFINE(PLATFORM_OS_WINDOWS,,[Define if compiling for the Win32 platform])
AC_DEFINE(HAVE_LANGUAGE_SELECTION,,[Define if the UI language can be defined in the preferences])
;;
*-*-darwin* | *-*-rhapsody*)
PLATFORM_OS_MACOS=yes
platform_os_name="OS X"
AC_DEFINE(PLATFORM_OS_MACOS,,[Define if compiling for the OS X platform])
;;
*)
platform_os_unix=yes
platform_os_name="Unix"
AC_DEFINE(PLATFORM_OS_UNIX,,[Define if compiling for a Unix platform])
;;
esac
AC_MSG_RESULT([$platform_os_name])
AM_CONDITIONAL(PLATFORM_OS_WINDOWS, test "x$PLATFORM_OS_WINDOWS" = "xyes")
AM_CONDITIONAL(PLATFORM_OS_MACOS, test "x$PLATFORM_OS_MACOS" = "xyes")
AM_CONDITIONAL(PLATFORM_OS_UNIX, test "x$platform_os_unix" = "xyes")
AM_CONDITIONAL(HAVE_LANGUAGE_SELECTION, test "x$PLATFORM_OS_WINDOWS" = "xyes")
dnl
dnl Debug
dnl
config_debug=no
config_tracing=no
if test "x$enable_debug" = "xyes"
then
config_debug=yes
CFLAGS="${CFLAGS} -O0 -g -Wall"
CXXFLAGS="${CXXFLAGS} -O0 -g -Wall"
LDFLAGS="${LDFLAGS} -g"
AC_DEFINE([GLIBCXX_FORCE_NEW], , [Define for debugging purposes])
AC_DEFINE([GLIBCPP_FORCE_NEW], , [Define for debugging purposes])
else
AC_DEFINE([NDEBUG], , [Define if debugging code should be disabled])
fi
if test "x$enable_tracing" = "xyes"
then
config_tracing=yes
AC_DEFINE([TRACING], , [Define to enable method call tracing])
fi
dnl
dnl Windows specific checks
dnl
have_dsound=no
LIBSTDCPP_LIBS=
WIN32CONSOLE=
DIRECTSOUNDLIBS=
if test "x$PLATFORM_OS_WINDOWS" = "xyes"
then
LIBSTDCPP_LIBS=-lstdc++
AC_DEFINE([_WIN32_IE], [0x0600], [Windows version])
AC_DEFINE([_WIN32_WINNT], [0x0600], [Windows version])
#if test "x$enable_debug" != "xyes"
#then
WIN32CONSOLE=-mwindows
#else
# WIN32CONSOLE=-mconsole
#fi
enable_gconf=no
enable_gnome3=no
enable_xml=no
enable_indicator=no
enable_xfce=no
enable_mate=no
AC_CHECK_HEADER(dsound.h, [ AC_DEFINE(HAVE_DSOUND, 1, [Define if we have DirectSound])
have_dsound=yes DIRECTSOUNDLIBS="-ldsound -luuid -ldxguid -ldxerr8"
])
AC_CHECK_HEADERS([dxerr.h dxerr8.h], [], [],
[[#include <windows.h>
]])
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
#include <mmdeviceapi.h>
#include <endpointvolume.h>
static REFIID foo = __uuidof(IAudioEndpointVolume);
]], [[
IMMDeviceEnumerator *device_enum = NULL;
]])],[ have_mmdeviceapi=yes
AC_DEFINE(HAVE_MMDEVICEAPI_H, 1, [Define if we have mm device api])
AC_MSG_RESULT(yes)
],[AC_MSG_RESULT(no)])
fi
AC_SUBST(LIBSTDCPP_LIBS)
AC_SUBST(WIN32CONSOLE)
AC_SUBST(DIRECTSOUNDLIBS)
AM_CONDITIONAL(HAVE_DSOUND, test "x$have_dsound" = "xyes")
dnl
dnl MacOS specific checks
dnl
PKG_PROG_PKG_CONFIG
AC_SUBST(MacOS_CFLAGS)
if test "x$PLATFORM_OS_MACOS" = "xyes"
then
PKG_CHECK_MODULES(IGE, gtk-mac-integration >= 2.0,
[AC_DEFINE(HAVE_GTK_MAC_INTEGRATION, 1, [Define if we have gtk-mac-integration 2.0+])],
[PKG_CHECK_MODULES(IGE, ige-mac-integration >= 0.6, AC_DEFINE(HAVE_IGE_MAC_INTEGRATION, 1, [Define if we have ige-mac-integration 0.6+]))])
AC_CHECK_LIB(resolv, res_query)
AC_CHECK_HEADER(CoreFoundation/CoreFoundation.h, [ AC_CHECK_HEADER(IOKit/IOKitLib.h,
[ AC_DEFINE(HAVE_IOKIT, 1, [Define if we have IOKit])
LIBS="$LIBS -framework IOKit -framework CoreFoundation"
])])
config_gnome3=no
config_gconf=no
LDFLAGS="$LDFLAGS -headerpad_max_install_names"
LIBS="$LIBS -framework CoreServices -framework Carbon -framework Cocoa -framework Foundation"
MacOS_CFLAGS=""
fi
AC_SUBST(IGE_LIBS)
AC_SUBST(IGE_CFLAGS)
dnl
dnl Unix specific checks
dnl
if test "x$platform_os_unix" = "xyes"
then
AC_PATH_X
AC_PATH_XTRA
if test x$have_x != xyes ; then
AC_MSG_ERROR(X11 required on Unix platform)
fi
LIBS_save=$LIBS
if test -n "$ac_x_libraries"
then
LIBS="$LIBS -L$x_libraries"
fi
CPPFLAGS_save="$CPPFLAGS"
if test -n "$x_includes"
then
CPPFLAGS="$CPPFLAGS -I$x_includes"
fi
have_xrecord=no
AC_CHECK_LIB(Xtst, XRecordEnableContext,
have_xrecord=yes X_LIBS="$X_LIBS -lXtst" AC_DEFINE(HAVE_XRECORD,,[Define if the RECORD extension is available]),
)
if test x$have_xrecord != xyes ; then
AC_MSG_ERROR(X RECORD extension headers files required on Unix platform)
fi
AC_CHECK_LIB(Xext, XScreenSaverRegister,
have_xscreensaver=yes X_LIBS="$X_LIBS -lX11 -lXext",
[],
[-lX11 -lXext -lm])
AC_CHECK_LIB(Xss, XScreenSaverRegister,
have_xscreensaver=yes X_LIBS="$X_LIBS -lX11 -lXss",
[],
[-lX11 -lXext -lm])
if test "x$have_xscreensaver" = "xyes"; then
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
#include <X11/Xlib.h>
#include <X11/extensions/scrnsaver.h>
]], [[]])], [], [have_xscreensaver=no])
fi
if test "x$have_xscreensaver" = "xyes" ; then
AC_DEFINE(HAVE_SCREENSAVER, 1, [Define if XScreenSaver is available.])
fi
PKG_CHECK_MODULES(X11SM, sm ice)
LIBS=$LIBS_save
CPPFLAGS=$CPPFLAGS_save
fi
dnl
dnl Monitors
dnl
if test "x$platform_os_unix" = "xyes"
then
if test "x$enable_monitors" = "x"; then
enable_monitors="mutter"
if test "x$have_xrecord" = "xyes" ; then
if test "x$enable_monitors" != "x"; then
enable_monitors="$enable_monitors,"
fi
enable_monitors="${enable_monitors}record"
fi
if test "x$have_xscreensaver" = "xyes" ; then
if test "x$enable_monitors" != "x"; then
enable_monitors="$enable_monitors,"
fi
enable_monitors="${enable_monitors}screensaver"
fi
if test "x$enable_monitors" != "x"; then
enable_monitors="$enable_monitors,"
fi
enable_monitors="${enable_monitors}x11events"
fi
loop=${enable_monitors},
while echo $loop | grep \, &> /dev/null
do
monitor=${loop%%\,*}
loop=${loop#*\,}
case "$monitor" in
record)
if test "x$have_xrecord" != "xyes" ; then
AC_MSG_ERROR([record activity monitor not supported.])
fi
;;
x11events)
;;
mutter)
;;
screensaver)
if test "x$have_xscreensaver" != "xyes" ; then
AC_MSG_ERROR([screensaver activity monitor not supported.])
fi
;;
*)
AC_MSG_ERROR([unknown activity monitor: $monitor])
;;
esac
done
AC_DEFINE_UNQUOTED(HAVE_MONITORS, "$enable_monitors", "Enabled activity monitors")
fi
dnl
dnl DBus
dnl
config_dbus=no
have_python_jinja2=no
if test "x$enable_dbus" != "xno" -a "x$PLATFORM_OS_WINDOWS" != "xyes" -a "x$PLATFORM_OS_MACOS" != "xyes"
then
PKG_CHECK_MODULES([GIO],
[gio-2.0 >= 2.26.0],
[ config_dbus=yes ], [ config_dbus=no])
fi
if test "x$config_dbus" = "xyes"
then
# For now, only needed for DBus.
AX_BOOST_BASE([1.52],, AC_MSG_ERROR([requires boost library >= 1.52.]))
AC_DEFINE(HAVE_DBUS, , [DBus support])
AS_AC_EXPAND(DATADIR, "$datadir")
DBUS_SERVICES_DIR="$DATADIR/dbus-1/services"
AC_SUBST(DBUS_SERVICES_DIR)
AC_DEFINE_UNQUOTED(DBUS_SERVICES_DIR, "$DBUS_SERVICES_DIR", [Where services dir for DBUS is])
AM_PATH_PYTHON([3.0])
AX_PYTHON_MODULE([jinja2], [needed], python3)
fi
AM_CONDITIONAL(HAVE_DBUS, test x$config_dbus = xyes)
AM_CONDITIONAL(HAVE_PYTHON_JINJA2, test x$HAVE_PYMOD_jinja2 = xyes)
dnl
dnl Gnome
dnl
config_gnome3=no
config_panelapplet4=no
config_panelapplet5=no
config_libgnome_panel=no
if test "x$enable_gnome3" != "xno" -a "x$config_dbus" = "xyes"
then
PKG_CHECK_MODULES([GNOME3],
[libgnome-panel >= 3.36.0 gio-2.0 >= 2.26.0],
[config_gnome3=yes
config_libgnome_panel=yes
LIBGNOME_PANEL_MODULES_DIR=`$PKG_CONFIG --variable=modulesdir libgnome-panel`
AC_SUBST([LIBGNOME_PANEL_MODULES_DIR], [$LIBGNOME_PANEL_MODULES_DIR])
AC_DEFINE([HAVE_LIBGNOME_PANEL], 1, [Support for GNOME Panel applet])],
[ ])
if test "x$config_libgnome_panel" != "xyes"
then
PKG_CHECK_MODULES(GNOME3,
[libpanel-applet >= 3.16.1 gio-2.0 >= 2.26.0],
[config_gnome3=yes
config_panelapplet5=yes
AC_DEFINE([HAVE_PANELAPPLET], [1], [Support for Gnome panel applet v4/v5])
AC_DEFINE([HAVE_PANELAPPLET5], [1], [Support for Gnome panel applet v5])],
[ ])
if test "x$config_panelapplet5" != "xyes"
then
PKG_CHECK_MODULES([GNOME3],
[libpanelapplet-4.0 gio-2.0 >= 2.26.0],
[config_gnome3=yes
config_panelapplet4=yes
AC_DEFINE(HAVE_PANELAPPLET, 1, [Support for Gnome panel applet v4/v5]),
AC_DEFINE(HAVE_PANELAPPLET4, 1, [Support for Gnome panel applet v4])],
[if test "x$enable_gnome3" = "xyes"; then
AC_MSG_ERROR([Gnome 3 development headers not found.])
fi])
fi
fi
fi
AM_CONDITIONAL(HAVE_PANELAPPLET, test "x$config_panelapplet4" = "xyes" -o "x$config_panelapplet5" = "xyes")
AM_CONDITIONAL(HAVE_PANELAPPLET4, test "x$config_panelapplet4" = "xyes")
AM_CONDITIONAL(HAVE_PANELAPPLET5, test "x$config_panelapplet5" = "xyes")
AM_CONDITIONAL(HAVE_LIBGNOME_PANEL, test "x$config_libgnome_panel" = "xyes")
dnl
dnl GLIB
dnl
PKG_CHECK_MODULES([GLIB],
[glib-2.0 >= 2.10 gmodule-2.0 gthread-2.0],
[AC_DEFINE(HAVE_GLIB, , [Define if GLib is available])])
config_gsettings=no
if test "x$enable_gsettings" != "xno"
then
if test "x$platform_os_unix" = "xyes"; then
GLIB_GSETTINGS
config_gsettings=yes
AC_DEFINE(HAVE_GSETTINGS, 1, [Have GSettings])
fi
fi
AM_CONDITIONAL(HAVE_GSETTINGS, test "x$config_gsettings" = "xyes")
dnl
dnl GTK+
dnl
config_gtk=no
config_gtk_version=none
if test "x$PLATFORM_OS_WINDOWS" != "xyes"
then
PKG_CHECK_MODULES(GTK,
glib-2.0 >= 2.28.0
gio-2.0 >= 2.26.0
gtk+-3.0 >= 3.0.0
gdk-3.0 >= 3.0.0
sigc++-2.0 >= 2.2.4.2
glibmm-2.4 >= 2.28.0
gtkmm-3.0 >= 3.0.0,
[config_gtk=yes
config_gtk_version=3
AC_DEFINE(HAVE_GTK3, 1, Support for GTK3)
AC_DEFINE([HAVE_APP_GTK], , [Define if GTK+ is available])], [ ] )
fi
if test x$config_gtk = xno
then
PKG_CHECK_MODULES(GTK,
gtk+-2.0 >= 2.6.0 \
gdk-2.0 >= 2.8 \
sigc++-2.0 \
glibmm-2.4 >= 2.10 \
gtkmm-2.4 >= 2.10,
[config_gtk=yes
config_gtk_version=2
AC_DEFINE([HAVE_APP_GTK], , [Define if GTK+ is available])])
fi
AM_CONDITIONAL(HAVE_APP_GTKMM, test $config_gtk = yes)
AM_CONDITIONAL(HAVE_GTK3, test "x$config_gtk_version" = "x3")
dnl
dnl Introspection
dnl
if test "x$PLATFORM_OS_WINDOWS" != "xyes"
then
GOBJECT_INTROSPECTION_CHECK([0.6.7])
else
AM_CONDITIONAL(HAVE_INTROSPECTION, false)
fi
dnl
dnl Indicator applet
dnl
config_indicator=no
config_indicator_package=none
INDICATOR_REQUIRED_VERSION=0.3.19
DBUSMENUGLIB_REQUIRED_VERSION=0.1.1
DBUSMENUGTK_REQUIRED_VERSION=0.3.95
if test "x$enable_indicator" != "xno" -a "x$config_gtk_version" = "x3"
then
if test "x$found_introspection" != "xyes"
then
AC_MSG_ERROR([Introspection development headers not found.])
else
PKG_CHECK_MODULES(INDICATOR, ayatana-indicator3-0.4 >= $INDICATOR_REQUIRED_VERSION
dbusmenu-glib-0.4 >= $DBUSMENUGLIB_REQUIRED_VERSION
dbusmenu-gtk3-0.4 >= $DBUSMENUGTK_REQUIRED_VERSION,
[ config_indicator=yes
config_indicator_package=ayatana-indicator3-0.4
AC_DEFINE(HAVE_INDICATOR, 1, [Support for indicator applet])
AC_DEFINE(HAVE_INDICATOR_AYATANA, 1, [Support for ayatana indicator applet])
],
[ PKG_CHECK_MODULES(INDICATOR, indicator3-0.4 >= $INDICATOR_REQUIRED_VERSION
dbusmenu-glib-0.4 >= $DBUSMENUGLIB_REQUIRED_VERSION
dbusmenu-gtk3-0.4 >= $DBUSMENUGTK_REQUIRED_VERSION,
[ config_indicator=yes
config_indicator_package=indicator3-0.4
AC_DEFINE(HAVE_INDICATOR, 1, [Support for indicator applet])],
[if test "x$enable_indicator" = "xyes"; then
AC_MSG_ERROR([Indicator development headers not found.])
fi])
])
if test "x$config_indicator" != "xno"
then
PKG_CHECK_EXISTS(dbusmenu-gtk3-0.4 >= 0.5.90,
[ AC_DEFINE(HAVE_DBUSMENU_NEW_INCLUDES, 1, [DBusmenu header in new location])],
[ true ]
)
fi
fi
fi
with_localinstall="no"
AC_ARG_ENABLE(localinstall, AS_HELP_STRING([--enable-localinstall], [install all of the files localy instead of system directories (for distcheck)]), with_localinstall=$enableval, with_localinstall=no)
AS_IF([test "x$with_localinstall" = "xyes" -a "x$config_indicator_package" != "xnone"],
INDICATORDIR="${libdir}/indicators3/7"
INDICATORICONSDIR="${datadir}/libindicate/icons"
,
INDICATORDIR=`$PKG_CONFIG --variable=indicatordir $config_indicator_package | sed -e 's%/$%%'`
INDICATORICONSDIR=`$PKG_CONFIG --variable=iconsdir $config_indicator_package`
)
AM_CONDITIONAL(LOCALINSTALL, test "x$with_localinstall" = "xyes")
AC_SUBST(INDICATORDIR)
AC_SUBST(INDICATORICONSDIR)
AC_SUBST(INDICATORDIR)
AC_SUBST(INDICATORICONSDIR)
AM_CONDITIONAL(HAVE_INDICATOR, test "x$config_indicator" = "xyes")
dnl
dnl Xfce
dnl
config_xfce=no
config_xfce_gtk_version=none
if test "x$enable_xfce" != "xno"
then
PKG_CHECK_MODULES([LIBXFCE4PANEL],
[libxfce4panel-2.0 >= 4.12],
[config_xfce=yes
config_xfce_gtk_version=3
AC_DEFINE(HAVE_XFCE, 1, [Support for xfce applet])
AC_DEFINE(HAVE_XFCE_GTK3, 1, [Support for xfce applet])
],
[ true ])
if test x$config_xfce != xyes
then
PKG_CHECK_MODULES([LIBXFCE4PANEL],
[libxfce4panel-1.0 >= 4.4],
[config_xfce=yes
config_xfce_gtk_version=2
AC_DEFINE(HAVE_XFCE, 1, [Support for xfce applet])
AC_DEFINE(HAVE_XFCE_GTK2, 1, [Support for xfce applet])
],
[if test "x$enable_xfce" = "xyes"; then
AC_MSG_ERROR([XFCE Panel applet development headers not found.])
fi])
fi
fi
AM_CONDITIONAL(HAVE_XFCE, test "x$config_xfce" = "xyes")
AM_CONDITIONAL(HAVE_XFCE_GTK2, test "x$config_xfce_gtk_version" = "x2")
AM_CONDITIONAL(HAVE_XFCE_GTK3, test "x$config_xfce_gtk_version" = "x3")
dnl
dnl Mate
dnl
config_mate=no
if test "x$enable_mate" != "xno"
then
PKG_CHECK_MODULES([LIBMATEPANEL],
[libmatepanelapplet-4.0],
[config_mate=yes
AC_DEFINE(HAVE_MATE, 1, [Support for mate applet])],
[if test "x$enable_mate" = "xyes"; then
AC_MSG_ERROR([MATE Panel applet development headers not found.])
fi])
config_mate_gtk_version=none
if test "x$config_mate" = "xyes"
then
MATE_GTK=`$PKG_CONFIG --print-requires libmatepanelapplet-4.0 2>/dev/null | grep -m 1 '^gtk+-'`
case "$MATE_GTK" in
gtk+-2*)
config_mate_gtk_version=2
;;
gtk+-3*)
config_mate_gtk_version=3
;;
esac
fi
fi
AM_CONDITIONAL(HAVE_MATE, test "x$config_mate" = "xyes")
AM_CONDITIONAL(HAVE_MATE_GTK2, test "x$config_mate_gtk_version" = "x2")
AM_CONDITIONAL(HAVE_MATE_GTK3, test "x$config_mate_gtk_version" = "x3")
if test "x$config_mate_gtk_version" = "x2" -o "x$config_xfce_gtk_version" = "x2"
then
PKG_CHECK_MODULES([GTK2],
[gtk+-2.0 >= 2.6.0 gdk-2.0 >= 2.8 ],
[config_gtk2=yes
AC_DEFINE(HAVE_GTK2, 1, [Support for GTK2])],
[AC_MSG_ERROR([GTK2 development headers not found.])])
fi
AM_CONDITIONAL(HAVE_GTK2, test "x$config_gtk2" = "xyes")
dnl
dnl GConf
dnl
config_gconf=no
if test "x$enable_gconf" != "xno" -a "x$config_gnome3" != "xyes"
then
PKG_CHECK_MODULES([GCONF],
[gconf-2.0 >= 2.31.1],
[config_gconf=yes
AC_DEFINE([HAVE_GCONF], , [Define if GConf is available])],
[if test "x$enable_gconf" = "xyes"; then
AC_MSG_ERROR([GConf development headers not found.])
fi])
fi
AM_CONDITIONAL(HAVE_GCONF, test "x$config_gconf" = "xyes")
dnl
dnl XML
dnl
config_xml=no
if test "x$enable_xml" != "xno"
then
PKG_CHECK_MODULES([GDOME],
[gdome2],
[config_xml=yes
AC_DEFINE([HAVE_GDOME], ,[Define if GDome is available])],
[if test "x$enable_xml" = "xyes"; then
AC_MSG_ERROR([GDome2 development headers not found.])
fi])
fi
AM_CONDITIONAL(HAVE_GDOME, test "x$config_xml" = "xyes")
dnl
dnl GIO/GNet2 networking
dnl
config_distribution=no
have_gnet=no
if test "x$enable_distribution" != "xno"
then
PKG_CHECK_MODULES([GIO],
[gio-2.0 >= 2.22.0],
[config_distribution=yes
AC_DEFINE(HAVE_GIO_NET, 1, [Have GIO networking support])],
[PKG_CHECK_MODULES([GNET],
[gnet-2.0],
[config_distribution=yes
have_gnet=yes
AC_DEFINE([HAVE_GNET], , [Define if GNet is available])
AC_DEFINE([HAVE_GNET2], , [Define if GNet2 is available])],
[if test "x$enable_distribution" = "xyes"; then
AC_MSG_ERROR([GIO/GNet development headers not found.])
fi])])
fi
if test $config_distribution = yes
then
AC_DEFINE([HAVE_DISTRIBUTION], , [Define if network-distributed operation is available])
fi
AM_CONDITIONAL(HAVE_DISTRIBUTION, test "x$config_distribution" = "xyes")
AM_CONDITIONAL(HAVE_GNET, test $have_gnet = yes)
dnl
dnl GStreamer
dnl
config_gstreamer=no
if test "x$enable_gstreamer" != "xno";
then
PKG_CHECK_MODULES([GSTREAMER],
[gstreamer-0.10],
[config_gstreamer=yes
AC_DEFINE(HAVE_GSTREAMER, 1, [Use GStreamer for playing sounds])], [ ])
if test "x$config_gstreamer" != "xyes";
then
PKG_CHECK_MODULES([GSTREAMER],
[gstreamer-1.0],
[config_gstreamer=yes
AC_DEFINE(HAVE_GSTREAMER, 1, [Use GStreamer for playing sounds])],
[if test "x$enable_gstreamer" = "xyes"; then
AC_MSG_ERROR([GStreamer development headers not found.])
fi])
fi
fi
dnl
dnl PulseAudio
dnl
config_pulse=no
if test "$platform_os_unix" = "yes" -a "x$enable_pulse" != "xno"
then
PA_REQUIRED_VERSION=0.9.15
PKG_CHECK_MODULES([PULSE],
[glib-2.0 libpulse >= $PA_REQUIRED_VERSION libpulse-mainloop-glib >= $PA_REQUIRED_VERSION],
[config_pulse=yes
AC_DEFINE(CONFIG_PULSE, 1, [Define if PULSE sound server should be used])],
[if test "x$enable_pulse" = "xyes"; then
AC_MSG_ERROR([Pulseaudio development headers not found.])
fi])
fi
AM_CONDITIONAL(CONFIG_PULSE, test "x$config_pulse" = "xyes")
dnl
dnl Internationalization
dnl
AM_GNU_GETTEXT_VERSION([0.18])
AM_GNU_GETTEXT([external])
dnl Hack because windows gettext package is SEVERELY broken...
if test "x$PLATFORM_OS_WINDOWS" = "xyes"
then
USE_NLS=yes
AC_DEFINE(ENABLE_NLS,1,[Define to 1 if translation of program messages to the user's native language is requested.])
AC_DEFINE(USE_INCLUDED_LIBINTL, "no", [Dont])
AC_DEFINE(BUILD_INCLUDED_LIBINTL, "no", [Dont])
USE_INCLUDED_LIBINTL=no
BUILD_INCLUDED_LIBINTL=no
fi
GETTEXT_PACKAGE=workrave
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Define to the gettext domain name.])
IT_PROG_INTLTOOL([0.40.0])
dnl
dnl Manual
dnl
dnl (taken from clutter)
dnl
AC_ARG_ENABLE(manual,
AS_HELP_STRING([--enable-manual],
[Build user manual. Requires jw and xmlto binaries.]))
if test "x$enable_manual" = "xyes"; then
AC_PATH_PROG(JW, jw, no)
if test "x$JW" = "xno"; then
AC_MSG_ERROR(['jw' program needed by the manual not found in path])
fi
AC_PATH_PROG(XMLTO, xmlto, no)
if test "x$XMLTO" = "xno"; then
AC_MSG_ERROR(['xmlto' program needed by the manual not found in path])
fi
fi
AM_CONDITIONAL(ENABLE_MANUAL, test "x$enable_manual" = "xyes")
dnl
dnl What variant to build
dnl
variant=""
if test "x$PLATFORM_OS_WINDOWS" = "xyes"
then
variant="$variant win32"
elif test "x$PLATFORM_OS_MACOS" = "xyes"
then
variant="$variant macos unix"
elif test "x$platform_os_unix" = "xyes"
then
variant="$variant x11 unix"
fi
WR_BACKEND_INCLUDES="-I\$(top_srcdir)/backend/include"
WR_COMMON_INCLUDES="-I\$(top_srcdir)/common/include -I\$(top_srcdir)/libs/dbus/include"
WR_FRONTEND_COMMON_INCLUDES="-I\$(top_srcdir)/frontend/common/include"
for v in $variant; do
if test -d common/src/$v
then
WR_COMMON_INCLUDES="$WR_COMMON_INCLUDES -I\$(top_srcdir)/common/include/$v"
fi
done
WR_LDADD="-lworkrave-backend -lworkrave-frontend-common -lworkrave-common"
if test "x$config_dbus" = "xyes"; then
WR_LDADD="$WR_LDADD -lworkrave-dbus"