-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathds3231rtc.asm
208 lines (160 loc) · 3.41 KB
/
ds3231rtc.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
;----[ ds3231rtc.asm ]------------------
;DS3231 RTC over i2c6502 for C64
;Copyright (c) 2020 Greg Nacu
*= $0801
.word end ;next line ptr
.word 64 ;basic line #64
.byte $9e ;sys
.null "2061" ;$080d
end .word $00 ;end of basic
doset = 0
i2cbase = $2000
init_ = 0
reset_ = 3
prep_rw_ = 6
readreg_ = 9
writreg_ = 12
ds3231addr = $68
dssecsreg = $00
chrout = $ffd2
;-----------------------
;--[ main ]-------------
;-----------------------
jsr i2cbase+init_
.ifne doset
beq settime
.endif
.ifeq doset
beq gettime
.endif
ldx #<errmsg_init
ldy #>errmsg_init
jmp msg_out
.ifne doset
settime ldx #<dss_secs
ldy #>dss_secs
lda #dss_size
jsr i2cbase+prep_rw_
lda #ds3231addr
ldy #dssecsreg
jsr i2cbase+writreg_
beq showsetmsg
ldx #<errmsg_sett
ldy #>errmsg_sett
jmp msg_out
showsetmsg
ldx #<msg_settime
ldy #>msg_settime
jmp msg_out
.endif
.ifeq doset
gettime ldx #<dss_secs
ldy #>dss_secs
lda #dss_size
jsr i2cbase+prep_rw_
lda #ds3231addr
ldy #dssecsreg
clc ;don't skip reg write
jsr i2cbase+readreg_
beq showtime
ldx #<errmsg_time
ldy #>errmsg_time
jmp msg_out
showtime
ldx #<msg_curt
ldy #>msg_curt
jsr msg_out
lda dss_date
jsr bcd_out
lda #"/"
jsr chrout
lda dss_mon
jsr bcd_out
lda #"/"
jsr chrout
lda dss_year
jsr bcd_out
lda #" "
jsr chrout
lda dss_hrs
jsr bcd_out
lda #":"
jsr chrout
lda dss_mins
jsr bcd_out
lda #":"
jsr chrout
lda dss_secs
jsr bcd_out
lda #" "
jsr chrout
ldx #<msg_wd
ldy #>msg_wd
jsr msg_out
lda dss_dow
jmp bcd_out
.endif
;-----------------------
;--[ print msgs ]-------
;-----------------------
bcd_out ;A -> number in bcd
pha
lsr a
lsr a
lsr a
lsr a
clc
adc #$30;convert to petscii
jsr chrout
pla
and #$0f
clc
adc #$30;convert to petscii
jmp chrout
msg_out
.block
;RegPtr -> message
stx $fb
sty $fc
ldy #0
loop lda ($fb),y
beq done
jsr chrout
iny
bne loop
done rts
.bend
msg_curt .null "current time: "
msg_wd .null "wd: "
msg_settime
.null "rtc time has been set"
errmsg_init
.null "failed to init i2c bus"
errmsg_time
.null "failed to get rtc time"
errmsg_sett
.null "failed to set rtc time"
;----------------------
;--[ data structure ]---
;-----------------------
;ds seconds register struct
.ifne doset
;Set values must be in BCD
dss_secs .byte $00
dss_mins .byte $01
dss_hrs .byte $02
dss_dow .byte $03
dss_date .byte $25
dss_mon .byte $06
dss_year .byte $81
.endif
.ifeq doset
dss_secs .byte 0
dss_mins .byte 0
dss_hrs .byte 0
dss_dow .byte 0
dss_date .byte 0
dss_mon .byte 0
dss_year .byte 0
.endif
dss_size = 7