memcpy not working when creating new Tensor inside swap

[AlienKevin]

I'm experimenting with swaping the content of two tensors.

When I create a new tmp tensor inside swap, its content is not overwritten by A after calling memcpy.

from tensor import TensorShape
from memory import memcpy

alias t = DType.float32

fn swap(A: Tensor[t], B: Tensor[t]):
    var tmp = Tensor[t](TensorShape(5))
    memcpy(tmp.data(), A.data(), 5)
    memcpy(A.data(), B.data(), 5)
    memcpy(B.data(), tmp.data(), 5)

fn main():
    var A = Tensor[t](TensorShape(5), 1, 2, 3, 4, 5)
    var B = Tensor[t](TensorShape(5), 6, 7, 8, 9, 10)

    print(A)
    print(B)

    swap(A, B)

    print(A)
    print(B)

prints:

Tensor([[1.0, 2.0, 3.0, 4.0, 5.0]], dtype=float32, shape=5)
Tensor([[6.0, 7.0, 8.0, 9.0, 10.0]], dtype=float32, shape=5)
Tensor([[6.0, 7.0, 8.0, 9.0, 10.0]], dtype=float32, shape=5)
Tensor([[0.0, 0.0, 0.0, 0.0, 0.0]], dtype=float32, shape=5)

However, when I pass in a tmp tensor as argument, it works:

from tensor import TensorShape
from memory import memcpy

alias t = DType.float32

fn swap(tmp: Tensor[t], A: Tensor[t], B: Tensor[t]):
    memcpy(tmp.data(), A.data(), 5)
    memcpy(A.data(), B.data(), 5)
    memcpy(B.data(), tmp.data(), 5)

fn main():
    var A = Tensor[t](TensorShape(5), 1, 2, 3, 4, 5)
    var B = Tensor[t](TensorShape(5), 6, 7, 8, 9, 10)

    print(A)
    print(B)

    var tmp = Tensor[t](TensorShape(5))
    swap(tmp, A, B)

    print(A)
    print(B)

Prints:

Tensor([[1.0, 2.0, 3.0, 4.0, 5.0]], dtype=float32, shape=5)
Tensor([[6.0, 7.0, 8.0, 9.0, 10.0]], dtype=float32, shape=5)
Tensor([[6.0, 7.0, 8.0, 9.0, 10.0]], dtype=float32, shape=5)
Tensor([[1.0, 2.0, 3.0, 4.0, 5.0]], dtype=float32, shape=5)

[soraros]

.data() is unsafe API, and tmp is destroyed before your memcpy due to Mojo's ASAP destruction. Can be fixed by retaining tmp with _ = tmp.

fn swap(A: Tensor[t], B: Tensor[t]):
    var tmp = Tensor[t](5)
    memcpy(tmp.data(), A.data(), 5)
    memcpy(A.data(), B.data(), 5)
    memcpy(B.data(), tmp.data(), 5)
   _ = tmp

There are other ways to write this code. The following is slightly better:

from memory.unsafe import DTypePointer

fn swap(A: inout Tensor[t], B: inout Tensor[t]):
    var tmp = DTypePointer[t].alloc(5)
    memcpy(tmp, A.data(), 5)
    memcpy(A.data(), B.data(), 5)
    memcpy(B.data(), tmp, 5)
    tmp.free()

I think the best option is to use swap from the stdlib:

from algorithm.swap import swap

[AlienKevin]

Thanks that makes sense! For the second snippet you showed, do we need to manually free the tmp variable at the end of swap?

[AlienKevin]

The algorithm.swap method looks awesome. However, I will need finer control over which portion of the tensor is swapped (like swapping two rows of the same tensor etc). So I guess I still need to use memcpy right now?

[soraros]

For the second snippet you showed, do we need to manually free the tmp variable at the end of swap?

Ah, right. I think you do. Such is the ergonomics of unsafe API.

So I guess I still need to use memcpy right now?

I guess so.