-
Notifications
You must be signed in to change notification settings - Fork 10
/
pack.pl
1420 lines (1238 loc) · 43.6 KB
/
pack.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* Part of SWI-Prolog
Author: Jan Wielemaker
E-mail: [email protected]
WWW: http://www.swi-prolog.org
Copyright (C): 2013-2024, VU University Amsterdam
SWI-Prolog Solutions b.v.
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module(pack,
[ pack/1, % ?Pack
pack_version_hashes/2, % +Pack, -VersionHashesPairs
hash_git_url/2, % +Hash, -URL
hash_file_url/2, % +Hash, -URL
pack_url_hash/2, % +URL, -SHA1
current_pack/2, % +Filter, -Pack
sort_packs/3, % +By, +Packs, -Sorted
pack_table//2 % +Packs, +Options
]).
:- use_module(library(http/http_dispatch)).
:- use_module(library(http/http_parameters)).
:- use_module(library(http/http_client)).
:- use_module(library(http/http_log)).
:- use_module(library(http/http_wrapper)).
:- use_module(library(http/html_write)).
:- use_module(library(http/html_head)).
:- use_module(library(persistency)).
:- use_module(library(lists)).
:- use_module(library(aggregate)).
:- use_module(library(option)).
:- use_module(library(record)).
:- use_module(library(pairs)).
:- use_module(library(error)).
:- use_module(library(apply)).
:- use_module(library(uri)).
:- use_module(library(debug)).
:- use_module(library(prolog_versions)).
:- use_module(pack_info).
:- use_module(pack_mirror).
:- use_module(review).
:- use_module(messages).
:- use_module(openid).
:- use_module(proxy).
:- use_module(parms).
:- http_handler(root(pack/query), pack_query, []).
:- http_handler(root(pack/list), pack_list, [prefix]).
:- http_handler(root(pack/file_details), pack_file_details,
[prefix, time_limit(20)]).
:- http_handler(root(pack/delete), pack_delete, []).
:- http_handler(root(pack/pattern), set_allowed_url, []).
%! pack_query(+Request)
%
% Handle package query requests from remote installers. Content
% is of type application/x-prolog. Reply is also a Prolog term.
pack_query(Request) :-
proxy_master(Request),
!.
pack_query(Request) :-
memberchk(content_type(ContentType), Request),
content_x_prolog(ContentType, ReplyType),
!,
http_peer(Request, Peer),
http_read_data(Request, Query,
[ content_type('application/x-prolog')
]),
http_log('pack_query(~q, ~q).~n', [Query, Peer]),
format('Cache-Control: private~n'),
( catch(pack_query(Query, Peer, Reply), E, true)
-> format('Content-type: ~w; charset=UTF-8~n~n', [ReplyType]),
( var(E)
-> format('~q.~n', [true(Reply)]),
http_log('pack_query_done(ok, ~q).~n', [Peer])
; format('~q.~n', [exception(E)]),
message_to_string(E, String),
http_log('pack_query_done(error(~q), ~q).~n', [String, Peer])
)
; format('Content-type: ~w; charset=UTF-8~n~n', [ReplyType]),
format('false.~n'),
http_log('pack_query_done(failed, ~q).~n', [Peer])
).
content_x_prolog(ContentType, 'text/x-prolog') :-
sub_atom(ContentType, 0, _, _, 'text/x-prolog'),
!.
content_x_prolog(ContentType, 'application/x-prolog') :-
sub_atom(ContentType, 0, _, _, 'application/x-prolog').
%! proxy_master(Request)
%
% Proxy the request to the master to make sure the central package
% database remains synchronised.
proxy_master(Request) :-
option(host(Host), Request),
server(Role, Host),
Role \== master,
server(master, Master),
Master \== Host,
!,
http_peer(Request, Peer),
format(string(To), 'https://~w', [Master]),
proxy(To, Request,
[ request_headers([ 'X-Forwarded-For' = Peer,
'X-Real-IP' = Peer,
'Cache-Control' = 'no-cache'
])
]).
%! pack_query(+Query, +Peer, -Reply) is det.
%
% Implements the various queries from the pack_install/1.
% Currently defined Query values are:
%
% * install(+URL, +SHA1, +Info)
% User tries to install from URL an object with the indicated
% hash and Info.
% * downloaded(+Data)
% Register download for indicated Data
% * locate(+Pack)
% Query download locations for Pack.
% * versions(+Packs, +Options)
% Query download and versions for a set of packs and all
% (recursive) dependencies.
% * search(+Keyword)
% Find packs that match Keyword.
% * info(+Packs)
% Return a list of meta-data terms for the latest version of
% Packs. Unknown packs are omitted from the result list.
pack_query(install(URL0, SHA10, Info), Peer, Reply) =>
to_atom(URL0, URL),
to_atom(SHA10, SHA1),
save_request(Peer, download(URL, SHA1, Info), Result),
( Result = throw(Error)
-> throw(Error)
; findall(ReplyInfo, install_info(URL, SHA1, ReplyInfo), Reply)
).
pack_query(downloaded(Data), Peer, Reply) =>
maplist(save_request(Peer), Data, Reply).
pack_query(locate(Pack), _, Reply) =>
pack_version_urls_v1(Pack, Reply).
pack_query(versions(Pack, Options), _, Reply) =>
pack_versions(Pack, Reply, Options).
pack_query(search(Word), _, Reply) =>
search_packs(Word, Reply).
pack_query(info(Packs), _, Hits) =>
convlist(pack_search_result, Packs, Hits).
to_atom(Atom, Atom) :-
atom(Atom),
!.
to_atom(String, Atom) :-
atom_string(Atom, String).
%! pack_admin(+Pack)//
%
% Display pack admin options
pack_admin(Pack) -->
{ admin_user },
!,
html(div(class('pack-admin'),
[ div(class('delete-pack'), \delete_button(Pack)),
div(style('clear:right'), \pattern_input(Pack))
])).
pack_admin(_) -->
[].
delete_button(Pack) -->
{ http_link_to_id(pack_delete, [], HREF)
},
html(form([ action(HREF),
class('delete-pack')
],
[ input([ type(hidden), name(p), value(Pack)]),
button([type(submit)], 'Delete pack'),
&(nbsp)
])).
pattern_input(Pack) -->
{ http_link_to_id(set_allowed_url, [], HREF),
( pack_allowed_url(Pack, IsGit, Pattern)
-> true
; pack_version_hashes(Pack, VersionHashes),
member(_-Hashes, VersionHashes),
member(Hash, Hashes),
sha1_url(Hash, URL)
-> url_pattern(URL, IsGit, Pattern)
; Pattern = "",
IsGit = false
)
},
html(form([ action(HREF),
class('pack-set-url-pattern')
],
[ input([ type(hidden), name(p), value(Pack)]),
label(for(url), 'URL pattern'),
input([ class('url-pattern'), name(url), value(Pattern)]),
input([ type(checkbox), name(git), value(IsGit)]),
label(for(git), 'Is GIT'),
button([type(submit)],
'Update URL pattern'),
&(nbsp)
])).
admin_user :-
current_prolog_flag(admin, true),
!.
admin_user :-
site_user_logged_in(User),
site_user_property(User, granted(admin)).
%! pack_delete(+Request)
%
% HTTP handler to delete a pack
pack_delete(Request) :-
admin_user,
http_parameters(Request,
[ p(Pack, [optional(true)]),
h(Hash, [optional(true)])
], []),
( nonvar(Pack)
-> call_showing_messages(delete_pack(Pack), [])
; nonvar(Hash)
-> call_showing_messages(delete_hash(Hash), [])
).
pack_delete(Request) :-
memberchk(path(Path), Request),
throw(http_reply(forbidden(Path))).
/*******************************
* COMPUTATIONAL LOGIC *
*******************************/
%! install_info(+URL, +SHA1, -Info) is nondet.
%
% Info is relevant information for the client who whishes to
% install URL, which has the given SHA1 hash. Currently provided
% info is:
%
% - alt_hash(Downloads, URLs, Hash)
% Another file with the same (base) name was registered that
% has a different hash. This file was downloaded Downloads
% times, resides on the given URLs (a list) and has the given
% Hash.
% - downloads(Downloads)
% This hash was downloaded Downloads times from a unique IP
% address
% - dependency(Token, Pack, Version, URLs, SubSeps)
% The requirement Token can be provided by Pack@Version, which
% may be downloaded from the given URLs (a list). Pack has
% install info as specified by SubSeps (recursive
% dependencies)
install_info(URL, SHA1, Info) :-
install_info(URL, SHA1, Info, []).
install_info(_, SHA1, _, Seen) :-
memberchk(SHA1, Seen), !, fail.
install_info(URL, SHA1, alt_hash(Downloads, URLs, Hash), _) :-
prolog_pack:pack_url_file(URL, File),
sha1_file(Hash, File),
Hash \== SHA1,
\+ is_github_release(URL),
sha1_downloads(Hash, Downloads),
sha1_urls(Hash, URLs).
install_info(_, SHA1, downloads(Count), _) :-
sha1_downloads(SHA1, Count).
install_info(_, SHA1, dependency(Token, Pack, Version, URLs, SubDeps), Seen) :-
sha1_requires(SHA1, Token),
\+ is_prolog_token(Token), % not in this version
( ( sha1_pack(_Hash, Token),
Pack = Token
; sha1_provides(Hash, Token),
sha1_pack(Hash, Pack),
Pack \== Token
),
pack_latest_version(Pack, Hash1, _VersionTerm, _Older),
sha1_info(Hash1, Info),
memberchk(version(Version), Info),
findall(URL, sha1_url(Hash1, URL), URLs),
URLs \== []
-> findall(SubDep, install_info(-, Hash1, SubDep, [SHA1|Seen]), SubDeps)
; Pack = (-), Version = (-), URLs = []
).
%! is_prolog_token(+Token) is semidet.
%
% @tbd: share with library(pack_install).
is_prolog_token(Token), cmp(Token, prolog, _Cmp, _Version) => true.
is_prolog_token(prolog:_Feature) => true.
is_prolog_token(_) => fail.
sha1_downloads(Hash, Count) :-
aggregate_all(count, sha1_download(Hash, _), Count).
sha1_urls(Hash, URLs) :-
findall(URL, sha1_url(Hash, URL), URLs).
sha1_version(Hash, Version) :-
sha1_info(Hash, Info),
memberchk(version(Atom), Info),
atom_version(Atom, Version).
sha1_title(Hash, Title) :-
sha1_info(Hash, Info),
( memberchk(title(Title), Info)
-> true
; Title = '<no title>'
).
sha1_is_git(Hash, Boolean) :-
sha1_info(Hash, Info),
( memberchk(git(true), Info)
-> Boolean = true
; Boolean = false
).
%! pack_version_hashes(+Pack, -VersionHashesPairs) is semidet.
%
% True when HashesByVersion is an ordered list Version-Hashes,
% latest version first.
pack_version_hashes(Pack, VersionAHashesPairs) :-
findall(SHA1, sha1_pack(SHA1, Pack), Hashes),
map_list_to_pairs(sha1_version, Hashes, VersionHashPairs),
keysort(VersionHashPairs, Sorted),
group_pairs_by_key(Sorted, VersionHashesPairs),
reverse(VersionHashesPairs, RevPairs),
maplist(atomic_version_hashes, RevPairs, VersionAHashesPairs).
atomic_version_hashes(Version-Hashes, VersionA-Hashes) :-
atom_version(VersionA, Version).
%! pack_version_urls_v1(+Pack, -Locations) is det.
%
% True when Locations is a set of Version-list(URL) pairs used for
% installing Pack.
%
% @arg Locations is a list Version-URLs, sorted latest version
% first.
% @see pack_version_urls_v2/3
pack_version_urls_v1(Pack, VersionURLs) :-
pack_version_hashes(Pack, VersionHashes),
maplist(version_hashes_urls, VersionHashes, VersionURLs).
version_hashes_urls(Version-Hashes, Version-URLs) :-
maplist(sha1_url, Hashes, URLs0),
sort(URLs0, URLs).
%! pack_versions(+Packs, -PackVersions, +Options) is det.
%
% Given a single or multiple packs, return information on all
% these packs as well as their dependencies. PackVersions is a
% list of `Pack-Versions`. `Versions` is a list of
% `Version-InfoList`. `InfoList` is a list of dicts, each holding
%
% - info.pack
% Pack name
% - info.hash
% Hash of the version. This is either a GIT hash or the
% sha1 of the archive file.
% - info.provides
% List of provided tokens. Each provide is either a simple
% token or a term @(Token,Version).
% - info.requires
% List of required tokens. Each requirement is either a
% simple token or a term `Token cmp Version`, where _cmp_
% is one of `<`, `=<`, `=`, `>=` or `>`.
% - info.conflicts
% Similar to `info.requires`, declaring conflicts
% - info.url
% URL for downloading the archive or URL of the git repo.
% - info.git
% Boolean expressing wether the URL is a git repo or
% archive.
% - info.downloads
% Download count.
pack_versions(Packs, Deps, Options) :-
phrase(pack_versions(Packs, [seen(Deps)|Options]), Deps).
pack_versions([], _) --> !.
pack_versions([H|T], Options) -->
pack_versions(H, Options),
pack_versions(T, Options).
pack_versions(Pack, Options) -->
{ option(seen(Deps), Options),
seen(Pack, Deps)
},
!.
pack_versions(Pack, Options) -->
{ pack_version_hashes(Pack, VersionHashes),
convlist(version_hash_info(Pack, Options),
VersionHashes, Infos),
maplist(arg(2), Infos, RequiresLists),
append(RequiresLists, Requires0),
sort(Requires0, Requires),
maplist(arg(1), Infos, VersionInfo)
},
[ Pack-VersionInfo ],
include_pack_requirements(Requires, Options).
seen(Pack, [Pack-_|_]) => true.
seen(Pack, [_|T]) => seen(Pack, T).
seen(_, _) => fail.
version_hash_info(Pack, Options, Version-Hashes, info(Version-Info, Requires)) :-
maplist(hash_info(Pack, Options), Hashes, Info, Requires0),
append(Requires0, Requires1),
sort(Requires1, Requires).
hash_info(Pack, _Options, Hash, Dict, Requires) :-
sha1_url(Hash, URL),
sha1_is_git(Hash, IsGit),
sha1_downloads(Hash, Count),
findall(Req, sha1_requires(Hash, Req), Requires),
findall(Prv, sha1_provides(Hash, Prv), Provides),
findall(Prv, sha1_conflicts(Hash, Prv), Conflicts),
Dict = #{ pack: Pack,
hash: Hash,
url: URL,
git: IsGit,
requires: Requires,
provides: Provides,
conflicts: Conflicts,
downloads: Count
}.
include_pack_requirements([], _) --> !.
include_pack_requirements([ReqToken|T], Options) -->
{ findall(Unseen, resolves(ReqToken, Unseen), DepPacks)
},
pack_versions(DepPacks, Options),
include_pack_requirements(T, Options).
resolves(ReqToken, Pack) :-
( sha1_pack(Hash, Token),
sha1_version(Hash, Version),
PrvToken = @(Token,Version)
; sha1_provides(Hash, PrvToken)
),
satisfies(PrvToken, ReqToken),
sha1_pack(Hash, Pack).
satisfies(Token, Token) => true.
satisfies(@(Token,_), Token) => true.
satisfies(@(Token,PrvVersion), Req), cmp(Req, Token, Cmp, ReqVersion) =>
atomic_list_concat(PrvVersion, PrvVersionAtom),
atomic_list_concat(ReqVersion, ReqVersionAtom),
cmp_versions(Cmp, PrvVersionAtom, ReqVersionAtom).
satisfies(_,_) => fail.
cmp(Token < Version, Token, <, Version).
cmp(Token =< Version, Token, =<, Version).
cmp(Token = Version, Token, =, Version).
cmp(Token == Version, Token, ==, Version).
cmp(Token >= Version, Token, >=, Version).
cmp(Token > Version, Token, >, Version).
%! search_packs(+Search, -Packs) is det.
%
% Search packs by keyword, returning a list
%
% pack(Pack, Status, Version, Title, URLs).
search_packs(Search, Packs) :-
setof(Pack, matching_pack(Search, Pack), Names),
!,
maplist(pack_search_result, Names, Packs).
matching_pack(Search, Pack) :-
sha1_pack(SHA1, Pack),
( sub_atom_icasechk(Pack, _, Search)
-> true
; sha1_title(SHA1, Title),
sub_atom_icasechk(Title, _, Search)
).
pack_search_result(Pack, pack(Pack, p, Title, VersionA, URLs)) :-
pack_latest_version(Pack, SHA1, Version, _Older),
sha1_title(SHA1, Title),
atom_version(VersionA, Version),
findall(URL, sha1_url(SHA1, URL), URLs).
/*******************************
* DATABASE *
*******************************/
:- multifile error:has_type/2.
error:has_type(dependency, Value) :-
is_dependency(Value, _Token, _Version).
is_dependency(Token, Token, *) :-
atom(Token).
is_dependency(Term, Token, VersionCmp) :-
Term =.. [Op,Token,Version],
cmp(Op, _),
version_data(Version, _),
VersionCmp =.. [Op,Version].
cmp(<, @<).
cmp(=<, @=<).
cmp(==, ==).
cmp(=, =).
cmp(>=, @>=).
cmp(>, @>).
version_data(Version, version(Data)) :-
atomic_list_concat(Parts, '.', Version),
maplist(atom_number, Parts, Data).
:- persistent
sha1_pack(sha1:atom, pack:atom),
sha1_file(sha1:atom, file:atom),
sha1_requires(sha1:atom, token:dependency),
sha1_provides(sha1:atom, token:dependency),
sha1_conflicts(sha1:atom, token:dependency),
sha1_info(sha1:atom, info:list),
sha1_url(sha1:atom, url:atom),
sha1_download(sha1:atom, peer:atom),
pack_allowed_url(pack:atom, isgit:boolean, pattern:atom).
:- initialization
absolute_file_name(data('packs.db'), File,
[ access(write) ]),
db_attach(File, [sync(close)]),
populate_pack_url_patterns.
%! delete_pack(+PackName) is det.
%
% Remove a pack from the database.
delete_pack(PackName) :-
must_be(atom, PackName),
pack(PackName),
!,
clean_pack_info(PackName),
pack_unmirror(PackName),
forall(sha1_pack(Hash, PackName),
delete_hash(Hash)),
retractall_pack_allowed_url(PackName,_,_),
print_message(informational, delete_pack(PackName)).
delete_pack(PackName) :-
existence_error(pack, PackName).
%! delete_hash(Hash) is det.
%
% Remove Hash from the database
delete_hash(Hash) :-
retractall_sha1_pack(Hash, _),
retractall_sha1_file(Hash, _),
retractall_sha1_requires(Hash, _),
retractall_sha1_provides(Hash, _),
retractall_sha1_conflicts(Hash, _),
retractall_sha1_info(Hash, _),
retractall_sha1_url(Hash, _),
retractall_sha1_download(Hash, _),
print_message(informational, delete_hash(Hash)).
%! save_request(+Peer, +Data, -Result)
%
% Update the database with the given information. We only update
% if the request is new, which means the same SHA1 has not been
% downloaded from the same Peer.
:- det(save_request/3).
save_request(Peer, download(URL, Hash, Metadata), Result) =>
Result = Pack-Action,
memberchk(name(Pack), Metadata),
with_mutex(pack, save_request(URL, Hash, Metadata, Peer, Action)).
save_request(URL, Hash, Metadata, Peer, Result) :-
( Error = error(Formal,_),
catch(save_request_(URL, Hash, Metadata, Peer, Res0),
Error,
true)
-> ( var(Formal)
-> Result = Res0
; Result = throw(Error)
)
; Result = false
).
save_request_(URL, SHA1, Info, Peer, Result) :-
sha1_download(SHA1, Peer),
sha1_pack(SHA1, Peer), % already downloaded from here
!,
info_is_git(Info, IsGIT),
register_url(SHA1, IsGIT, URL, Result). % but maybe from a different URL
save_request_(URL, SHA1, Info, Peer, Result) :-
memberchk(name(Pack), Info),
info_is_git(Info, IsGIT),
( accept_url(URL, Pack, IsGIT)
-> register_url(SHA1, IsGIT, URL, Result0),
register_pack(SHA1, Pack),
register_info(SHA1, Info)
; permission_error(register, pack(Pack), URL)
),
assert_sha1_download(SHA1, Peer),
( Result0 == no_change
-> Result = download
; Result = Result0
).
info_is_git(Info, IsGIT) :-
memberchk(git(IsGIT), Info),
!.
info_is_git(_, false).
%! accept_url(+URL, +Pack, +IsGit) is det.
%
% True when URL is an aceptable URL for Pack. We only
% register this on the first submission of a pack.
accept_url(URL, Pack, IsGIT) :-
( pack_allowed_url(Pack, _, Pattern)
*-> wildcard_match(Pattern, URL), !
; admissible_url(URL)
-> url_pattern(URL, IsGIT, Pattern),
assert_pack_allowed_url(Pack, IsGIT, Pattern)
).
admissible_url(URL) :-
uri_components(URL, Components),
uri_data(scheme, Components, Scheme),
uri_data(authority, Components, Authority),
uri_authority_components(Authority, AuthComponents),
uri_authority_data(host, AuthComponents, Host),
uri_authority_data(port, AuthComponents, Port),
\+ nonadmissible_host(Host),
admissible_scheme(Scheme, Port).
nonadmissible_host(localhost).
nonadmissible_host(IP) :-
split_string(IP, ".", "", Parts),
maplist(number_string, _, Parts).
admissible_scheme(http, 80).
admissible_scheme(https, 443).
url_pattern(URL, true, URL) :- !.
url_pattern(URL, false, Pattern) :-
site_pattern(URL, Pattern),
!.
url_pattern(URL, false, Pattern) :-
( atom_concat('http://', Rest, URL)
-> atom_concat('http{,s}://', Rest, URL2)
; URL2 = URL
),
file_directory_name(URL2, Dir),
atom_concat(Dir, '/*', Pattern).
site_pattern(URL, Pattern) :-
sub_atom(URL, 0, _, _, 'https://gitlab.com/'),
git_user_project_pattern(URL, Pattern).
site_pattern(URL, Pattern) :-
sub_atom(URL, 0, _, _, 'https://github.com/'),
git_user_project_pattern(URL, Pattern).
git_user_project_pattern(URL, Pattern) :-
uri_components(URL, Components),
uri_data(path, Components, Path0),
split_string(Path0, "/", "/", [User,Project|_]),
atomic_list_concat([/, User, /, Project, /, *], Path),
uri_data(path, Components, Path, Components1),
uri_components(Pattern, Components1).
populate_pack_url_patterns :-
forall(pack(Pack),
populate_pack_url_pattern(Pack)).
populate_pack_url_pattern(Pack) :-
pack_allowed_url(Pack, _, _),
!.
populate_pack_url_pattern(Pack) :-
findall(URL-IsGIT,
( sha1_pack(SHA1, Pack),
sha1_info(SHA1, Info),
( memberchk(git(IsGIT), Info)
-> true
; IsGIT = false
),
sha1_url(SHA1, URL)
),
URLS),
last(URLS, URL-IsGIT),
url_pattern(URL, IsGIT, Pattern),
assert_pack_allowed_url(Pack, IsGIT, Pattern),
!.
populate_pack_url_pattern(Pack) :-
print_message(error, pack(pattern_failed(Pack))).
%! set_allowed_url(+Request)
%
% Set the URL pattern for a pack.
set_allowed_url(Request) :-
admin_user,
http_parameters(Request,
[ p(Pack, []),
url(Pattern, []),
git(IsGit, [boolean, optional(true)])
], []),
call_showing_messages(set_allowed_url(Pack, IsGit, Pattern), []).
set_allowed_url(Request) :-
memberchk(path(Path), Request),
throw(http_reply(forbidden(Path))).
set_allowed_url(Pack, _IsGit, _Pattern) :-
\+ sha1_pack(_, Pack),
!,
existence_error(pack, Pack).
set_allowed_url(Pack, IsGit, Pattern) :-
( var(IsGit)
-> ( sub_atom(Pattern, _, _, _, *)
-> IsGit = false
; IsGit = true
)
; true
),
retractall_pack_allowed_url(Pack, _, _),
assert_pack_allowed_url(Pack, IsGit, Pattern).
%! register_pack(+SHA1, +Pack) is det.
register_pack(SHA1, Pack) :-
( sha1_pack(SHA1, Pack)
-> true
; assert_sha1_pack(SHA1, Pack)
).
register_info(SHA1, Info0) :-
sort(Info0, Info),
( sha1_info(SHA1, _Info)
-> true
; assert_sha1_info(SHA1, Info),
forall(member(requires(Token), Info),
register_requires(SHA1, Token)),
forall(member(provides(Token), Info),
register_provides(SHA1, Token)),
forall(member(conflicts(Token), Info),
register_conflicts(SHA1, Token))
).
register_requires(SHA1, Token) :-
( sha1_requires(SHA1, Token)
-> true
; assert_sha1_requires(SHA1, Token)
).
register_provides(SHA1, Token) :-
( sha1_provides(SHA1, Token)
-> true
; assert_sha1_provides(SHA1, Token)
).
register_conflicts(SHA1, Token) :-
( sha1_conflicts(SHA1, Token)
-> true
; assert_sha1_conflicts(SHA1, Token)
).
%! register_url(+SHA1, +IsGIT, +URL) is det.
%
% Register we have that data loaded from URL has signature SHA1.
:- debug(pack(changed)).
register_url(SHA1, IsGIT, URL, Result) :-
( sha1_url(SHA1, URL)
-> Result = no_change
; sha1_url(SHA2, URL),
\+ ( IsGIT == true,
hash_git_url(SHA2, URL)
),
( debug(pack(changed), '~p seems changed', [URL]),
is_github_release(URL)
-> debug(pack(changed), 'From github: ~p', [URL]),
retractall_sha1_url(SHA1, URL),
fail
; true
)
-> Result = throw(pack(modified_hash(SHA1-URL, SHA2-[URL])))
; IsGIT == true
-> assert_sha1_url(SHA1, URL),
Result = git(URL)
; prolog_pack:pack_url_file(URL, File),
register_file(SHA1, File, URL),
assert_sha1_url(SHA1, URL),
Result = file(URL)
).
%! is_github_release(+URL) is semidet.
%
% True when URL reflects a GitHub release pack download. These
% have the unpeleasant habbit to change exact content.
is_github_release(URL) :-
uri_components(URL, Components),
uri_data(scheme, Components, Scheme), Scheme == https,
uri_data(authority, Components, Auth), Auth == 'github.com',
uri_data(path, Components, Path), atomic(Path),
split_string(Path, "/", "", ["", _User, _Repo, "archive", Zip]),
file_name_extension(_, Ext, Zip),
github_archive_extension(Ext).
github_archive_extension(tgz).
github_archive_extension(zip).
register_file(SHA1, File, URL) :-
( sha1_file(SHA1, File)
-> true
; sha1_file(SHA2, File),
sha1_urls(SHA2, URLs),
( maplist(is_github_release, [URL|URLs])
-> retractall_sha1_file(SHA1, File),
fail
; true
)
-> throw(pack(modified_hash(SHA1-URL, SHA2-URLs)))
; assert_sha1_file(SHA1, File)
).
%! hash_git_url(+SHA1, -GitURL) is semidet.
%
% True when SHA1 was installed using GIT from GitURL.
hash_git_url(SHA1, GitURL) :-
sha1_info(SHA1, Info),
memberchk(git(true), Info),
!,
sha1_url(SHA1, GitURL).
%! hash_file_url(+SHA1, -FileURL) is nondet.
%
% True when SHA1 was installed using GIT from GitURL.
hash_file_url(SHA1, FileURL) :-
sha1_info(SHA1, Info),
\+ memberchk(git(true), Info),
!,
sha1_url(SHA1, FileURL).
%! pack_url_hash(?URL, ?Hash) is nondet.
%
% True when Hash is the registered hash for URL.
pack_url_hash(URL, Hash) :-
sha1_url(Hash, URL).
%! pack(?Pack) is nondet.
%
% True when Pack is a currently known pack.
pack(Pack) :-
findall(Pack, sha1_pack(_,Pack), Packs),
sort(Packs, Sorted),
member(Pack, Sorted).
/*******************************
* USER API *
*******************************/
%! pack_list(+Request)
%
% List available packages.
pack_list(Request) :-
memberchk(path_info(SlashPack), Request),
atom_concat(/, Pack, SlashPack),
format(atom(Title), '"~w" pack for SWI-Prolog', [Pack]),
reply_html_page(pack(list),
title(Title),
[ \pack_listing(Pack, _Author, _Sort)
]).
pack_list(Request) :-
http_parameters(Request,
[ p(Pack, [optional(true)]),
author(Author, [optional(true)]),
sort(Sort, [ oneof([name,downloads,rating]),
optional(true),
default(name)
])
]),
( ground(Pack)
-> format(atom(Title), '"~w" pack for SWI-Prolog', [Pack])
; Title = 'SWI-Prolog packages'
),
reply_html_page(pack(list),
title(Title),
[ \pack_listing(Pack, Author, Sort)
]).
pack_listing(Pack, _Author, _Sort) -->
{ ground(Pack) },
!,
html([ h1(class(wiki), 'Package "~w"'-[Pack]),
\html_requires(css('pack.css')),
\pack_info(Pack)
]).
pack_listing(_Pack, Author, SortBy) -->
{ ( nonvar(Author)
-> Filter = [author(Author)]
; Filter = []
),
( setof(Pack, current_pack(Filter, Pack), Packs)
-> true
; Packs = []
),
sort_packs(SortBy, Packs, Sorted)
},
html({|html||
<p>
Below is a list of known packages. Please be aware that packages are
<b>not moderated</b>. Installing a pack does not execute code in the
pack, but simply loading a library from the pack may execute arbitrary
code. More information about packages is available <a
href="/howto/Pack.html">here</a>. You can search for packages from
the Prolog command line using pack_list/1. This contacts the pack
server for packs that match by name or title. A leading <b>i</b>
indicates that the pack is already installed, while <b>p</b> merely
indicates that it is known by the server.
</p>
<pre class="code">
?- pack_list(graph).
p [email protected] - Predicate call graph visualisation
i [email protected] - Write GraphML files
i [email protected] - Show Prolog terms using graphviz
p [email protected] - Musicbrainz client library
p [email protected] - Access to Sindice semantic web search engine
</pre>
<p>
After finding the right pack, the pack and its dependencies can be installed
using the pack_install/1 as illustrated below.
</p>
<pre class="code">
?- pack_install(hello).
</pre>
<p>
Clicking the package shows details and allows you to rate and comment
the pack.
</p>
|}),
pack_table(Sorted, [sort_by(SortBy)]),
html_receive(rating_scripts).
%! pack_table(+Packs, +Options)// is det.
%
% Show a table of packs.
pack_table(Packs, Options) -->
{ option(sort_by(SortBy), Options, -),
length(Packs, PackCount),
maplist(pack_downloads, Packs, Totals),
sum_list(Totals, Total)
},
html_requires(css('pack.css')),
html(table(class(packlist),
[ tr([ \pack_header(name, SortBy,