-
Notifications
You must be signed in to change notification settings - Fork 22
/
Copy pathpage2tei-0.xsl
1219 lines (1151 loc) · 49.3 KB
/
page2tei-0.xsl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
<?xml version="1.0" encoding="UTF-8"?><xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
xmlns="http://www.tei-c.org/ns/1.0" xmlns:tei="http://www.tei-c.org/ns/1.0"
xmlns:p="http://schema.primaresearch.org/PAGE/gts/pagecontent/2013-07-15"
xmlns:pc="http://schema.primaresearch.org/PAGE/gts/pagecontent/2019-07-15"
xmlns:mets="http://www.loc.gov/METS/" xmlns:xlink="http://www.w3.org/1999/xlink"
xmlns:map="http://www.w3.org/2005/xpath-functions/map" xmlns:local="local"
xmlns:xstring="https://github.com/dariok/XStringUtils" exclude-result-prefixes="#all"
version="3.0">
<xsl:output indent="0"/>
<xsl:variable name="langs" select="map { 'French': 'fr', 'German': 'de', 'English': 'en', 'Latin': 'la',
'Spanish': 'es', 'Ancient Greek': 'grc' }"/>
<xsl:include href="combine-hi.xsl" />
<xd:doc>
<xd:desc>Page XML parameter 'PAGEXML' with which ID and USE definition is referenced in the mets:fileGrp to the PAGE xml files.</xd:desc>
</xd:doc>
<xsl:param name="PAGEXML" select="'PAGEXML'" />
<xd:doc>
<xd:desc>Whether to create `rs type="..."` for person/place/org (default) or `persName` etc.
(false())</xd:desc>
</xd:doc>
<xsl:param name="rs" select="true()"/>
<xd:doc>
<xd:desc>Whether to run white space tokenization</xd:desc>
</xd:doc>
<xsl:param name="tokenize" select="false()"/>
<xsl:include href="tokenize.xsl" />
<xd:doc>
<xd:desc>Whether to combine entities over line breaks</xd:desc>
</xd:doc>
<xsl:param name="combine" select="false()"/>
<xsl:include href="combine-continued.xsl" />
<xd:doc>
<xd:desc>If false(), region types that correspond to valid TEI elements will be returned as
this element; types that do not correspond to a TEI element will be returned as
tei:ab[@type]. If set to true(), all region types (except for paragraph, heading) will be
returned as tei:ab.</xd:desc>
</xd:doc>
<xsl:param name="ab" select="false()"/>
<xd:doc>
<xd:desc>If true(), export the (estimated) word coordinates to the facsimile section. Default:
false().</xd:desc>
</xd:doc>
<xsl:param name="word-coordinates" select="false()"/>
<xd:doc>
<xd:desc>Whether to create bounding rectangles from polygons (default: true())</xd:desc>
</xd:doc>
<xsl:param name="bounding-rectangles" select="true()"/>
<xsl:include href="simplify-coordinates.xsl" />
<xd:doc>
<xd:desc>Whether to export lines without baseline (true()) or not (false(), default)</xd:desc>
</xd:doc>
<xsl:param name="withoutBaseline" select="false()"/>
<xd:doc>
<xd:desc>Whether to export regions without text lines (true()) or not (false(),
default)</xd:desc>
</xd:doc>
<xsl:param name="withoutTextline" select="false()"/>
<xd:doc>
<xd:desc>Whether to export custom attributes from tags that we do not know how to convert to valid TEI (true(),
default) or whether to discard them (false()).</xd:desc>
</xd:doc>
<xsl:param name="unknownAttributes" select="true()" />
<xd:doc scope="stylesheet">
<xd:desc>
<xd:p><xd:b>Author:</xd:b> Dario Kampkaspar, [email protected] |
[email protected]</xd:p>
<xd:p>Austrian Centre for Digital Humanities http://acdh.oeaw.ac.at | University and State
Library Darmstadt https://ulb.tu-darmstadt.de</xd:p>
<xd:p/>
<xd:p>This stylesheet, when applied to mets.xml of the PAGE output, will create (valid)
TEI</xd:p>
<xd:p>While this XSLT is designed to run on many different flavours of PAGE-XMLs described
by a common mets.xml file, some special care was taken to include meta data provided by
Transkribus; other meta data providers may be included if examples are provided.</xd:p>
<xd:p/>
<xd:p><xd:b>Contributor</xd:b> Matthias Boenig, github:@tboenig</xd:p>
<xd:p>OCR-D, Berlin-Brandenburg Academy of Sciences and Humanities
http://ocr-d.de/eng</xd:p>
<xd:p>extend the original XSL-Stylesheet by specific elements based on the @typing of the
text region</xd:p>
<xd:p/>
<xd:p><xd:b>Contributor</xd:b> Peter Stadler, github:@peterstadler</xd:p>
<xd:p>Carl-Maria-von-Weber-Gesamtausgabe</xd:p>
<xd:p>Added corrections to tei:sic/tei:corr</xd:p>
<xd:p/>
<xd:p><xd:b>Contributor</xd:b> Till Grallert, github:@tillgrallert</xd:p>
<xd:p>Orient-Institut Beirut</xd:p>
<xd:p>Use tei:ab as fallback instead of tei:p</xd:p>
</xd:desc>
</xd:doc>
<!-- use extended string functions from https://github.com/dariok/XStringUtils -->
<xsl:include href="string-pack.xsl"/>
<xsl:param name="debug" select="false()"/>
<xd:doc>
<xd:desc>Entry</xd:desc>
</xd:doc>
<xsl:template match="/">
<xsl:apply-templates select="mets:mets" />
</xsl:template>
<xd:doc>
<xd:desc>helper: gather page contents</xd:desc>
</xd:doc>
<xsl:variable name="make_div">
<div>
<xsl:apply-templates select="//mets:fileSec//mets:fileGrp[(@ID, @USE) = $PAGEXML]/mets:file" mode="text" />
</div>
</xsl:variable>
<xd:doc>
<xd:desc>Entry point: start at the top of METS.xml</xd:desc>
</xd:doc>
<xsl:template match="/mets:mets">
<TEI>
<xsl:text>
</xsl:text>
<teiHeader>
<xsl:text>
</xsl:text>
<fileDesc>
<xsl:text>
</xsl:text>
<titleStmt>
<xsl:apply-templates select="mets:amdSec" mode="titleStmt"/>
<xsl:text>
</xsl:text>
</titleStmt>
<xsl:text>
</xsl:text>
<publicationStmt>
<xsl:apply-templates select="mets:amdSec" mode="publicationStmt"/>
</publicationStmt>
<xsl:text>
</xsl:text>
<sourceDesc>
<xsl:text>
</xsl:text>
<bibl>
<xsl:apply-templates select="mets:amdSec" mode="sourceDesc"/>
</bibl>
<xsl:text>
</xsl:text>
</sourceDesc>
<xsl:text>
</xsl:text>
</fileDesc>
<xsl:text>
</xsl:text>
<profileDesc>
<xsl:apply-templates select="descendant::*:trpDocMetadata/*:language" />
<xsl:text>
</xsl:text>
</profileDesc>
<xsl:text>
</xsl:text>
</teiHeader>
<xsl:text>
</xsl:text>
<facsimile>
<xsl:choose>
<xsl:when test="$bounding-rectangles">
<xsl:variable name="facs">
<xsl:apply-templates select="mets:fileSec//mets:fileGrp[(@ID, @USE) = $PAGEXML]/mets:file" mode="facsimile"/>
</xsl:variable>
<xsl:apply-templates select="$facs" mode="bounding-rectangle" />
</xsl:when>
<xsl:otherwise>
<xsl:apply-templates select="mets:fileSec//mets:fileGrp[(@ID, @USE) = $PAGEXML]/mets:file" mode="facsimile"/>
</xsl:otherwise>
</xsl:choose>
<xsl:text>
</xsl:text>
</facsimile>
<xsl:text>
</xsl:text>
<text>
<xsl:text>
</xsl:text>
<body>
<xsl:for-each-group
select="$make_div//*[local-name() = 'div']/*"
group-starting-with="*[local-name() = 'pb' and following-sibling::*[1][local-name() = 'head']]
| *[local-name() = 'head' and not(preceding-sibling::*[1][local-name() = 'pb'])]"
>
<xsl:text>
</xsl:text>
<div xmlns="http://www.tei-c.org/ns/1.0">
<xsl:variable name="combined">
<xsl:choose>
<xsl:when test="$combine">
<xsl:apply-templates select="current-group()" mode="continued" />
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="current-group()" />
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="combined-hi">
<xsl:apply-templates select="$combined" mode="combine-hi" />
</xsl:variable>
<xsl:variable name="tokenized">
<xsl:choose>
<xsl:when test="$tokenize">
<xsl:apply-templates select="$combined-hi" mode="tokenize" />
</xsl:when>
<xsl:otherwise>
<xsl:copy-of select="$combined-hi" />
</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:for-each select="$tokenized/*">
<xsl:text>
</xsl:text>
<xsl:sequence select="." />
</xsl:for-each>
<xsl:text>
</xsl:text>
</div>
</xsl:for-each-group>
<xsl:text>
</xsl:text>
</body>
<xsl:text>
</xsl:text>
</text>
<xsl:text>
</xsl:text>
</TEI>
</xsl:template>
<!-- create teiHeader from METS and (if present) included Transkribus Meta data -->
<xd:doc>
<xd:desc>Contents for titleStmt</xd:desc>
</xd:doc>
<xsl:template match="mets:amdSec" mode="titleStmt">
<xsl:apply-templates select="descendant::trpDocMetadata/title"/>
<xsl:apply-templates select="descendant::trpDocMetadata/author"/>
</xsl:template>
<xd:doc>
<xd:desc>Contents for publicationStmt</xd:desc>
</xd:doc>
<xsl:template match="mets:amdSec" mode="publicationStmt">
<xsl:text>
</xsl:text>
<xsl:apply-templates select="descendant::trpDocMetadata//colList[1]/colName" />
<xsl:text>
</xsl:text>
</xsl:template>
<xd:doc>
<xd:desc>Contents for sourceDesc</xd:desc>
</xd:doc>
<xsl:template match="mets:amdSec" mode="sourceDesc">
<xsl:apply-templates select="descendant::trpDocMetadata/title"/>
<xsl:apply-templates
select="descendant::trpDocMetadata/author | descendant::trpDocMetadata/writer"/>
<xsl:text>
</xsl:text>
<idno type="Transkribus">
<xsl:value-of select="descendant::trpDocMetadata/docId"/>
</idno>
<xsl:text>
</xsl:text>
<xsl:apply-templates select="descendant::trpDocMetadata/externalId"/>
<xsl:apply-templates select="descendant::trpDocMetadata/desc"/>
</xsl:template>
<xd:doc>
<xd:desc>Contents for editionStmt</xd:desc>
</xd:doc>
<xsl:template match="mets:amdSec" mode="editionStmt">
<p>TRP document creator: <xsl:value-of select="descendant::trpDocMetadata/uploader"/></p>
<xsl:apply-templates select="mets:amdSec//trpDocMetadata/desc"/>
</xsl:template>
<!-- Templates for trpMetaData -->
<xd:doc>
<xd:desc>
<xd:p>The title within the Transkribus meta data</xd:p>
</xd:desc>
</xd:doc>
<xsl:template match="title">
<xsl:text>
</xsl:text>
<title>
<xsl:if test="position() = 1">
<xsl:attribute name="type">main</xsl:attribute>
</xsl:if>
<xsl:apply-templates/>
</title>
</xsl:template>
<xd:doc>
<xd:desc>The author as stated in Transkribus meta data. Will be used in the teiHeader as
titleStmt/author</xd:desc>
</xd:doc>
<xsl:template match="author">
<xsl:text>
</xsl:text>
<author>
<xsl:apply-templates/>
</author>
</xsl:template>
<xd:doc>
<xd:desc>The author as stated in Transkribus meta data. Will be used in the teiHeader as
titleStmt/respStmt</xd:desc>
</xd:doc>
<xsl:template match="writer">
<xsl:text>
</xsl:text>
<respStmt>
<resp>Writer</resp>
<name>
<xsl:apply-templates/>
</name>
</respStmt>
</xsl:template>
<xd:doc>
<xd:desc>The uploader of the current document. Will be used as titleStmt/principal</xd:desc>
</xd:doc>
<xsl:template match="uploader">
<respStmt>
<resp>Uploader</resp>
<xsl:apply-templates/>
</respStmt>
</xsl:template>
<xd:doc>
<xd:desc>The description as given in Transkribus meta data. Will be used in
sourceDesc</xd:desc>
</xd:doc>
<xsl:template match="desc">
<note>
<xsl:apply-templates/>
</note>
</xsl:template>
<xd:doc>
<xd:desc>The name of the collection from which this document was exported. Will be used as
seriesStmt/title</xd:desc>
</xd:doc>
<xsl:template match="colName">
<p>
<xsl:apply-templates/>
</p>
</xsl:template>
<xd:doc>
<xd:desc>Transkribus meta data: external ID</xd:desc>
</xd:doc>
<xsl:template match="externalId">
<idno type="external">
<xsl:value-of select="."/>
</idno>
</xsl:template>
<xd:doc>
<xd:desc>Transkribus meta data: languages</xd:desc>
</xd:doc>
<xsl:template match="language">
<xsl:text>
</xsl:text>
<langUsage>
<xsl:for-each select="tokenize(., ', ')">
<xsl:text>
</xsl:text>
<language>
<xsl:attribute name="ident">
<xsl:value-of select="map:get($langs, .)" />
</xsl:attribute>
<xsl:value-of select="." />
</language>
</xsl:for-each>
<xsl:text>
</xsl:text>
</langUsage>
</xsl:template>
<!-- Templates for METS -->
<xd:doc>
<xd:desc>Create tei:facsimile with @xml:id</xd:desc>
</xd:doc>
<xsl:template match="mets:file" mode="facsimile">
<xsl:variable name="file" select="document(mets:FLocat/@xlink:href, /)"/>
<xsl:variable name="numCurr" select="@SEQ"/>
<xsl:apply-templates select="$file//p:Page | $file//pc:Page" mode="facsimile">
<xsl:with-param name="imageName" select="substring-after(mets:FLocat/@xlink:href, '/')"/>
<xsl:with-param name="numCurr" select="$numCurr" tunnel="true"/>
</xsl:apply-templates>
</xsl:template>
<xd:doc>
<xd:desc>Apply by-page</xd:desc>
</xd:doc>
<xsl:template match="mets:file" mode="text">
<xsl:variable name="file" select="document(mets:FLocat/@xlink:href, .)"/>
<xsl:variable name="numCurr" select="@SEQ"/>
<xsl:apply-templates select="$file//p:Page | $file//pc:Page" mode="text">
<xsl:with-param name="numCurr" select="$numCurr" tunnel="true"/>
</xsl:apply-templates>
</xsl:template>
<!-- Templates for PAGE, facsimile -->
<xd:doc>
<xd:desc>
<xd:p>Create tei:facsimile/tei:surface</xd:p>
</xd:desc>
<xd:param name="imageName">
<xd:p>the file name of the image</xd:p>
</xd:param>
<xd:param name="numCurr">
<xd:p>Numerus currens of the parent facsimile</xd:p>
</xd:param>
</xd:doc>
<xsl:template match="p:Page | pc:Page" mode="facsimile">
<xsl:param name="imageName"/>
<xsl:param name="numCurr" tunnel="true"/>
<!-- <xsl:variable name="coords" select="tokenize(p:PrintSpace/p:Coords/@points, ' ')"/>-->
<xsl:variable name="type" select="substring-after(@imageFilename, '.')"/>
<xsl:text>
</xsl:text>
<surface ulx="0" uly="0" lrx="{@imageWidth}" lry="{@imageHeight}" xml:id="facs_{$numCurr}">
<xsl:text>
</xsl:text>
<graphic url="{encode-for-uri(@imageFilename)}" width="{@imageWidth}px"
height="{@imageHeight}px"/>
<!-- include Transkribus image link as second graphic element for later evaluation -->
<xsl:apply-templates
select="preceding-sibling::p:Metadata/*:TranskribusMetadata,
preceding-sibling::pc:Metadata/*:TranskribusMetadata"/>
<xsl:apply-templates
select="p:PrintSpace | p:TextRegion | p:SeparatorRegion | p:GraphicRegion | p:TableRegion
| pc:PrintSpace | pc:TextRegion | pc:SeparatorRegion | pc:GraphicRegion | pc:TableRegion"
mode="facsimile"/>
<xsl:text>
</xsl:text>
</surface>
</xsl:template>
<xd:doc>
<xd:desc>create the zones within facsimile/surface</xd:desc>
<xd:param name="numCurr">Numerus currens of the current page</xd:param>
</xd:doc>
<xsl:template
match="p:PrintSpace | p:TextRegion | p:SeparatorRegion | p:GraphicRegion | p:TextLine
| pc:PrintSpace | pc:TextRegion | pc:SeparatorRegion | pc:GraphicRegion | pc:TextLine"
mode="facsimile">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:variable name="renditionValue">
<xsl:choose>
<xsl:when test="local-name(parent::*) = 'TableCell'">TableCell</xsl:when>
<xsl:when test="local-name() = 'TextRegion'">TextRegion</xsl:when>
<xsl:when test="local-name() = 'SeparatorRegion'">Separator</xsl:when>
<xsl:when test="local-name() = 'GraphicRegion'">Graphic</xsl:when>
<xsl:when test="local-name() = 'TextLine'">Line</xsl:when>
<xsl:otherwise>printspace</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<xsl:variable name="custom" as="map(xs:string, xs:string)">
<xsl:map>
<xsl:for-each-group select="tokenize(@custom || ' lfd {' || $numCurr, '\} ')"
group-by="substring-before(., ' ')">
<xsl:map-entry key="substring-before(., ' ')"
select="string-join(substring-after(., '{'), '–')"/>
</xsl:for-each-group>
</xsl:map>
</xsl:variable>
<xsl:choose>
<xsl:when test="self::p:TextLine or self::pc:TextLine">
<xsl:text>
</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>
</xsl:text>
</xsl:otherwise>
</xsl:choose>
<zone points="{(p:Coords/@points, pc:Coords/@points)}" rendition="{$renditionValue}">
<xsl:if test="$renditionValue != 'printspace'">
<xsl:attribute name="xml:id">
<xsl:value-of select="'facs_' || $numCurr || '_' || @id"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="@type">
<xsl:attribute name="subtype">
<xsl:value-of select="@type"/>
</xsl:attribute>
</xsl:if>
<xsl:if test="map:contains($custom, 'structure') and not(@type)">
<xsl:attribute name="subtype"
select="substring-after(substring-before(map:get($custom, 'structure'), ';'), ':')"/>
</xsl:if>
<xsl:apply-templates select="p:TextLine | pc:TextLine" mode="facsimile"/>
<xsl:if test="$word-coordinates">
<xsl:apply-templates select="p:Word | pc:Word" mode="facsimile" />
</xsl:if>
<xsl:choose>
<xsl:when test="self::p:TextLine and p:Word and $word-coordinates">
<xsl:text>
</xsl:text>
</xsl:when>
<xsl:when test="self::p:TextRegion">
<xsl:text>
</xsl:text>
</xsl:when>
<xsl:when test="self::pc:TextLine and pc:Word and $word-coordinates">
<xsl:text>
</xsl:text>
</xsl:when>
<xsl:when test="self::pc:TextRegion">
<xsl:text>
</xsl:text>
</xsl:when>
</xsl:choose>
</zone>
</xsl:template>
<xd:doc>
<xd:desc>create a zone for each word within facsimile/surface</xd:desc>
<xd:param name="numCurr">Numerus currens of the current page</xd:param>
</xd:doc>
<xsl:template match="p:Word | pc:Word" mode="facsimile">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:text>
</xsl:text>
<zone points="{(p:Coords/@points, pc:Coords/@points)}" type="word">
<xsl:attribute name="xml:id">
<xsl:value-of select="'facs_' || $numCurr || '_' || @id"/>
</xsl:attribute>
</zone>
</xsl:template>
<xd:doc>
<xd:desc>Create the zone for a table</xd:desc>
<xd:param name="numCurr">Numerus currens of the current page</xd:param>
</xd:doc>
<xsl:template match="p:TableRegion | pc:TableRegion" mode="facsimile">
<xsl:param name="numCurr" tunnel="true"/>
<zone points="{(p:Coords/@points, pc:Coords/@points)}" rendition="Table">
<xsl:attribute name="xml:id">
<xsl:value-of select="'facs_' || $numCurr || '_' || @id"/>
</xsl:attribute>
<xsl:apply-templates select="p:TableCell//p:TextLine | pc:TableCell//pc:TextLine" mode="facsimile"/>
</zone>
</xsl:template>
<xd:doc>
<xd:desc>create the page content</xd:desc>
<xd:param name="numCurr">Numerus currens of the current page</xd:param>
</xd:doc>
<!-- Templates for PAGE, text -->
<xsl:template match="p:Page | pc:Page" mode="text">
<xsl:param name="numCurr" tunnel="true"/>
<pb facs="#facs_{$numCurr}" n="{$numCurr}" xml:id="img_{format-number($numCurr, '0000')}"/>
<xsl:apply-templates
select="p:TextRegion | p:SeparatorRegion | p:GraphicRegion | p:TableRegion
| pc:TextRegion | pc:SeparatorRegion | pc:GraphicRegion | pc:TableRegion" mode="text">
<xsl:with-param name="center" tunnel="true" select="number(@imageWidth) div 2"
as="xs:double"/>
</xsl:apply-templates>
</xsl:template>
<xd:doc>
<xd:desc>
<xd:p>create specific elements based on the @typing of the text region</xd:p>
<xd:p>PAGE labels for text region see: https://www.primaresearch.org/tools/PAGELibraries
caption observed header observed footer observed page-number observed drop-capital
ignored credit ignored floating ignored signature-mark observed catch-word observed
marginalia observed footnote observed footnote-continued observed endnote ignored
TOC-entry ignored list-label ignored other observed </xd:p>
</xd:desc>
<xd:param name="numCurr"/>
<xd:param name="center"/>
</xd:doc>
<xsl:template match="p:TextRegion | pc:TextRegion" mode="text">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:param name="center" tunnel="true" as="xs:double"/>
<xsl:variable name="custom" as="map(*)">
<xsl:apply-templates select="@custom"/>
</xsl:variable>
<xsl:variable name="regionType" as="xs:string*" select="(@type, $custom?structure?type)" />
<xsl:choose>
<xsl:when test="not(p:TextLine or pc:TextLine or $withoutTextline)"/>
<xsl:when test="'heading' = $regionType">
<head facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</head>
</xsl:when>
<xsl:when test="'caption' = $regionType and not($ab)">
<figure>
<head facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</head>
</figure>
</xsl:when>
<xsl:when test="'header' = $regionType and not($ab)">
<fw type="header" place="top" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</fw>
</xsl:when>
<xsl:when test="'catch-word' = $regionType and not($ab)">
<fw type="catch" place="bottom" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</fw>
</xsl:when>
<xsl:when test="'signature-mark' = $regionType and not($ab)">
<fw place="bottom" type="sig" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</fw>
</xsl:when>
<xsl:when test="'marginalia' = $regionType and not($ab)">
<xsl:variable name="side">
<xsl:choose>
<xsl:when test="number(substring-before((p:Coords/@points, pc:Coords/@points), ',')) gt $center"
>margin-right</xsl:when>
<xsl:otherwise>margin-left</xsl:otherwise>
</xsl:choose>
</xsl:variable>
<note place="{$side}" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</note>
</xsl:when>
<xsl:when test="'footnote' = $regionType and not($ab)">
<note place="foot" n="[footnote reference]" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</note>
</xsl:when>
<xsl:when test="'footnote-continued' = $regionType and not($ab)">
<note place="foot" n="[footnote-continued reference]" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</note>
</xsl:when>
<xsl:when test="'endnote' = $regionType and not($ab)">
<note type="endnote" n="[footnote reference]" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</note>
</xsl:when>
<xsl:when test="'footer' = $regionType and not($ab)">
<fw type="footer" place="bottom" facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</fw>
</xsl:when>
<xsl:when test="'page-number' = $regionType and not($ab)">
<fw type="page-number" facs="#facs_{$numCurr}_{@id}">
<xsl:attribute name="place">
<xsl:variable name="verticalPosition"
select="(p:Coords/@points, pc:Coords/@points) => substring-before(' ') => substring-after(',') => number()"/>
<xsl:choose>
<xsl:when
test="$verticalPosition div number(../@imageHeight) lt .33">
<xsl:text>top</xsl:text>
</xsl:when>
<xsl:when
test="$verticalPosition div number(../@imageHeight) lt .66">
<xsl:text>centre</xsl:text>
</xsl:when>
<xsl:otherwise>
<xsl:text>bottom</xsl:text>
</xsl:otherwise>
</xsl:choose>
</xsl:attribute>
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</fw>
</xsl:when>
<xsl:when test="'paragraph' = $regionType">
<xsl:text>
</xsl:text>
<p facs="#facs_{$numCurr}_{@id}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</p>
</xsl:when>
<!-- the fallback option should be a semantically open element such as <ab> -->
<xsl:otherwise>
<xsl:text>
</xsl:text>
<ab facs="#facs_{$numCurr}_{@id}" type="{(@type,$custom?structure?type)[normalize-space() != ''][1]}">
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
<xsl:text>
</xsl:text>
</ab>
</xsl:otherwise>
</xsl:choose>
</xsl:template>
<xd:doc>
<xd:desc>create a table</xd:desc>
<xd:param name="numCurr"/>
</xd:doc>
<xsl:template match="p:TableRegion | pc:TableRegion" mode="text">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:text>
</xsl:text>
<table facs="#facs_{$numCurr}_{@id}">
<xsl:for-each-group select="p:TableCell | pc:TableCell" group-by="@row">
<xsl:sort select="@col"/>
<xsl:text>
</xsl:text>
<row n="{@row}">
<xsl:apply-templates select="current-group()"/>
</row>
</xsl:for-each-group>
</table>
</xsl:template>
<xd:doc>
<xd:desc>create table cells</xd:desc>
<xd:param name="numCurr"/>
</xd:doc>
<xsl:template match="p:TableCell | pc:TableCell">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:text>
</xsl:text>
<cell facs="#facs_{$numCurr}_{@id}" n="{@col}">
<xsl:apply-templates select="@rowSpan | @colSpan"/>
<xsl:attribute name="rend">
<xsl:value-of select="number((xs:boolean(@leftBorderVisible), false())[1])"/>
<xsl:value-of select="number((xs:boolean(@topBorderVisible), false())[1])"/>
<xsl:value-of select="number((xs:boolean(@rightBorderVisible), false())[1])"/>
<xsl:value-of select="number((xs:boolean(@bottomBorderVisible), false())[1])"/>
</xsl:attribute>
<xsl:apply-templates select="p:TextLine | pc:TextLine"/>
</cell>
</xsl:template>
<xd:doc>
<xd:desc>rowspan -> rows</xd:desc>
</xd:doc>
<xsl:template match="@rowSpan">
<xsl:choose>
<xsl:when test=". > 1">
<xsl:attribute name="rows" select="."/>
</xsl:when>
</xsl:choose>
</xsl:template>
<xd:doc>
<xd:desc>colspan -> cols</xd:desc>
</xd:doc>
<xsl:template match="@colSpan">
<xsl:choose>
<xsl:when test=". > 1">
<xsl:attribute name="cols" select="."/>
</xsl:when>
</xsl:choose>
</xsl:template>
<xd:doc>
<xd:desc>create a figure for graphics
– Provided by github:@liladude in https://github.com/dariok/page2tei/issues/25#issuecomment-1543625106
– Reported by github:@giorgiaagostini</xd:desc>
<xd:param name="numCurr"/>
</xd:doc>
<xsl:template match="p:GraphicRegion" mode="text">
<xsl:param name="numCurr" tunnel="true" />
<xsl:text>
</xsl:text>
<figure facs="#facs_{$numCurr}_{@id}">
<graphic xml:id="#facs_{$numCurr}_{@id}" />
</figure>
</xsl:template>
<xd:doc>
<xd:desc>Converts one line of PAGE to one line of TEI</xd:desc>
<xd:param name="numCurr">Numerus currens, to be tunneled through from the page
level</xd:param>
</xd:doc>
<xsl:template match="p:TextLine | pc:TextLine">
<xsl:param name="numCurr" tunnel="true"/>
<xsl:if test="p:Baseline or pc:Baseline or $withoutBaseline">
<xsl:variable name="text" select="p:TextEquiv/p:Unicode, pc:TextEquiv/pc:Unicode"/>
<xsl:variable name="custom" as="text()*">
<xsl:for-each select="tokenize(@custom, '\}')">
<xsl:variable name="content" select="substring-after(., '{') => normalize-space()"/>
<xsl:variable name="name" select="substring-before(., ' {') => normalize-space()"/>
<xsl:choose>
<xsl:when test="not(contains(., 'offset:'))" />
<xsl:otherwise>
<xsl:value-of select="normalize-space()"/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:variable>
<xsl:variable name="starts" as="map(*)">
<xsl:map>
<xsl:if test="count($custom) > 0">
<xsl:for-each-group select="$custom"
group-by="substring-before(substring-after(., 'offset:'), ';')">
<xsl:map-entry key="xs:int(current-grouping-key())" select="current-group()"/>
</xsl:for-each-group>
</xsl:if>
</xsl:map>
</xsl:variable>
<xsl:variable name="ends" as="map(*)">
<xsl:map>
<xsl:if test="count($custom) > 0">
<xsl:for-each-group select="$custom" group-by="
xs:int(substring-before(substring-after(., 'offset:'), ';'))
+ xs:int(substring-before(substring-after(., 'length:'), ';'))">
<xsl:map-entry key="current-grouping-key()" select="current-group()"/>
</xsl:for-each-group>
</xsl:if>
</xsl:map>
</xsl:variable>
<xsl:variable name="prepped">
<xsl:for-each select="0 to string-length($text)">
<xsl:if test=".">
<xsl:value-of select="substring($text, ., 1)"/>
</xsl:if>
<!-- place end marker for all non-void elements that end here; we must not place void elements here
as this would mean closing a tei:gap before it was opened -->
<xsl:for-each select="map:get($ends, .)">
<xsl:sort select="substring-before(substring-after(., 'offset:'), ';')"
order="descending"/>
<xsl:sort select="substring(., 1, 3)" order="descending"/>
<xsl:if test="substring-after(., 'length:') => substring-before(';') != '0'">
<xsl:element name="local:m">
<xsl:attribute name="type" select="normalize-space(substring-before(., ' '))"/>
<xsl:attribute name="o" select="substring-after(., 'offset:')"/>
<xsl:attribute name="pos">e</xsl:attribute>
</xsl:element>
</xsl:if>
</xsl:for-each>
<xsl:for-each select="map:get($starts, .)">
<xsl:sort select="
xs:int(substring-before(substring-after(., 'offset:'), ';'))
+ xs:int(substring-before(substring-after(., 'length:'), ';'))"
order="descending"/>
<xsl:sort select="substring(., 1, 3)" order="ascending"/>
<xsl:element name="local:m">
<xsl:attribute name="type" select="normalize-space(substring-before(., ' '))"/>
<xsl:attribute name="o" select="substring-after(., 'offset:')"/>
<xsl:attribute name="pos">s</xsl:attribute>
</xsl:element>
</xsl:for-each>
<!-- place end marker for void elements such as tei:gap -->
<xsl:for-each select="map:get($ends, .)">
<xsl:sort select="substring-before(substring-after(., 'offset:'), ';')"
order="descending"/>
<xsl:sort select="substring(., 1, 3)" order="descending"/>
<xsl:if test="substring-after(., 'length:') => substring-before(';') = '0'">
<xsl:element name="local:m">
<xsl:attribute name="type" select="normalize-space(substring-before(., ' '))"/>
<xsl:attribute name="o" select="substring-after(., 'offset:')"/>
<xsl:attribute name="pos">e</xsl:attribute>
</xsl:element>
</xsl:if>
</xsl:for-each>
</xsl:for-each>
</xsl:variable>
<xsl:variable name="prepared">
<xsl:for-each select="$prepped/node()">
<xsl:choose>
<xsl:when test="@pos = 'e'">
<xsl:variable name="position" select="count(preceding-sibling::node())"/>
<xsl:variable name="o" select="@o"/>
<xsl:variable name="id" select="@type"/>
<xsl:variable name="precs"
select="preceding-sibling::local:m[@pos = 's' and preceding-sibling::local:m[@o = $o]]"/>
<xsl:for-each select="$precs">
<xsl:variable name="so" select="@o"/>
<xsl:variable name="myP"
select="count(following-sibling::local:m[@pos = 'e' and @o = $so]/preceding-sibling::node())"/>
<xsl:if test="
following-sibling::local:m[@pos = 'e' and @o = $so
and $myP > $position] and not(@type = $id)">
<local:m type="{@type}" pos="e" o="{@o}"
prev="{$myP||'.'||$position||($myP > $position)}"/>
</xsl:if>
</xsl:for-each>
<xsl:sequence select="."/>
<xsl:for-each select="$precs">
<xsl:variable name="so" select="@o"/>
<xsl:variable name="myP"
select="count(following-sibling::local:m[@pos = 'e' and @o = $so]/preceding-sibling::node())"/>
<xsl:if test="
following-sibling::local:m[@pos = 'e' and @o = $so
and $myP > $position] and not(@type = $id)">
<local:m type="{@type}" pos="s" o="{@o}"
prev="{$myP||'.'||$position||($myP > $position)}"/>
</xsl:if>
</xsl:for-each>
</xsl:when>
<xsl:otherwise>
<xsl:sequence select="."/>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each>
</xsl:variable>
<!-- TODO parameter to create <l>...</l> - #1 -->
<xsl:text>
</xsl:text>
<lb facs="#facs_{$numCurr}_{@id}">
<xsl:if test="@custom">
<xsl:variable name="pos"
select="xs:integer(substring-before(substring-after(@custom, 'index:'), ';')) + 1"/>
<xsl:attribute name="n">
<xsl:text>N</xsl:text>
<xsl:value-of select="format-number($pos, '000')"/>
</xsl:attribute>
</xsl:if>
</lb>
<xsl:apply-templates select="$prepared/text()[not(preceding-sibling::local:m)]"/>
<xsl:apply-templates select="
$prepared/local:m[@pos = 's']
[count(preceding-sibling::local:m[@pos = 's']) = count(preceding-sibling::local:m[@pos = 'e'])]"/>
<!--[not(preceding-sibling::local:m[1][@pos='s'])]" />-->
</xsl:if>
</xsl:template>
<xd:doc>
<xd:desc>Starting milestones for (possibly nested) elements</xd:desc>
</xd:doc>
<xsl:template match="local:m[@pos = 's']">
<xsl:variable name="o" select="@o"/>
<xsl:variable name="custom" as="map(*)">
<xsl:map>
<xsl:variable name="t" select="tokenize(@o, ';')"/>
<xsl:if test="count($t) > 1">
<xsl:for-each select="$t[. != '']">
<xsl:map-entry
key="normalize-space(substring-before(., ':'))"
select="normalize-space(substring-after(., ':'))"/>
</xsl:for-each>
</xsl:if>
</xsl:map>
</xsl:variable>
<xsl:variable name="elem">
<local:t>
<xsl:sequence select="
following-sibling::node()
intersect following-sibling::local:m[@o = $o]/preceding-sibling::node()"
/>
</local:t>
</xsl:variable>
<xsl:choose>
<xsl:when test="@type = 'textStyle'">
<xsl:variable name="rend" as="xs:string*">
<xsl:if test="$custom?italic = 'true'">
<xsl:text>font-style: italic;</xsl:text>
</xsl:if>
<xsl:if test="$custom?bold = 'true'">
<xsl:text>font-weight: bold;</xsl:text>
</xsl:if>
<xsl:if test="$custom?underlined = 'true'">
<xsl:text>text-decoration: underline;</xsl:text>
</xsl:if>
<xsl:if test="$custom?strikethrough = 'true'">
<xsl:text>text-decoration: line-through;</xsl:text>
</xsl:if>
<xsl:if test="number($custom?fontSize) gt 0">
<xsl:value-of select="'font-size: ' || $custom?fontSize || 'px;'"/>
</xsl:if>
<xsl:if test="number($custom?kerning) gt 0">
<xsl:value-of select="'letter-spacing: ' || $custom?fontSize || 'px;'"/>
</xsl:if>
<xsl:if test="$custom?fontFamily != ''">
<xsl:value-of select="'font-family: ' || $custom?fontFamily || ';'"/>
</xsl:if>
<xsl:if test="$custom?superscript = 'true'">
<xsl:text>vertical-align: superscript;</xsl:text>
</xsl:if>
<xsl:if test="$custom?subscript = 'true'">
<xsl:text>vertical-align: subscript;</xsl:text>
</xsl:if>
<xsl:if test="$custom?smallCaps = 'true'">
<xsl:text>font-variant-caps: small-caps;</xsl:text>