build.gradle

buildscript {
    repositories {
        mavenLocal()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
        maven {
            url = "https://oss.sonatype.org/content/groups/public"
        }
        mavenCentral()
    }
    dependencies {
        classpath "gradle.plugin.org.frege-lang:frege-gradle-plugin:0.5"
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.3"
    }
}

apply plugin: "java"
apply plugin: "maven"
apply plugin: "signing"
apply plugin: "org.frege-lang"
apply plugin: 'io.codearte.nexus-staging'
apply plugin: "application"

mainClassName = "frege.nativegen.Main"

run {
    standardInput = System.in
    standardOutput = System.out

    if (project.hasProperty("options")) {
        String noptions = "-t $rootDir/src/dist/types.properties " + options
        args noptions.split(' ')
    }
}

defaultTasks "build"

sourceCompatibility = 1.7
targetCompatibility = 1.7

ext {
    baseVersion = "1.4"
    isSnapshot = true
    snapshotAppendix = "-SNAPSHOT"
    projectVersion = baseVersion + (isSnapshot ? snapshotAppendix : "")
    fregeVersion = "3.23.450-SNAPSHOT"
    guavaVersion = "18.0"
}

apply from: "$rootDir/gradle/sonatype.gradle"

version = projectVersion
group = groupName
archivesBaseName = project.name

repositories {
    mavenLocal()
    maven {
        url = sonatypeRepositoryUrl
    }
    mavenCentral()
}

compileTestFrege {
    enabled = false
}

dependencies {
    compile "org.frege-lang:frege:$fregeVersion"
    compile "com.google.guava:guava:$guavaVersion"
}

nexusStaging {
    packageGroup = groupName
    stagingProfileId = "a622b6773bea07"
}