maven_local.gradle

subprojects {
    afterEvaluate { project ->
        if (!plugins.hasPlugin('maven-publish')) {
            return
        }
        if (project.parent == rootProject) {
            group = "${rootProject.group}.${project.name}"
        } else {
            group = "${rootProject.group}.${project.parent.name}"
        }
        if (plugins.hasPlugin('com.android.library')) {
            version = android.defaultConfig.versionName
        } else if (plugins.hasPlugin('java-library')) {
            version = POM_VERSION
        } else {
            println("Ignore publish ${project.displayName}")
            return
        }
        println("Process Module:" + "${project.displayName}: ${group}:${project.name}:${version}")
        publishing {
            publications {
                mavenJava(MavenPublication) {
                    group project.group
                    artifactId project.name
                    version version
                    afterEvaluate {
                        if (plugins.hasPlugin('com.android.library')) {
                            from components.release
                        } else if (plugins.hasPlugin('java-library')) {
                            from components.java
                        }
                    }
                }
            }
        }
    }
}