forked from math-comp/hierarchy-builder
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathhierarchy_3.v
181 lines (144 loc) · 4.53 KB
/
hierarchy_3.v
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
From Coq Require Import ssreflect ssrfun.
From HB Require Import structures.
(**************************************************************************)
(* Stage 3: AddComoid ----> AddAG -----> Ring *)
(* \ / *)
(* -> +SemiRing+ - *)
(**************************************************************************)
HB.mixin Record AddComoid_of_TYPE A := {
zero : A;
add : A -> A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
}.
HB.structure Definition AddComoid := { A of AddComoid_of_TYPE A }.
HB.mixin Record AddAG_of_AddComoid A of AddComoid A := {
opp : A -> A;
addNr : left_inverse zero opp add;
}.
HB.factory Record AddAG_of_TYPE A := {
zero : A;
add : A -> A -> A;
opp : A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
addNr : left_inverse zero opp add;
}.
HB.builders Context A (a : AddAG_of_TYPE A).
HB.instance
Definition to_AddComoid_of_TYPE := AddComoid_of_TYPE.Build A
zero add addrA addrC add0r.
HB.instance
Definition to_AddAG_of_AddComoid := AddAG_of_AddComoid.Build A _ addNr.
HB.end.
HB.structure Definition AddAG := { A of AddAG_of_TYPE A }.
(* Begin change *)
HB.mixin Record SemiRing_of_AddComoid A of AddComoid A := {
one : A;
mul : A -> A -> A;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
mul0r : left_zero zero mul;
mulr0 : right_zero zero mul;
}.
HB.structure Definition SemiRing := { A of AddComoid A & SemiRing_of_AddComoid A }.
HB.factory Record Ring_of_AddAG A of AddAG A := {
one : A;
mul : A -> A -> A;
mulrA : associative mul;
mulr1 : left_id one mul;
mul1r : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
HB.builders Context A (a : Ring_of_AddAG A).
Fact mul0r : left_zero zero mul.
Proof.
move=> x; rewrite -[LHS]add0r addrC.
rewrite -{2}(addNr (mul x x)) (addrC (opp _)) addrA.
by rewrite -mulrDl add0r addrC addNr.
Qed.
Fact mulr0 : right_zero zero mul.
Proof.
move=> x; rewrite -[LHS]add0r addrC.
rewrite -{2}(addNr (mul x x)) (addrC (opp _)) addrA.
by rewrite -mulrDr add0r addrC addNr.
Qed.
HB.instance
Definition to_SemiRing_of_AddComoid := SemiRing_of_AddComoid.Build A
_ mul mulrA mulr1 mul1r
mulrDl mulrDr mul0r mulr0.
HB.end.
(* End change *)
HB.factory Record Ring_of_AddComoid A of AddComoid A := {
opp : A -> A;
one : A;
mul : A -> A -> A;
addNr : left_inverse zero opp add;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
HB.builders Context A (a : Ring_of_AddComoid A).
HB.instance
Definition to_AddAG_of_AddComoid := AddAG_of_AddComoid.Build A _ addNr.
HB.instance
Definition to_Ring_of_AddAG := Ring_of_AddAG.Build A
_ _ mulrA mul1r mulr1 mulrDl mulrDr.
HB.end.
(* End change *)
HB.factory Record Ring_of_TYPE A := {
zero : A;
one : A;
add : A -> A -> A;
opp : A -> A;
mul : A -> A -> A;
addrA : associative add;
addrC : commutative add;
add0r : left_id zero add;
addNr : left_inverse zero opp add;
mulrA : associative mul;
mul1r : left_id one mul;
mulr1 : right_id one mul;
mulrDl : left_distributive mul add;
mulrDr : right_distributive mul add;
}.
HB.builders Context A (a : Ring_of_TYPE A).
HB.instance
Definition to_AddComoid_of_TYPE := AddComoid_of_TYPE.Build A
zero add addrA addrC add0r.
HB.instance
Definition to_Ring_of_AddComoid := Ring_of_AddComoid.Build A
_ _ _ addNr mulrA mul1r mulr1 mulrDl mulrDr.
HB.end.
HB.structure Definition Ring := { A of Ring_of_TYPE A }.
(* Notations *)
Declare Scope hb_scope.
Delimit Scope hb_scope with G.
Local Open Scope hb_scope.
Notation "0" := zero : hb_scope.
Notation "1" := one : hb_scope.
Infix "+" := (@add _) : hb_scope.
Notation "- x" := (@opp _ x) : hb_scope.
Infix "*" := (@mul _) : hb_scope.
Notation "x - y" := (x + - y) : hb_scope.
(* Theory *)
Section Theory.
Variable R : Ring.type.
Implicit Type (x : R).
Lemma addr0 : right_id (@zero R) add.
Proof. by move=> x; rewrite addrC add0r. Qed.
Lemma addrN : right_inverse (@zero R) opp add.
Proof. by move=> x; rewrite addrC addNr. Qed.
Lemma subrr x : x - x = 0.
Proof. by rewrite addrN. Qed.
Lemma addrNK x y : x + y - y = x.
Proof. by rewrite -addrA subrr addr0. Qed.
End Theory.