-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathflake.nix
242 lines (240 loc) · 7.31 KB
/
flake.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
{
description = "my flkae <3";
inputs = {
nixpkgs.url = "github:nixos/nixpkgs/nixos-24.11";
nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";
nixos-hardware.url = "github:nixos/nixos-hardware";
home-manager = {
url = "github:nix-community/home-manager/release-24.11";
inputs.nixpkgs.follows = "nixpkgs"; # ensures nixpkgs version is consistent between home manager and system
};
nix-darwin = {
# declarative macOS with nix
url = "github:LnL7/nix-darwin";
inputs.nixpkgs.follows = "nixpkgs";
};
lanzaboote = {
# secure boot
url = "github:nix-community/lanzaboote/v0.3.0";
inputs.nixpkgs.follows = "nixpkgs";
};
firefox-addons = {
url = "gitlab:rycee/nur-expressions?dir=pkgs/firefox-addons";
inputs.nixpkgs.follows = "nixpkgs";
};
disko = {
# declarative disks
url = "github:nix-community/disko";
inputs.nixpkgs.follows = "nixpkgs";
};
vscode-server = {
# makes remote servers work
url = "github:nix-community/nixos-vscode-server";
inputs.nixpkgs.follows = "nixpkgs";
};
stylix = {
url = "github:danth/stylix/release-24.11";
inputs.nixpkgs.follows = "nixpkgs";
};
jovian = {
url = "github:Jovian-Experiments/Jovian-NixOS";
inputs.nixpkgs.follows = "nixpkgs-unstable";
};
};
outputs =
{ ... }@inputs:
with inputs;
{
nixosConfigurations =
let
mkHost =
host:
{
modules ? [ ],
home-modules ? [ ],
system ? "x86_64-linux",
specialArgs ? {
inherit inputs;
},
...
}:
nixpkgs.lib.nixosSystem {
system = system;
modules =
modules
++ [
(
{ ... }:
{
networking.hostName = host;
}
)
./mod
home-manager.nixosModules.home-manager
{
home-manager = {
useGlobalPkgs = true;
useUserPackages = false;
extraSpecialArgs = {
inherit inputs;
};
backupFileExtension = "hm-bkp";
users.flame = {
imports =
home-modules
++ [ ./mod-hm ]
++ nixpkgs.lib.optional (builtins.pathExists ./host/${host}/home.nix) ./host/${host}/home.nix;
};
};
}
]
++ nixpkgs.lib.optional (builtins.pathExists ./host/${host}/hardware-configuration.nix) ./host/${host}/hardware-configuration.nix
++ nixpkgs.lib.optional (builtins.pathExists ./host/${host}/configuration.nix) ./host/${host}/configuration.nix;
specialArgs = specialArgs;
};
in
builtins.mapAttrs mkHost {
# make configuration name same as host name to make rebuild command work automagically
# system default is "x86_64-linux"
# modules default to ./mod and ./host/${host}/configuration.nix
# specialArgs defaults to inheriting inputs alone
fnix2 = {
modules = [
./mod/sd-boot.nix
./mod/ui.nix
./mod/hyprland.nix
./mod/nvidia.nix
./mod/remote-builder.nix
./mod/ssh-server.nix
./mod/syncthing.nix
];
home-modules = [
{
flame.hyprland.monitor = [
"Unknown-1, disabled"
"DP-1, highres, 0x0, auto"
"HDMI-A-1, highres, 3200x1440, 1"
];
}
./mod-hm/ui-apps.nix
./mod-hm/rose-pine.nix
];
};
surfnix = {
modules = [
./mod/sd-boot.nix
./mod/ui.nix
./mod/hyprland.nix
./mod/surface.nix
./mod/syncthing.nix
];
home-modules = [
{
flame.hyprland.monitor = [
"eDP-1, preferred, 1920x0, auto"
"DP-1, preferred, 0x0, 1"
];
}
./mod-hm/ui-apps.nix
./mod-hm/rose-pine.nix
];
};
servnix = {
system = "aarch64-linux";
modules = [
./mod/rpi-boot.nix
./mod/ssh-server.nix
./mod/syncthing.nix
{ flame.syncthing.server = true; }
];
};
shaktop = {
modules = [
./mod/sd-boot.nix
./mod/mc-server.nix
./mod/laptop-server.nix
./mod/ssh-server.nix
./mod/unturned.nix
{ flame.ssh-server.openFirewall = true; }
];
};
acervnix = {
modules = [
disko.nixosModules.disko
./host/acervnix/disk-config.nix
./mod/sd-boot.nix
./mod/ssh-server.nix
./mod/laptop-server.nix
];
};
deck = {
modules = [
disko.nixosModules.disko
./host/deck/disk-config.nix
./mod/sd-boot.nix
./mod/jovian.nix
];
};
ephe = {
modules = [
(nixpkgs + "/nixos/modules/installer/cd-dvd/installation-cd-minimal.nix")
./mod/ssh-server.nix
];
};
testy = {
modules = [
./mod/sd-boot.nix
./mod/ui.nix
./mod/plasma.nix
./mod/nvidia.nix
{ flame.ui.minimal = true; }
];
home-modules = [
./mod-hm/ui-apps.nix
./mod-hm/rose-pine.nix
];
};
};
darwinConfigurations =
let
mkDarwin =
host:
{
modules ? [ ],
home-modules ? [ ],
system ? "x86_64-darwin",
specialArgs ? {
inherit inputs;
},
...
}:
nix-darwin.lib.darwinSystem {
modules = modules ++ [
(
{ ... }:
{
networking.hostName = host;
nixpkgs.hostPlatform = system;
}
)
./host/${host}/configuration.nix
home-manager.nixosModules.home-manager
{
home-manager = {
useGlobalPkgs = true;
useUserPackages = true;
extraSpecialArgs = {
inherit inputs;
};
users.flame = {
imports = home-modules ++ [ ./mod-hm ];
};
};
}
];
specialArgs = specialArgs;
};
in
builtins.mapAttrs mkDarwin { bear = { }; };
};
}