settings.gradle

pluginManagement {
    repositories {
        maven {
            def repoPath = file(rootDir.relativePath(file(conclaveRepo)))
            if (repoPath == null) {
                throw new Exception("Make sure the 'conclaveRepo' setting exists in gradle.properties, or your " +
                        "$HOME/gradle.properties file. See https://docs.conclave.net/gradle-properties.html")
            } else if (!new File(repoPath, "com").isDirectory()) {
                throw new GradleException("The $repoPath directory doesn't seem to exist or isn't a Maven " +
                        "repository; it should be the SDK 'repo' subdirectory. See the Conclave tutorial on " +
                        "https://docs.conclave.net")
            }
            url = repoPath
        }
        // Add standard repositories back.
        gradlePluginPortal()
        mavenCentral()
    }

    plugins {
        id 'com.r3.conclave.enclave' version conclaveVersion apply false
    }
}

include 'host', 'client', 'enclave', 'common', 'oracle'

// Each sub-module can be called modulename.gradle, to make IDE navigation and tabs better.
rootProject.children.each { it.buildFileName = "${it.name}.gradle" }

rootProject.name = 'PSSC_With_Conclave'