build.gradle

import java.util.stream.Collectors

buildscript {
    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
        gradlePluginPortal() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }

    dependencies {
        classpath 'com.gradle.publish:plugin-publish-plugin:1.2.1'
        classpath 'com.palantir.baseline:gradle-baseline-java:5.61.0'
        classpath 'com.palantir.gradle.consistentversions:gradle-consistent-versions:2.23.0'
        classpath 'com.palantir.gradle.externalpublish:gradle-external-publish-plugin:1.15.0'
        classpath 'com.palantir.gradle.gitversion:gradle-git-version:3.1.0'
        classpath 'com.palantir.jakartapackagealignment:jakarta-package-alignment:0.6.0'
        classpath 'com.palantir.javaformat:gradle-palantir-java-format:2.32.0'
        classpath 'gradle.plugin.org.inferred:gradle-processors:3.7.0'
    }
}

apply plugin: 'com.palantir.external-publish'
apply plugin: 'java-gradle-plugin'
apply plugin: 'groovy'
apply plugin: 'com.palantir.baseline'
apply plugin: 'com.palantir.git-version'
apply plugin: 'com.palantir.consistent-versions'
apply plugin: 'com.palantir.external-publish-jar'
apply plugin: 'com.palantir.external-publish-gradle-plugin'

dependencies {
    implementation 'org.revapi:revapi-basic-features'
    implementation 'org.revapi:revapi-java'
    implementation 'org.revapi:revapi-reporter-text'
    implementation 'org.freemarker:freemarker'
    implementation 'com.fasterxml.jackson.core:jackson-databind'
    implementation 'com.fasterxml.jackson.dataformat:jackson-dataformat-yaml'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jdk8'
    implementation 'com.google.guava:guava'

    testImplementation platform('org.junit:junit-bom')
    testImplementation 'com.netflix.nebula:nebula-test'
    testImplementation "org.junit.jupiter:junit-jupiter"
    testImplementation 'org.mockito:mockito-core'
    testImplementation 'org.assertj:assertj-core'
    testRuntimeOnly "org.junit.vintage:junit-vintage-engine"

    annotationProcessor "org.immutables:value"
    annotationProcessor "org.immutables:serial"
    compileOnly "org.immutables:value::annotations"
    compileOnly "org.immutables:serial"
}

allprojects {
    apply plugin: 'com.palantir.java-format'
    apply plugin: 'com.palantir.jakarta-package-alignment'
    apply plugin: 'org.inferred.processors'

    repositories {
        mavenCentral() { metadataSources { mavenPom(); ignoreGradleMetadataRedirection() } }
    }

    group 'com.palantir.gradle.revapi'
    version System.env.CIRCLE_TAG ?: gitVersion()
    sourceCompatibility = 1.8
}

test {
    environment = System.getenv().entrySet().stream()
            .filter { entry -> entry.key != 'CIRCLE_TEST_REPORTS' }
            .collect(Collectors.toMap({ it.key }, { it.value }))
}

gradlePlugin {
    plugins {
        revapi {
            id = 'com.palantir.revapi'
            implementationClass = 'com.palantir.gradle.revapi.RevapiPlugin'
            description = 'API/ABI backwards compatibility for Java libraries using Revapi'
            displayName = 'API/ABI backwards compatibility for Java libraries using Revapi'
        }
    }
}

pluginBundle {
    website = 'https://github.com/palantir/gradle-revapi'
    vcsUrl = 'https://github.com/palantir/gradle-revapi'
    description = 'API/ABI backwards compatibility for Java libraries using Revapi'
    tags = ['java', 'versions']
}

tasks.named('processResources').configure {
    duplicatesStrategy 'include'
}

tasks.publish.dependsOn tasks.publishPlugins
publishPlugins.onlyIf {
    versionDetails().isCleanTag
}
project.ext.'gradle.publish.key' = System.env["GRADLE_KEY"]
project.ext.'gradle.publish.secret' = System.env["GRADLE_SECRET"]