build.gradle

plugins {
    id 'java'
    id 'jacoco'
    id 'maven'
}

group 'org.iotlabs'
version '0.0.2'

sourceCompatibility = 1.8

repositories {
    mavenCentral()
    maven {
        url "https://repo.eclipse.org/content/repositories/paho-snapshots/"
    }
    // for Iot Labs repository
    maven {
        url "http://13.76.209.35:8081/nexus/content/repositories/dev/"
    }
}

dependencies {
    testCompile group: 'junit', name: 'junit', version: '4.11'
    compile group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.7'
    compile group: 'org.apache.logging.log4j', name: 'log4j-core', version: '2.7'
    compile 'org.eclipse.paho:org.eclipse.paho.client.mqttv3:1.0.2'
    compile 'com.google.code.gson:gson:2.7'
}


task makejar (type: Jar) {
    destinationDir = file("$rootDir/")
    from { configurations.compile.collect { it.isDirectory() ? it : zipTree(it) } }
    with jar
}

uploadArchives {
    if (project.hasProperty("mavenUser")) {
        repositories {
            mavenDeployer {
                repository(url: "http://13.76.209.35:8081/nexus/content/repositories/dev/") {
                    authentication(userName: "$mavenUser", password: "$mavenPassword")
                }
                pom.version = "${project.version}"
                pom.artifactId = "${project.name}"
                pom.groupId = "org.iotlabs"
            }
        }
    }
}

jacoco {
    toolVersion = "0.7.6.201602180812"
}
jacocoTestReport  {
    group = "Reporting"
    description = "Generate Jacoco coverage reports after running tests."
    reports {
        xml{
            enabled true
        }
    }
}

check.dependsOn jacocoTestReport