build.gradle

plugins {
    id "io.franzbecker.gradle-lombok" version "4.0.0"
}

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'signing'


sourceCompatibility = "1.8"
targetCompatibility = "1.8"

dependencies {
    implementation('com.squareup:javapoet:1.13.0')
    implementation('com.google.guava:guava:24.1-jre')
    implementation project(':delivery-sdk')

    testImplementation("junit:junit:4.13.1");
    testImplementation("org.apache.httpcomponents:httpclient:4.5.13:tests");
    testImplementation("org.apache.httpcomponents:httpclient:4.5.13");
}

lombok {
    version = "1.18.16"
    sha256 = ""
}

task sourcesJar(type: Jar, dependsOn: classes) {
    archiveClassifier = 'sources'
    from sourceSets.main.allJava
}

import io.franzbecker.gradle.lombok.task.DelombokTask
task delombok(type: DelombokTask, dependsOn: compileJava) {
    ext.outputDir = file("$buildDir/delombok")
    outputs.dir(outputDir)
    sourceSets.main.java.srcDirs.each { dir ->
        inputs.dir(dir)
        args(dir, "-d", outputDir)
    }
}

javadoc {
    dependsOn delombok
    source = delombok.outputDir
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

def packageSummary = 'Kontent.ai model generator.'
def packageDescription = 'Generators producing strongly-typed models based on content types in a Kontent.ai project.'
def repoArtifactId = 'delivery-sdk-generators'


publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifact sourcesJar
            artifact javadocJar
            artifactId = repoArtifactId
            groupId = repoGroupId
            versionMapping {
                usage('java-api') {
                    fromResolutionOf('runtimeClasspath')
                }
                usage('java-runtime') {
                    fromResolutionResult()
                }
            }
            pom.withXml {
                def root = asNode()
                root.appendNode('description', packageDescription)
                root.appendNode('name', packageSummary)
                root.appendNode('url', 'https://kontent.ai')
                root.children().last() + pomConfig
            }
        }
    }
    repositories {
        maven {
            if (project.getVersion().toString().endsWith('SNAPSHOT')) {
                url "https://s01.oss.sonatype.org/content/repositories/snapshots/"
            } else {
                url "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
            }

            credentials {
                username nexusUsername
                password nexusPassword
            }
        }
    }
}

signing {
    // https://docs.gradle.org/current/userguide/signing_plugin.html#using_in_memory_ascii_armored_openpgp_subkeys
    useInMemoryPgpKeys(signingKeyId, signingKey, signingPassword)
    sign publishing.publications.mavenJava
}