build.gradle

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

group = 'com.unquietcode.tools.spring'
version = '4.2.5'
sourceCompatibility = 1.7


task wrapper(type: Wrapper) {
  gradleVersion = '2.3'
}

task sourcesJar(type: Jar, dependsOn: classes) {
	classifier = 'sources'
	from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
	classifier = 'javadoc'
	from javadoc.destinationDir
}

artifacts {
	archives sourcesJar
	archives javadocJar
}

uploadArchives {
	repositories {
		mavenDeployer {
			beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

			repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
				authentication(userName: hasProperty('ossrhUsername') ? ossrhUsername : '', password: hasProperty('ossrhPassword') ? ossrhPassword : '')
			}

			snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
				authentication(userName: hasProperty('ossrhUsername') ? ossrhUsername : '', password: hasProperty('ossrhPassword') ? ossrhPassword : '')
			}

			pom.project {
				name 'Spring Generics'
				packaging 'jar'
				description 'Procedurally extracted version of the Spring Framework\'s wonderful generics utilities.'
				url 'https://github.com/UnquietCode/spring-generics'

				scm {
					connection 'scm:git:https://github.com/UnquietCode/spring-generics.git'
					developerConnection 'scm:git:https://github.com/UnquietCode/spring-generics.git'
					url 'https://github.com/UnquietCode/spring-generics'
				}

				licenses {
					license {
						name 'The Apache License, Version 2.0'
						url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
					}
				}

				developers {
					developer {
						id 'unquietcode'
						name 'Benjamin Fagin'
						email 'blouis@unquietcode.com'
					}
				}
			}
		}
	}
}

// code signing
if (System.getProperty("do.sign") != null) {
	signing {
		sign configurations.archives
	}
}