-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathPreservation.agda
356 lines (299 loc) · 13.1 KB
/
Preservation.agda
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
open import Data.List hiding ([_]) renaming (_∷_ to _∷ₗ_)
open import Data.Maybe
open import Data.Product
open import AEff
open import EffectAnnotations
open import Renamings
open import Substitutions
open import Types
open import Relation.Binary.PropositionalEquality hiding ([_])
open import Relation.Nullary
module Preservation where
-- BINDING CONTEXTS
BCtx = List VType
-- WELL-TYPED EVALUATION CONTEXTS
data _⊢E[_]⦂_ (Γ : Ctx) : (Δ : BCtx) → CType → Set where
[-] : {C : CType} →
-------------
Γ ⊢E[ [] ]⦂ C
let=_`in_ : {Δ : BCtx}
{X Y : VType}
{o : O}
{i : I} →
Γ ⊢E[ Δ ]⦂ X ! (o , i) →
Γ ∷ X ⊢M⦂ Y ! (o , i) →
------------------------
Γ ⊢E[ Δ ]⦂ Y ! (o , i)
↑ : {Δ : BCtx}
{X : VType}
{o : O}
{i : I} →
(op : Σₛ) →
op ∈ₒ o →
Γ ⊢V⦂ ``(payload op) →
Γ ⊢E[ Δ ]⦂ X ! (o , i) →
------------------------
Γ ⊢E[ Δ ]⦂ X ! (o , i)
↓ : {Δ : BCtx}
{X : VType}
{o : O}
{i : I}
(op : Σₛ) →
Γ ⊢V⦂ ``(payload op) →
Γ ⊢E[ Δ ]⦂ X ! (o , i) →
---------------------------
Γ ⊢E[ Δ ]⦂ X ! op ↓ₑ (o , i)
promise_∣_↦_`in_ : {Δ : BCtx}
{X Y : VType}
{o o' : O}
{i i' : I} →
(op : Σₛ) →
lkpᵢ op i ≡ just (o' , i') →
Γ ∷ ``(payload op) ⊢M⦂ ⟨ X ⟩ ! (o' , i') →
Γ ∷ ⟨ X ⟩ ⊢E[ Δ ]⦂ Y ! (o , i) →
------------------------------------------
Γ ⊢E[ X ∷ₗ Δ ]⦂ Y ! (o , i)
coerce : {Δ : BCtx}
{X : VType}
{o o' : O}
{i i' : I} →
o ⊑ₒ o' →
i ⊑ᵢ i' →
Γ ⊢E[ Δ ]⦂ X ! (o , i) →
------------------------
Γ ⊢E[ Δ ]⦂ X ! (o' , i')
-- MERGING AN ORDINARY CONTEXT AND A BINDING CONTEXT
infix 30 _⋈_
_⋈_ : Ctx → BCtx → Ctx
Γ ⋈ [] = Γ
Γ ⋈ (X ∷ₗ Δ) = (Γ ∷ ⟨ X ⟩) ⋈ Δ
-- FINDING THE TYPE OF THE HOLE OF A WELL-TYPED EVALUATION CONTEXT
hole-ty-e : {Γ : Ctx} {Δ : BCtx} {C : CType} → Γ ⊢E[ Δ ]⦂ C → CType
hole-ty-e {_} {_} {C} [-] =
C
hole-ty-e (let= E `in M) =
hole-ty-e E
hole-ty-e (↑ op p V E) =
hole-ty-e E
hole-ty-e (↓ op V E) =
hole-ty-e E
hole-ty-e (promise op ∣ p ↦ M `in E) =
hole-ty-e E
hole-ty-e (coerce p q E) =
hole-ty-e E
-- FILLING A WELL-TYPED EVALUATION CONTEXT
{- LEMMA 3.5 -}
infix 30 _[_]
_[_] : {Γ : Ctx} {Δ : BCtx} {C : CType} → (E : Γ ⊢E[ Δ ]⦂ C) → Γ ⋈ Δ ⊢M⦂ (hole-ty-e E) → Γ ⊢M⦂ C
[-] [ M ] =
M
(let= E `in N) [ M ] =
let= (E [ M ]) `in N
↑ op p V E [ M ] =
↑ op p V (E [ M ])
↓ op V E [ M ] =
↓ op V (E [ M ])
(promise op ∣ p ↦ N `in E) [ M ] =
promise op ∣ p ↦ N `in (E [ M ])
coerce p q E [ M ] =
coerce p q (E [ M ])
-- STRENGTHENING OF GROUND VALUES WRT BOUND PROMISES
strengthen-var : {Γ : Ctx} → (Δ : BCtx) → {A : BType} → `` A ∈ Γ ⋈ Δ → `` A ∈ Γ
strengthen-var [] x = x
strengthen-var (y ∷ₗ Δ) x with strengthen-var Δ x
... | Tl p = p
strengthen-val : {Γ : Ctx} {Δ : BCtx} {A : BType} → Γ ⋈ Δ ⊢V⦂ `` A → Γ ⊢V⦂ `` A
strengthen-val {_} {Δ} (` x) =
` strengthen-var Δ x
strengthen-val (``_ c) =
``_ c
strengthen-val-[] : {Γ : Ctx}
{A : BType} →
(V : Γ ⋈ [] ⊢V⦂ `` A) →
--------------------
strengthen-val {Δ = []} V ≡ V
strengthen-val-[] (` x) =
refl
strengthen-val-[] (``_ c) =
refl
-- SMALL-STEP OPERATIONAL SEMANTICS FOR WELL-TYPED COMPUTATIONS
-- (ADDITIONALLY SERVES AS THE PRESERVATION THEOREM)
{- THEOREM 3.6 -}
infix 10 _↝_
data _↝_ {Γ : Ctx} : {C : CType} → Γ ⊢M⦂ C → Γ ⊢M⦂ C → Set where
-- COMPUTATIONAL RULES
apply : {X : VType}
{C : CType} →
(M : Γ ∷ X ⊢M⦂ C) →
(V : Γ ⊢V⦂ X) →
----------------------
(ƛ M) · V
↝
M [ id-subst [ V ]s ]m
let-return : {X Y : VType}
{o : O}
{i : I} →
(V : Γ ⊢V⦂ X) →
(N : Γ ∷ X ⊢M⦂ Y ! (o , i)) →
-----------------------------
let= (return V) `in N
↝
N [ id-subst [ V ]s ]m
let-↑ : {X Y : VType}
{o : O}
{i : I}
{op : Σₛ} →
(p : op ∈ₒ o) →
(V : Γ ⊢V⦂ ``(payload op)) →
(M : Γ ⊢M⦂ X ! (o , i)) →
(N : Γ ∷ X ⊢M⦂ Y ! (o , i)) →
-----------------------------
let= (↑ op p V M) `in N
↝
↑ op p V (let= M `in N)
let-promise : {X Y Z : VType}
{o o' : O}
{i i' : I}
{op : Σₛ} →
(p : lkpᵢ op i ≡ just (o' , i')) →
(M₁ : Γ ∷ ``(payload op) ⊢M⦂ ⟨ X ⟩ ! (o' , i')) →
(M₂ : Γ ∷ ⟨ X ⟩ ⊢M⦂ Y ! (o , i)) →
(N : Γ ∷ Y ⊢M⦂ Z ! (o , i)) →
---------------------------------------------------------------------------
let= (promise op ∣ p ↦ M₁ `in M₂) `in N
↝
(promise op ∣ p ↦ M₁ `in (let= M₂ `in (M-rename (comp-ren exchange wk₁) N)))
letrec-unfold : {X : VType}
{C D : CType}
(M : Γ ∷ (X ⇒ C) ∷ X ⊢M⦂ C) →
(N : Γ ∷ (X ⇒ C) ⊢M⦂ D) →
----------------------------------------
(letrec M `in N)
↝
N [ id-subst [ ƛ (letrec M-rename wk₃ M `in M-rename exchange M) ]s ]m
promise-↑ : {X Y : VType}
{o o' : O}
{i i' : I}
{op op' : Σₛ} →
(p : lkpᵢ op i ≡ just (o' , i')) →
(q : op' ∈ₒ o) →
(V : Γ ∷ ⟨ X ⟩ ⊢V⦂ ``(payload op')) →
(M : Γ ∷ ``(payload op) ⊢M⦂ ⟨ X ⟩ ! (o' , i')) →
(N : Γ ∷ ⟨ X ⟩ ⊢M⦂ Y ! (o , i)) →
--------------------------------------------
(promise op ∣ p ↦ M `in (↑ op' q V N))
↝
↑ op' q (strengthen-val {Δ = X ∷ₗ []} V) (promise op ∣ p ↦ M `in N)
↓-return : {X : VType}
{o : O}
{i : I}
{op : Σₛ} →
(V : Γ ⊢V⦂ ``(payload op)) →
(W : Γ ⊢V⦂ X) →
----------------------------------------------------------------
↓ {o = o} {i = i} op V (return W)
↝
return {o = proj₁ (op ↓ₑ (o , i))} {i = proj₂ (op ↓ₑ (o , i))} W
↓-↑ : {X : VType}
{o : O}
{i : I}
{op : Σₛ}
{op' : Σₛ} →
(p : op' ∈ₒ o) →
(V : Γ ⊢V⦂ ``(payload op)) →
(W : Γ ⊢V⦂ ``(payload op')) →
(M : Γ ⊢M⦂ X ! (o , i)) →
-------------------------------
↓ op V (↑ op' p W M)
↝
↑ op' (↓ₑ-⊑ₒ op' p) W (↓ op V M)
↓-promise-op : {X Y : VType}
{o o' : O}
{i i' : I}
{op : Σₛ} →
(p : lkpᵢ op i ≡ just (o' , i')) →
(V : Γ ⊢V⦂ ``(payload op)) →
(M : Γ ∷ ``(payload op) ⊢M⦂ ⟨ X ⟩ ! (o' , i')) →
(N : Γ ∷ ⟨ X ⟩ ⊢M⦂ Y ! (o , i)) →
---------------------------------------------------------------------------------------
↓ op V (promise op ∣ p ↦ M `in N )
↝
(let= (coerce (↓ₑ-⊑ₒ-o' {o} p) (↓ₑ-⊑ₒ-i' {o} p) (M [ id-subst [ V ]s ]m)) `in
↓ op (V-rename wk₁ V) ((M-rename (comp-ren exchange wk₁) N) [ id-subst [ ` Hd ]s ]m))
↓-promise-op' : {X Y : VType}
{o o' : O}
{i i' : I}
{op op' : Σₛ} →
(p : ¬ op ≡ op') →
(q : lkpᵢ op' i ≡ just (o' , i')) →
(V : Γ ⊢V⦂ ``(payload op)) →
(M : Γ ∷ ``(payload op') ⊢M⦂ ⟨ X ⟩ ! (o' , i')) →
(N : Γ ∷ ⟨ X ⟩ ⊢M⦂ Y ! (o , i)) →
------------------------------------------------------------------------------------------
↓ op V (promise op' ∣ q ↦ M `in N )
↝
promise_∣_↦_`in_ {o' = proj₁ (lkpᵢ-↓ₑ-neq {o = o} {i = i} p q)}
{i' = proj₁ (proj₂ (lkpᵢ-↓ₑ-neq {o = o} {i = i} p q))}
op'
(proj₁ (proj₂ (proj₂ (lkpᵢ-↓ₑ-neq {o = o} {i = i} p q))))
(coerce (proj₁ (proj₂ (proj₂ (proj₂ (lkpᵢ-↓ₑ-neq {o = o} {i = i} p q)))))
(proj₂ (proj₂ (proj₂ (proj₂ (lkpᵢ-↓ₑ-neq {o = o} {i = i} p q)))))
M)
(↓ op (V-rename wk₁ V) N)
await-promise : {X : VType}
{C : CType} →
(V : Γ ⊢V⦂ X) →
(M : Γ ∷ X ⊢M⦂ C) →
--------------------
await ⟨ V ⟩ until M
↝
M [ id-subst [ V ]s ]m
-- EVALUATION CONTEXT RULE
context : {Δ : BCtx}
{C : CType} →
(E : Γ ⊢E[ Δ ]⦂ C) →
{M N : Γ ⋈ Δ ⊢M⦂ (hole-ty-e E)} →
M ↝ N →
-------------------------------
E [ M ] ↝ E [ N ]
-- COERCION RULES
-- (THE RESULT OF WORKING WITH WELL-TYPED SYNTAX AND MAKING SUBSUMPTION INTO AN EXPLICIT COERCION)
coerce-return : {X : VType}
{o o' : O}
{i i' : I}
{p : o ⊑ₒ o'}
{q : i ⊑ᵢ i'} →
(V : Γ ⊢V⦂ X) →
--------------------------------
coerce p q (return V) ↝ return V
coerce-↑ : {X : VType}
{o o' : O}
{i i' : I}
{p : o ⊑ₒ o'}
{q : i ⊑ᵢ i'}
{op : Σₛ} →
(r : op ∈ₒ o) →
(V : Γ ⊢V⦂ ``(payload op)) →
(M : Γ ⊢M⦂ X ! (o , i)) →
-------------------------------
coerce p q (↑ op r V M)
↝
↑ op (p op r) V (coerce p q M)
coerce-promise : {X Y : VType}
{o o' o'' : O}
{i i' i'' : I}
{p : o ⊑ₒ o'}
{q : i ⊑ᵢ i'}
{op : Σₛ} →
(r : lkpᵢ op i ≡ just (o'' , i''))
(M : Γ ∷ ``(payload op) ⊢M⦂ ⟨ X ⟩ ! (o'' , i'')) →
(N : Γ ∷ ⟨ X ⟩ ⊢M⦂ Y ! (o , i)) →
------------------------------------------------------------------
coerce p q (promise op ∣ r ↦ M `in N)
↝
promise_∣_↦_`in_ {o' = lkpᵢ-nextₒ q r}
{i' = lkpᵢ-nextᵢ q r}
op
(lkpᵢ-next-eq q r)
(coerce (lkpᵢ-next-⊑ₒ q r) (lkpᵢ-next-⊑ᵢ q r) M)
(coerce p q N)