build.gradle

plugins {
	id 'fabric-loom' version '0.4-SNAPSHOT'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

configurations {
	embed
}

configurations.all {
	exclude group: 'com.mojang', module: 'datafixerupper'
}

dependencies {
	//to change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	compile project(":DataFixerUpper")
	embed project(":DataFixerUpper")
}

processResources {
	inputs.property "version", project.version

	from(sourceSets.main.resources.srcDirs) {
		include "fabric.mod.json"
		expand "version": project.version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude "fabric.mod.json"
	}
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
	options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
	classifier = "sources"
	from sourceSets.main.allSource
}

task cleanupLibraries(type:Delete) {
	delete "$buildDir/shaded"
}

task copyLibraries(type: Copy) {
	from { configurations.embed.filter { f -> f.name.startsWith("DataFixer") } }
	into "$buildDir/shaded/META-INF/jar-replacements"

	dependsOn cleanupLibraries
}

jar {
	from "LICENSE.txt"
	from "$buildDir/shaded"

	dependsOn copyLibraries
}