build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.3.2'
    id 'io.spring.dependency-management' version '1.1.4'
    id "org.sonarqube" version "4.0.0.2929"
    id 'checkstyle'
    id 'jacoco'
}

group = 'org.dnd'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.2.0'
    implementation("org.springframework.boot:spring-boot-devtools")
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'
    implementation 'com.google.firebase:firebase-admin:9.2.0'
    implementation 'org.springframework.boot:spring-boot-starter-websocket'


    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    runtimeOnly("com.h2database:h2")

    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.security:spring-security-test'
    testRuntimeOnly 'com.h2database:h2'

    // third-party
    implementation group: 'com.auth0', name: 'java-jwt', version: '4.3.0'

}

tasks.named('test') {
    useJUnitPlatform()
}

sonar {
    properties {
        property "sonar.projectKey", "dnd-10th-2-backend"
    }
}

checkstyle {
    toolVersion '10.13.0'
    configFile file("${project.rootDir}/config/checkstyle-config.xml")
}

jacoco {
    toolVersion = '0.8.11'
}

jacocoTestReport {
    reports {
        html {
            required.set(true)
            outputLocation.set(file("build/reports/jacocoHtml"))
        }
        xml.required.set(false)
        csv.required.set(false)
    }
}

jacocoTestCoverageVerification {

    violationRules {
        rule {
            element = 'CLASS'

            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.30 // 30% 이상 커버리지가 되어야 빌드 성공
            }
        }
    }
}