-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathlatex2html.pl
3270 lines (2917 loc) · 96 KB
/
latex2html.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* Part of SWI-Prolog
Author: Jan Wielemaker
E-mail: [email protected]
WWW: http://www.swi-prolog.org
Copyright (c) 1997-2023, University of Amsterdam
VU University Amsterdam
CWI, Amsterdam
SWI-Prolog Solutions b.v.
All rights reserved.
Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions
are met:
1. Redistributions of source code must retain the above copyright
notice, this list of conditions and the following disclaimer.
2. Redistributions in binary form must reproduce the above copyright
notice, this list of conditions and the following disclaimer in
the documentation and/or other materials provided with the
distribution.
THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
"AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
POSSIBILITY OF SUCH DAMAGE.
*/
:- module(tex,
[ welcome/0,
latex2html/1, % +BaseName
latex2html/2, % +BaseName, +Options
macro_expand/2, % +In, -Out
translate/4, % +In, +ModeIn, -ModeOut, -Out
translate/3, % +In, +ModeIn, -Out
latex2html_module/0, % Register extension module
tex_input_directory/1, % +Input Dir
step_counter/2, % +Name, -NewValue
ps2gif/3, % +PsFile, -GifFile, +Options
translate_command/4, % +In, +ModeIn, -ModeOut, -HTML
translate_environment/4, % +In, +ModeIn, -ModeOut, -HTML
translate_reference/4, % +Kind, +RefPrefix, +Label, -HTML
translate_table/3, % +Format, +BodyTokens, -HTML
translate_section/4, % +Level, -/*, +Title, -HTML
translate_section/5, % +Level, -/*, +Title, -HTML, +FileBase
current_setting/1, % +Type(-Value ...)
do_float/2, % +Float(+Number), :Goal
tex_load_commands/1, % +BaseName
add_to_index/1, % +Term
add_to_index/2, % +Term, +Tag
clean_tt/2, % +Raw, -Clean
op(100, fx, #)
]).
:- use_module(library(debug),[debug/3]).
:- autoload(library(apply),[maplist/3]).
:- autoload(library(backcomp),[convert_time/8]).
:- autoload(library(ctypes),
[is_lower/1,to_upper/2,is_alpha/1,is_upper/1,to_lower/2]).
:- autoload(library(filesex),[copy_file/2,directory_file_path/3]).
:- autoload(library(gui_tracer),[gtrace/0]).
:- autoload(library(lists),
[ reverse/2,
member/2,
flatten/2,
append/3,
select/3,
nth1/3,
last/2
]).
:- autoload(library(main),[main/0,argv_options/3]).
:- autoload(library(occurs),[sub_term/2]).
:- autoload(library(option),[option/2,select_option/3]).
:- autoload(library(readutil),[read_file_to_codes/3]).
:- autoload(library(statistics),[statistics/0]).
ltx2htm_version('0.98'). % for SWI-Prolog 5.6.18
page_header('<!DOCTYPE HTML PUBLIC "-//W3C//DTD HTML 4.01//EN" \c
"http://www.w3.org/TR/html4/strict.dtd">\n\n').
:- dynamic
html_output_dir/1, % output relative to this dir
tex_file_base/1, % Basename of the main file
html_file_base/1, % Basename of main output file
html_split_level/1, % Split upto this level
bodycolor/1, % \bodycolor storage
title/1, % \title{} storage
author/1, % \auther{} command storage
link_image/2, % Id, Image
center_tables/0,
quiet/0.
:- discontiguous
cmd/2,
cmd/3,
cmd/4.
html_split_level(2).
html_file_base('Title').
:- multifile
user:file_search_path/2.
:- dynamic
user:file_search_path/2.
add_my_path :-
user:file_search_path(latex2html, _),
!.
add_my_path :-
prolog_load_context(directory, Dir),
asserta(user:file_search_path(latex2html, Dir)).
:- initialization(add_my_path, now).
user:file_search_path(psfig, tex(figs)).
user:file_search_path(includegraphics, tex(figs)).
user:file_search_path(includegraphics, tex(.)).
user:file_search_path(tex, '.').
user:file_search_path(img, '.').
user:file_search_path(img, icons).
user:file_search_path(img, latex2html(icons)).
:- use_foreign_library(foreign(tex)).
% support list_strings/0
:- multifile check:valid_string_goal/1.
check:valid_string_goal(tex:delete_all(_,S,_)) :- string(S).
check:valid_string_goal(tex:replace_all(_,S1,S2,_)) :- string(S1), string(S2).
check:valid_string_goal(tex:string_without(S,_,_,_)) :- string(S).
/*******************************
* TEX INPUTS *
*******************************/
read_tex_inputs :-
getenv('TEXINPUTS', Val),
!,
read_tex_inputs(Val).
read_tex_inputs.
read_tex_inputs(Val) :-
split(Val, 0':, PathElement),
retractall(user:file_search_path(tex, _)),
reverse(PathElement, RevPath),
forall(member(E, RevPath), assert_tex_input(E)).
assert_tex_input('') :-
!,
retractall(user:file_search_path(tex, '.')),
asserta(user:file_search_path(tex, '.')).
assert_tex_input(Dir) :-
retractall(user:file_search_path(tex, Dir)),
asserta(user:file_search_path(tex, Dir)).
/*******************************
* EXTENSION MODULES *
*******************************/
:- dynamic
tex_extension_module/1.
tex_extension_module(tex).
:- module_transparent
latex2html_module/0.
latex2html_module :-
context_module(M),
( tex:tex_extension_module(M)
-> true
; asserta(tex:tex_extension_module(M))
),
M:dynamic((cmd/2, cmd/3, cmd/4, env/2, (#)/2)),
M:discontiguous((cmd/2, cmd/3, cmd/4, env/2, (#)/2)),
M:dynamic((list_command/4)).
% Load a tex command file
tex_load_commands(File) :-
( package_alias(File, Alias),
member(Term, [tex(Alias), latex2html(Alias)]),
absolute_file_name(Term,
CmdFile,
[ extensions([cmd]),
access(read),
file_errors(fail)
])
-> tex_read_commands(CmdFile),
( quiet
-> true
; format(user_error, 'Loaded LaTeX commands from "~w"~n', [CmdFile])
)
; format(user_error,
'Can not find command file "~w"~n', [File]),
fail
).
tex_input_directory(D) :-
asserta(user:file_search_path(tex, D)).
% current_setting(?Term)
%
% Report current settings to the extension module
current_setting(keep_figures) :-
keep_figures(true).
current_setting(html_output_dir(Dir)) :-
html_output_dir(Dir).
/*******************************
* SETTINGS *
*******************************/
:- dynamic
keep_figures/1,
onefile/1,
makeindex/1,
title/1,
auther/1.
keep_figures(true).
onefile(false).
makeindex(false).
title('No title').
author('Anonymous').
/*******************************
* TOPLEVEL *
*******************************/
run_latex2html(TeXFile) :-
reset_counters,
reset_sections,
reset_index,
reset_labels,
reset_cites,
reset_output,
tex_tokens(TeXFile, TeXTokens),
( member(env(document, _, _), TeXTokens)
-> translate(TeXTokens, preamble, HTML)
; format(user_error,
'No document environment; processing anyway~n', []),
translate(TeXTokens, document, HTML)
),
once(html_file_base(Base)),
expand_macros([tell(Base), #header], Header),
make_index(Index),
flatten([ Header,
HTML,
Index
],
HtmlDocument),
collect_labels(HtmlDocument, Base),
write_html(HtmlDocument),
close_output.
latex2html(Spec) :-
latex2html(Spec, []).
latex2html(Spec, Options) :-
welcome(Options),
tex_load_commands(latex),
file_name_extension(Spec, tex, TeXFile),
file_name_extension(Base, tex, TeXFile),
absolute_file_name(tex(TeXFile),
[ access(read)
],
TheTeXFile),
asserta(html_output_dir(Base)),
asserta(tex_file_base(Base)),
run_latex2html(TheTeXFile),
goodbye(Options),
retract(tex_file_base(_)),
retract(html_output_dir(_)).
% make_output_directory
%
% Create the output directory.
:- dynamic
done_make_output_directory/0.
make_output_directory :-
done_make_output_directory,
!.
make_output_directory :-
html_output_dir(Dir),
!,
( exists_directory(Dir)
-> true
; make_directory(Dir)
),
assert(done_make_output_directory).
:- dynamic
current_html_output_db/1, % Base
in_head/1.
reset_output :-
retractall(current_html_output_db(_)),
retractall(in_head(_)).
open_output(Base) :-
make_output_directory,
html_output_dir(Dir),
!,
atomic_list_concat([Dir, /, Base, '.html'], HtmlFile),
tex_tell(HtmlFile),
page_header(Header),
put_html_token(html(Header)),
put_html_token(html('<html>')),
asserta(current_html_output_db(Base)).
close_output :-
( retract(current_html_output_db(_))
-> put_html_token(html('</body>')),
put_html_token(html('</html>'))
; true
),
tex_told.
current_html_output(Raw) :-
current_html_output_db(File),
!,
File = Raw.
welcome :-
welcome([]).
welcome(Options) :-
option(quiet(true), Options),
!.
welcome(_Options) :-
ltx2htm_version(Version),
format(user_error, 'Welcome to LaTeX2HTML version ~w~n~n', [Version]).
goodbye(Options) :-
option(quiet(true), Options),
!.
goodbye(_Options) :-
html_output_dir(Dir),
html_file_base(Html),
format(user_error, '~*t~72|~n', [0'*]),
format(user_error,
'Translation completed; output written to "~w/~w.html".~n',
[Dir, Html]),
format(user_error, 'Prolog statistics:~n~n', []),
statistics.
% translate(+TeX, +Mode, -HTML)
translate(TeX, Mode, HTML) :-
translate(TeX, Mode, _, HTML).
translate([], Mode, Mode, []) :- !.
translate([\(Section, -, [{Title}])|T], Mode, Mode, HTML) :-
trans_section(Section, Title, T, TitleHtml),
!,
append(TitleHtml, BodyHtml, HTML),
translate(T, Mode, Mode, BodyHtml).
translate(['`','`'|T0], Mode0, Mode, [html(' “')|T]) :-
\+ in_macro(code(_)),
!,
translate(T0, Mode0, Mode, T).
translate(['\'','\''|T0], Mode0, Mode, [html('” ')|T]) :-
\+ in_macro(code(_)),
!,
translate(T0, Mode0, Mode, T).
translate([H0|T0], Mode0, Mode, [H|T]) :-
!,
translate_1(H0, Mode0, Mode1, H),
translate(T0, Mode1, Mode, T).
translate(X, Mode, Mode, []) :-
format(user_error, 'translate(~p) failed in mode "~w"~n', [X, Mode]).
translate_1(Term, Mode0, Mode, HTML) :-
( translate_2(Term, Mode0, Mode, HTML)
-> true
; format(user_error, 'translate_2(~p, ~w, ...) failed~n',
[Term, Mode0]),
Mode = Mode0,
HTML = []
).
translate_2(\(Cmd, Mod, Args), Mode0, Mode, HTML) :- % \cmd*{Args}
Term =.. [Cmd, Mod|Args],
translate_command(Term, Mode0, Mode, HTML).
translate_2(\(Cmd, Args), Mode0, Mode, HTML) :- % \cmd{Args}
Term =.. [Cmd|Args],
translate_command(Term, Mode0, Mode, HTML).
translate_2(\Cmd, Mode0, Mode, HTML) :- % \cmd
translate_command(Cmd, Mode0, Mode, HTML).
translate_2(env(Env, Args, Bdy), Mode0, Mode, HTML) :- % \begin{x} ... \end{x}
Term =.. [Env, Args, Bdy],
translate_environment(Term, Mode0, Mode, HTML).
translate_2($$(Expr), Mode, Mode, #quote(#var(HTML))) :-% $$...$$
tex_atom_to_tokens(Expr, Tokens),
translate(Tokens, math, _, HTML).
translate_2($(Expr), Mode, Mode, #var(HTML)) :- % $...$
tex_atom_to_tokens(Expr, Tokens),
translate(Tokens, math, _, HTML).
translate_2(verbatim(_Cmd, Text), Mode, Mode, % \begin{verbatim} ...
#pre(code, pre(Text))).
translate_2(verb(_, Text), pcecode, pcecode, pre(Text)).
translate_2(Layout, pcecode, pcecode, []) :-
atomic(Layout),
!.
translate_2('\n', Mode, Mode, [html('<br>')]) :-
Mode = group(Atts),
memberchk(obeylines, Atts),
!.
translate_2(verb(_, Text), Mode, Mode, #code(Text)). % \verbX...X
translate_2([Atom], Mode, Mode, nospace(Atom)) :- % {foo}
atomic(Atom).
translate_2(Group, Mode, Mode, HTML) :- % {...}
Group = [_|_],
translate_group(Group, HTML).
translate_2(~, Mode, Mode, html(' ')). % ~
translate_2('`', Mode, Mode, html('‘')). % `
translate_2('\'', Mode, Mode, html('’')). % '
translate_2(~, Mode, Mode, html(' ')). % ~
translate_2('\\[]', Mode, Mode, html('[]')). % []
translate_2(Atom0, Mode, Mode, Atom) :- % Normal word
atomic(Atom0),
( Mode = group(Atts),
memberchk(font(sc), Atts)
-> upcase_atom(Atom0, Atom)
; Atom = Atom0
).
translate_group(Group, [HTML, Close]) :- % {...}
translate(Group, group([]), MEnd, HTML),
( MEnd = group(Attributes),
member(font(EndFont), Attributes),
html_font(EndFont, _, Close)
-> true
; Close = []
).
translate_command(Cmd, Mode0, Mode, HTML) :-
translate_cmd(Cmd, Mode0, Mode, HTML0),
expand_macros(HTML0, HTML).
translate_cmd(Cmd, Mode0, Mode, HTML) :-
tex_extension_module(M),
M:cmd(Cmd, Mode0, Mode, HTML),
!.
translate_cmd(Cmd, Mode, Mode, HTML) :-
tex_extension_module(M),
M:cmd(Cmd, Mode, HTML),
!.
translate_cmd(Cmd, Mode, Mode, HTML) :-
tex_extension_module(M),
M:cmd(Cmd, HTML),
!.
translate_cmd(Cmd, Mode, Mode, []) :-
functor(Cmd, Name, _),
format(user_error,
'Failed to translate \\~w in mode "~w"~n', [Name, Mode]),
format(user_error, 'Term: "~p"~n', [Cmd]),
true.
translate_environment(Env, Mode, Mode, HTML) :-
translate_env(Env, Mode, Mode, HTML0),
expand_macros(HTML0, HTML).
translate_env(Env, Mode, Mode, HTML) :-
tex_extension_module(M),
M:env(Env, HTML),
!.
translate_env(Env, Mode, Mode, []) :-
functor(Env, Name, _),
format(user_error,
'Failed to translate \\begin{~w} ... \\end{~w}~n',
[Name, Name]),
% format(user_error, 'Term: "~p"~n', [Env]),
true.
/*******************************
* LANGUAGE *
*******************************/
language_map(figure, 'Figure').
language_map(table, 'Table').
/*******************************
* # MACROS *
*******************************/
:- dynamic
in_anchor/0. % avoid nesting anchors
% #(+Macro, -Expansion)
% Do HTML macro expansion on the fly.
#(tell(_File), []) :- onefile(true).
#(tell(File), tell(File)).
#(head(Head), [html('<head>'), HtmlHead, Style, html('</head>')]) :-
expand_macros(Head, HtmlHead),
expand_macros(#style, Style).
#(style, [ html('<style type="text/css">'),
html(Style),
html('</style>')
]) :-
absolute_file_name(latex2html('latex2html.css'), StyleFile,
[ access(read) ]),
read_file_to_codes(StyleFile, Codes, []),
atom_codes(Style, Codes).
#(beginbody, html(Body)) :-
bodycolor(Colour),
!,
format(string(Body), '<body style="background:~w">', [Colour]).
#(beginbody, html('<body>')).
#(endbody, html('</body>')).
#(thetitle, Title) :-
title(Title).
#(theauthor, Author) :-
author(Author).
#(nameof(Type), Name) :-
language_map(Type, Name).
#(title(Text), [html('<title>'), Text, html('</title>')]).
#(var(Text), [html('<var>'), Text, html('</var>')]).
#(code(Text), [html('<code>'), Text, html('</code>')]).
#(pre(Text), [html('<pre>'), Text, html('</pre>')]).
#(pre(Class, Text), [html(Begin), Text, html('</pre>')]) :-
format(atom(Begin), '<pre class="~w">', [Class]).
#(xmp(Text), [html('<xmp>'), Text, html('</xmp>')]).
#(strong(Text), [html('<strong>'), Text, html('</strong>')]).
#(em(Text), [html('<em>'), Text, html('</em>')]).
#(b(Text), [html('<b>'), Text, html('</b>')]).
#(i(Text), [html('<i>'), Text, html('</i>')]).
#(tt(Text), [html('<code>'), Text, html('</code>')]).
#(sc(Text), [html('<span style="font-variant:small-caps">'),
Text, html('</span>')]).
#(div(Class, Text), [html(Begin), Text, html('</div>')]) :-
format(atom(Begin), '<div class="~w">', [Class]).
#(span(Class, Text), [html(Begin), Text, html('</span>')]) :-
format(atom(Begin), '<span class="~w">', [Class]).
#(center(Text), [ html('<div style="text-align:center">'),
Text,
html('</div>')
]).
#(navigate(Text), [html('<div class="navigate">'), Text, html('</div>')]).
#(right(Text), [html('<right>'), Text, html('</right>')]).
#(quote(Text), [html('<blockquote>'), Text, html('</blockquote>')]).
#(listing(Text), [html('<p><table width="90%" align=center border=6 bgcolor="#e0e0e0"><tr><td nowrap>'), Text,
html('</table>')]).
#(abstract(Text), [ html('<div class="abstract">'),
html('<div class="abstract-title">Abstract</div>'),
Text,
html('</div>')
]).
#(footnote(Text), #footnote(Mark, Text)) :-
step_counter(footnote, Mark).
#(footnote(Mark, Text), [ html('<sup class="fn">'), Mark,
#span('fn-text', Text),
html('</sup>')
]).
#(embrace(OC,Text), [nospace(OA), Text, nospace(CA)]) :-
string_codes(OC, [O,C]),
char_code(OA, O),
char_code(CA, C).
#(embrace(Text), #embrace("()", Text)).
#(h(Level, Title), [html(OpenH), Title, html(CloseH)]) :-
h(Level, OpenH, CloseH).
#(h(Level, NumRef, Title), [h(Level, NumRef, Title), Title, html(CloseH)]) :-
h(Level, _OpenH, CloseH).
#(predref(RN, Arity), #lref(pred, Label, Text)) :-
clean_tt(RN, Name),
format(string(Text), '~w/~w', [Name, Arity]),
latex2html4pl:predicate_refname(Name, Arity, Label).
#(dcgref(RN, Arity), #lref(pred, Label, Text)) :-
clean_tt(RN, Name),
format(string(Text), '~w//~w', [Name, Arity]),
latex2html4pl:dcg_refname(Name, Arity, Label).
#(funcref(RN, Arity), #lref(function, Label, Text)) :-
clean_tt(RN, Name),
format(string(Text), '~w/~w', [Name, Arity]),
latex2html4pl:function_refname(Name, Arity, Label).
#(row(Columns), [html('<tr>'), HtmlCols, html('</tr>')]) :-
add_td(Columns, HtmlCols).
#(label(Lbl, Text, Tag),label(ALabel, Expanded, Tag)) :-
atom_string(ALabel, Lbl),
expand_macros(Text, Expanded).
#(label(Lbl, Text), label(ALabel, Expanded, -)) :-
atom_string(ALabel, Lbl),
expand_macros(Text, Expanded).
#(lref(Label, Text), Expanded) :-
!,
#(lref('', Label, Text), Expanded).
#(lref(_, _Label, Text), Text) :-
in_anchor,
!.
#(lref(Class, Label, Text), lref(Class, ALabel, Expanded)) :-
canonicalise_label(Label, ALabel),
asserta(in_anchor),
expand_macros(Text, Expanded),
retractall(in_anchor).
#(iflref(Label, Text), iflref(ALabel, Expanded)) :-
canonicalise_label(Label, ALabel),
expand_macros(Text, Expanded).
#(url(_URL, Text), Text) :-
in_anchor,
!.
#(url(URL, Text), [html(Anchor), Expanded, html('</a>')]) :-
format(string(Anchor), '<a class="url" href="~w">', URL),
setup_call_cleanup(
asserta(in_anchor, Ref),
expand_macros(Text, Expanded),
erase(Ref)).
#(cite(Key), [ html('<cite>'),
Cites,
html('</cite>')
]) :-
cite_references(Key, cite, Cites).
#(opencite(Key), [ html('<cite>'),
Cites,
html('</cite>')
]) :-
cite_references(Key, cite, Cites).
#(yearcite(Key), [ html('<cite>'),
Cites,
html('</cite>')
]) :-
cite_references(Key, yearcite, Cites).
#(nocite(_), []).
#(header, HTML) :-
node_header(HTML).
#(header(Tag), HTML) :-
node_header(Tag, HTML).
#(footer(Tag), HTML) :-
node_footer(Tag, HTML).
#(next_and_prev_references,
[ #iflref(prevfile, '[Previous]'), ' ',
#iflref(nextfile, '[Next]')
]).
#(home_reference,
[ #iflref(home, '[Home]')
]).
#(Macro, []) :-
format(user_error,
'Post-processing macro #~p could not be expanded~n',
[Macro]),
gtrace, fail.
add_td([], []).
add_td([H|T0], [html('<td>'), H, html('</td>')|T]) :-
add_td(T0, T).
cite_references(KeyIn, Functor, Refs) :-
split(KeyIn, 0',, Keys),
make_cite_references(Keys, Functor, Refs).
make_cite_references([], _, []).
make_cite_references([Key], F, [#lref(cite, Key, Term)]) :-
!,
Term =.. [F, Key].
make_cite_references([Key|T0], F, [#lref(cite, Key, Term), nospace(','), ' '|T]) :-
Term =.. [F, Key],
make_cite_references(T0, F, T).
% canonicalise_label(+Raw, -Canonical)
%
% Ensures the label is either an atom, or fileof(Atom), so unification
% will work properly.
canonicalise_label(Atom, Atom) :-
atom(Atom),
!.
canonicalise_label(Atomic, Atom) :-
atomic(Atomic),
!,
atom_string(Atom, Atomic).
canonicalise_label(fileof(In), Out) :-
onefile(true),
!,
canonicalise_label(In, Out).
canonicalise_label(fileof(In), fileof(Out)) :-
canonicalise_label(In, Out).
%! expand_macros(Raw, Expanded).
%! macro_expand(Raw, Expanded).
%
% Expand +Term, Mode+Term and #Macro commands into plain HTML
macro_expand(In, Out) :-
expand_macros(In, Out).
expand_macros([], []) :- !.
expand_macros([[]|T0], [T]) :-
!,
expand_macros(T0, T).
expand_macros([H0|T0], [H|T]) :-
!,
expand_macro(H0, H),
expand_macros(T0, T).
expand_macros(Macro, Expanded) :-
expand_macro(Macro, Expanded).
expand_macro(+Term, HTML) :-
!,
translate(Term, normal, HTML0),
expand_macros(HTML0, HTML).
expand_macro(Mode+Term, HTML) :-
!,
translate(Term, Mode, HTML0),
expand_macros(HTML0, HTML).
expand_macro(#Macro, HTML) :-
tex_extension_module(M),
M:'#'(Macro, HTML0),
!,
push_macro(Macro),
expand_macros(HTML0, HTML),
pop_macro.
expand_macro(List, Expanded) :-
List = [_|_],
!,
expand_macros(List, Expanded).
expand_macro(NoExpand, NoExpand).
push_macro(Macro) :-
nb_current(macro_stack, Stack),
!,
b_setval(macro_stack, [Macro|Stack]).
push_macro(Macro) :-
b_setval(macro_stack, [Macro]).
pop_macro :-
nb_current(macro_stack, [_|Stack]),
!,
b_setval(macro_stack, Stack).
in_macro(Env) :-
nb_current(macro_stack, Stack),
\+ \+ memberchk(Env, Stack).
/*******************************
* CITES *
*******************************/
:- dynamic
cite/2. % Key, Cite (HTML)
reset_cites :-
retractall(cite(_, _)).
/*******************************
* FLOAT *
*******************************/
:- dynamic
current_float/2. % Type, Number
:- meta_predicate
do_float(+, 0).
% do_float(+Type(+Number), +Goal)
%
% Run goal, registering the current float object processed.
do_float(Term, Goal) :-
functor(Term, Type, 1),
arg(1, Term, Number),
asserta(tex:current_float(Type, Number), Ref),
ignore(Goal),
erase(Ref).
/*******************************
* LABEL/REF *
*******************************/
:- dynamic
label/3, % Label, File, Index
next_file/2, % File, NextFile
section_label/2. % Label, SecNr
reset_labels :-
retractall(label(_, _, _)),
retractall(next_file(_, _)),
retractall(section_label(_, _)).
collect_labels([], _) :- !.
collect_labels([tell(File)|T], PreviousFile) :-
!,
( PreviousFile \== File
-> assert(next_file(PreviousFile, File))
; true
),
collect_labels(T, File).
collect_labels([label(Label, _, Tag)|T], File) :-
!,
assert(label(Label, File, Tag)),
collect_labels(T, File).
collect_labels([_|T], File) :-
collect_labels(T, File).
label_tag(_Label, Tag) :-
current_float(_, Tag),
!.
label_tag(Label, Tag) :-
section_tag(Tag),
( sub_atom(Label, 0, _, _, 'sec:')
-> atom_concat('sec:', Tag, SecTag),
assert(section_label(Label, SecTag))
; true
).
/*******************************
* ENVIRONMENTS *
*******************************/
% env(+Env, -HTML)
%
% Translate an environment.
env(pcecode(_, Tokens), #pre(code, HTML)) :-
translate(Tokens, pcecode, HTML).
env(summarylist(_, Summary),
[ html('<table>'),
+Summary,
html('</table>')
]).
env(parameters(_, Paramlist), % Deprecated
[ html('<table class="paramlist">'),
Body,
html('</table>')
]) :-
table_body(Paramlist, [[], []], Body).
env(arguments(_, Arglist),
[ html('<table class="arglist">'),
Body,
html('</table>')
]) :-
table_body(Arglist, [[], []], Body).
env(comment(_, _), []).
env(htmlonly(_, Tokens), HTML) :-
translate(Tokens, normal, HTML).
env(document(_, Contents), HTML) :-
!,
translate(Contents, document, HTML).
env(quote(_, Tokens), #quote(Quote)) :-
translate_group(Tokens, Quote).
env(abstract(_, Tokens), #abstract(Quote)) :-
translate(Tokens, normal, Quote).
env(center(_, Tokens), HTML) :-
phrase(only_table(Table), Tokens),
setup_call_cleanup(
asserta(center_tables, Ref),
translate([Table], normal, HTML),
erase(Ref)).
env(center(_, Tokens), #center(Center)) :-
translate(Tokens, normal, Center).
env(titlepage(_, _Page), []) :-
( quiet
-> true
; format(user_error, 'Ignored the titlepage~n', [])
).
env(tabular([{Format}], Tokens), HTML) :-
translate_table(Format, Tokens, HTML).
env(tabulary([_Width, {Format}], Tokens), HTML) :-
translate_table(Format, Tokens, HTML).
env(array([{Format}], Tokens), HTML) :-
translate_table(Format, Tokens, HTML).
env(table(_, Tokens), Table) :-
step_counter(table, Tab),
asserta(current_float(table, Tab), Ref),
translate(Tokens, normal, Table),
erase(Ref).
env(figure(_, Tokens), Figure) :-
step_counter(figure, Fig),
asserta(current_float(figure, Fig), Ref),
translate(Tokens, normal, Figure),
erase(Ref).
env(minipage(_, Tokens), Page) :-
translate(Tokens, normal, Page).
env(thebibliography(Args, Tokens),
[ SectionHeader,
Open,
HtmlItems,
Close
]) :-
memberchk(\newblock, Tokens),
% writeln(Tokens),
( user_cmd(refname, document, _, Title)
-> true
; Title = ['Bibliography']
),
( documentclass(article)
-> SecLevel = 2,
Number = *
; SecLevel = 1,
Number = -
),
translate_section(SecLevel, Number, Title, SectionHeader,
'Bibliography'),
List = thebibliography,
( list_command(List, Args, Open, Close),
items(Tokens, Items),
translate_items(Items, List, HtmlItems)
-> true
; format(user_error, 'Failed to translate "~w" list~n', [List])
).
env(thebibliography(_Args, _Tokens), []) :- !.
env(Env, [Open, HtmlItems, Close]) :- % General lists
functor(Env, List, _),
tex_environment_function(List, list),
!,
arg(1, Env, Args),
arg(2, Env, Tokens),
( tex_extension_module(M),
M:list_command(List, Args, Open, Close),
items(Tokens, Items),
translate_items(Items, List, HtmlItems)
-> true
; format(user_error, 'Failed to translate "~w" list~n', [List])
).
list_command(description, _, html('<dl class="latex">'), html('</dl>')).
list_command(dlist, _, html('<dl class="latex">'), html('</dl>')).
list_command(itemize, _, html('<ul class="latex">'), html('</ul>')).
list_command(itemlist, _, html('<ul class="latex">'), html('</ul>')).
list_command(shortlist, _, html('<ul class="compact">'), html('</ul>')).
list_command(enumerate, _, html('<ol class="latex">'), html('</ol>')).
list_command(thebibliography, _, html('<dl class="bib">'), html('</dl>')).
% items(+Tokens, -Items)
%
% Translate the item-list of a list-environment into a nested list,
% where each first element is the item command, and the others are
% the tokens of the item.
items([], []).
items([Cmd|More], [[Cmd|ItemTokens]|Items]) :-
functor(Cmd, \, _),
arg(1, Cmd, TexCmd),
tex_command_function(TexCmd, item),
!,
item_commands(More, ItemTokens, Rest),
items(Rest, Items).
items([Token|More], List) :-
( no_item_token(Token)
-> true
; format(user_error, 'Skipped "~w"; no item~n', [Token])
),
items(More, List).
% no_item_token(+Token)
%
% Succeeds if Tokens is a token that may appear before the first
% item of a list, and should not be translated.
no_item_token(' ').
no_item_token('\n').
no_item_token(\par).
no_item_token(\(setlength, _)).
no_item_token(\(newcommand, _)).
item_commands(List, [], List) :-
List = [Cmd|_],
functor(Cmd, \, _),
arg(1, Cmd, TexCmd),
tex_command_function(TexCmd, item),
!.
item_commands([H|T0], [H|T1], T2) :-
item_commands(T0, T1, T2).
item_commands([], [], []).
% translate_items(+ItemTokens, +List, -HTMLTokens)
%
% Translate the TeX tokens for a list-item. List is passed as context,
% to ensure proper translation.
translate_items([], _, []).
translate_items([H0|T0], List, [H1|T1]) :-
translate(H0, List, _, H1),
translate_items(T0, List, T1).