JSON Web Token Library

[fvanzeveren]

Hello Oldes
I just wrapped and "imporved" the code you posted here into a small library to encode and decode JWT.
Thank you for you precious help.

REBOL [
	title: "JSON Web Token Library"
	purpose: "A simple library to encode and decode JSON Web Tokens (JWT) in Rebol."
	file: %jwt.r3
	version: 1.0.0
	date: 25-June-2023
	authors: "Oldes Huhuman & François Vanzeveren"
	history: [
		1.0.0	25-June-2023	"Improved 'jwt-decode to managed token validity"
		0.0.1	24-June-2023	"Created file based on Oldes input."
	]
]

context [
	base64UrlEncode: func[data [string! binary! map!]][
		if map? data [data: to-json data]
		data: enbase/flat/url data 64
		; trim/with data #"=" ;@@ https://github.com/Oldes/Rebol-issues/issues/2548 -- Fixed in 3.11.0
	]
	
	set 'jwt-encode func[
		payload [map! string!]
		secret [string!]
		alg [word!] "One of HS256, HS384, HS512 algorithms."
		/local method header data signature
	][
		header: make map! compose [
			alg: (to-string alg)
			typ: "JWT"
		]
		method: select [
			"HS256" SHA256
			"HS384" SHA384
			"HS512" SHA512
			"none"  'None
		] header/alg
		
		unless method [return to error! "Unsupported signing algorithm."]
		
		data: ajoin [base64UrlEncode header #"." base64UrlEncode payload]
		signature: checksum/with data method :secret
		ajoin [data #"." base64UrlEncode signature]
	]
	
	set 'jwt-decode func[token secret /local header payload signature part method][
		try/with [
			parse token [
				copy header to #"." skip copy payload to #"."
				part: ;; used to limit checksum to be counted only on header and payload
				skip  ;; the dot
				copy signature to end (
					header:  decode 'json debase/url header  64
					payload: decode 'json debase/url payload 64
					signature: debase/url signature 64
				)
			]
			method: select [
				"HS256" SHA256
				"HS384" SHA384
				"HS512" SHA512
				"none"  'None
			] header/alg
		][return to error! "Failed to decode JWT token."]
		
		unless method [return to error! "Unsupported signing algorithm."]
		
		if method = 'None [
			return payload ;; or throw an error!
		]
		
		unless 	equal? signature checksum/part/with token method :part :secret
				[return to error! "Invalid token. Signature does not match the payload."]
		unless any [not payload/exp lesser? now to date! payload/exp]
				[return to error! "Invalid token. The token has expired."]
		unless any [not payload/nbf greater-or-equal? now to date! payload/nbf]
				[return to error! "Invalid token. The start date of validity has not yet been reached."]
		payload
	]
]

[Oldes]

Maybe you could move:

[
	"HS256" SHA256
	"HS384" SHA384
	"HS512" SHA512
	"none"  'None
]

from the functions into the context and in functions have just: method: select methods header/alg