Look for Formset/Form/Group/Field description format

[WolfgangFahl]

e.g.

PythonWebFrameworks

query

# Python web frameworks
# WF 2024-01-14
# see https://w.wiki/8qJi

SELECT
  (?itemLabel AS ?project)
  (SAMPLE(?homepage) AS ?homepage) # Adding homepage link
  (SAMPLE(?article) AS ?wikipedia) # Adding Wikipedia link
  (?item AS ?wikidata)
  (GROUP_CONCAT(DISTINCT ?instanceOf; separator=", ") AS ?tags) # Tags derived from instanceof
  ?pypi
WHERE {
  # web framework
  ?item wdt:P31/wdt:P279* wd:Q1330336.
  # programmed in Python
  ?item wdt:P277 wd:Q28865.
  ?item rdfs:label ?itemLabel.
  OPTIONAL { ?item wdt:P31 ?instanceOfId. ?instanceOfId rdfs:label ?instanceOf. FILTER(LANG(?instanceOf) = "en") }
  OPTIONAL {
    # official website
    ?item wdt:P856 ?homepage.
  }
  OPTIONAL {
    ?article schema:about ?item.
    ?article schema:inLanguage "en".
    ?article schema:isPartOf <https://en.wikipedia.org/>.
  }
  FILTER(LANG(?itemLabel) = "en")
  OPTIONAL {
    # PyPi Packet
    ?item wdt:P5568 ?pypi
  }

}
GROUP BY ?item ?itemLabel ?pypi
ORDER BY ?project

try it!

result

project	homepage	wikidata	tags	wikipedia	pypi
BlueBream	http://bluebream.zope.org/	http://www.wikidata.org/entity/Q9302930	web framework, free software
Bottle	https://bottlepy.org	http://www.wikidata.org/entity/Q113868826	web framework
CherryPy	https://cherrypy.dev/	http://www.wikidata.org/entity/Q2635182	web framework, free software	https://en.wikipedia.org/wiki/CherryPy
CubicWeb	https://cubicweb.pages.logilab.fr/cubicweb/	http://www.wikidata.org/entity/Q2839592	Semantic Web Framework, free and open-source software	https://en.wikipedia.org/wiki/CubicWeb	cubicweb
DataViva	http://www.dataviva.info	http://www.wikidata.org/entity/Q15614605	open data portal, web framework	https://en.wikipedia.org/wiki/DataViva
Django	https://www.djangoproject.com/	http://www.wikidata.org/entity/Q842014	web framework	https://en.wikipedia.org/wiki/Django_(web_framework)	Django
FastAPI	https://fastapi.tiangolo.com/	http://www.wikidata.org/entity/Q101119404	web framework	https://en.wikipedia.org/wiki/FastAPI	fastapi
Flask	https://flask.palletsprojects.com/	http://www.wikidata.org/entity/Q289281	web framework	https://en.wikipedia.org/wiki/Flask_(web_framework)	Flask
Jam.py	https://jam-py.com/	http://www.wikidata.org/entity/Q97359958	web framework, software	https://en.wikipedia.org/wiki/Jam.py_(web_framework)
JustPy	https://justpy.io/	http://www.wikidata.org/entity/Q124283479	Python library, web framework		justpy
MkDocs	https://www.mkdocs.org/	http://www.wikidata.org/entity/Q102565362	static site generator, free software	https://en.wikipedia.org/wiki/MkDocs	mkdocs
NiceGUI	https://nicegui.io	http://www.wikidata.org/entity/Q123475332	Python library, web framework		nicegui
Pelican	https://blog.getpelican.com/	http://www.wikidata.org/entity/Q28975326	static site generator, free software		pelican
Plone	https://plone.org/	http://www.wikidata.org/entity/Q924422	content management system, web framework, free software	https://en.wikipedia.org/wiki/Plone_(software)
Protogrid	https://www.protogrid.com/bisc/en/000-landing	http://www.wikidata.org/entity/Q20712478	web framework
Pyjs	http://pyjs.org/	http://www.wikidata.org/entity/Q7263063	web framework, widget toolkit, free software	https://en.wikipedia.org/wiki/Pyjs
Pylons	https://pylonsproject.org/about-pylons-framework.html	http://www.wikidata.org/entity/Q18285301	Python library, web framework, free software		Pylons
Pyramid	https://trypyramid.com/	http://www.wikidata.org/entity/Q2342759	Python library, web framework, free software		pyramid
Tornado	http://www.tornadoweb.org/	http://www.wikidata.org/entity/Q1088546	Python library, web framework, free and open-source software, web server	https://en.wikipedia.org/wiki/Tornado_(web_server)	tornado
TurboGears	http://www.turbogears.org/	http://www.wikidata.org/entity/Q937689	web framework, free software	https://en.wikipedia.org/wiki/TurboGears	TurboGears2
Webware for Python	https://cito.github.io/w4py/	http://www.wikidata.org/entity/Q7979004	web framework, free software
repoze.bfg		http://www.wikidata.org/entity/Q55228969	web framework		repoze.bfg
web2py	http://www.web2py.com	http://www.wikidata.org/entity/Q286180	web framework	https://en.wikipedia.org/wiki/Web2py	web2py