build.gradle

plugins {
    id 'org.jetbrains.kotlin.jvm' version '1.9.0'
    id "org.jetbrains.dokka" version "1.8.20"
    id "org.jmailen.kotlinter" version "3.16.0"
    id "com.github.ben-manes.versions" version "0.47.0"
    id 'jacoco'
}

allprojects {
    kotlin {
        jvmToolchain(17)
    }
}

subprojects {
    apply plugin: 'org.jetbrains.kotlin.jvm'
    apply plugin: 'maven-publish'
    apply plugin: 'signing'
    apply plugin: "org.jetbrains.dokka"
    apply plugin: "org.jmailen.kotlinter"
    apply plugin: 'jacoco'

    repositories {
        mavenLocal()
        mavenCentral()
    }
    group = 'dev.angerm.ag_server'
    version = "1.5.0"

    dependencies {
        implementation platform('org.jetbrains.kotlin:kotlin-bom')
        api 'org.jetbrains.kotlin:kotlin-stdlib-jdk8'

        api 'org.jetbrains.kotlin:kotlin-reflect'
        ['kotlinx-coroutines-core',
         'kotlinx-coroutines-reactor',
         'kotlinx-coroutines-jdk8',
         'kotlinx-coroutines-slf4j',
        ].each {
            api "org.jetbrains.kotlinx:${it}:1.7.3"
        }


        api platform("com.linecorp.armeria:armeria-bom:1.24.3")
        ['armeria',
         'armeria-kotlin',
         'armeria-retrofit2',
         'armeria-rxjava3',
        ].each {
            api "com.linecorp.armeria:${it}"
        }
        api 'io.github.microutils:kotlin-logging-jvm:3.0.5'
        api 'com.uchuhimo:konf:1.1.2'

        ['simpleclient',
         'simpleclient_hotspot',
         'simpleclient_httpserver',
        ].each {
            api "io.prometheus:${it}:0.16.0"
        }

        api "com.google.inject:guice:7.0.0"

        testImplementation 'org.jetbrains.kotlin:kotlin-test'
        testImplementation(platform('org.junit:junit-bom:5.10.0'))
        testImplementation('org.junit.jupiter:junit-jupiter')

        dokkaHtmlPlugin "org.jetbrains.dokka:kotlin-as-java-plugin:1.8.20"
    }

    tasks.withType(JavaCompile) {
        options.compilerArgs += '-parameters'
    }

    tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
        kotlinOptions {
            jvmTarget = "17"
        }
    }

    test {
        useJUnitPlatform()
    }

    java {
        withJavadocJar()
        withSourcesJar()
    }

    publishing {
        repositories {
            maven {
                def releasesRepoUrl = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
                def snapshotsRepoUrl = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
                url = version.endsWith('SNAPSHOT') ? snapshotsRepoUrl : releasesRepoUrl
                credentials {
                    username = ossrhUsername
                    password = ossrhPassword
                }
            }
        }
        publications {
            agLibrary(MavenPublication) {
                from components.java
                pom {
                    name = 'AG Server'
                    description = 'A combination of Armeria+Guice'
                    url = 'https://github.com/AngerM/ag_server'
                    licenses {
                        license {
                            name = 'APACHE LICENSE, VERSION 2.0'
                            url = 'https://github.com/AngerM/ag_server/blob/main/LICENSE'
                        }
                    }
                    developers {
                        developer {
                            id = 'AngerM'
                            name = 'Matt Anger'
                            email = 'matt@angerm.dev'
                        }
                    }
                    scm {
                        connection = 'scm:git:https://github.com/AngerM/ag_server.git'
                        developerConnection = 'scm:git:https://github.com/AngerM/ag_server.git'
                        url = 'https://github.com/AngerM/ag_server'
                    }
                }
            }
        }
    }
    tasks.withType(Sign) {
        onlyIf { isReleaseVersion }
    }

    ext.isReleaseVersion = !version.endsWith("SNAPSHOT")
    signing {
        required { isReleaseVersion && gradle.taskGraph.hasTask("publish") }
        sign configurations.archives
        sign publishing.publications.agLibrary
    }

    jacocoTestReport {
        dependsOn test
        reports {
            xml.required = true
            html.required = false
            xml.destination file("${buildDir}/reports/jacoco/report.xml")
        }
    }

    check.dependsOn jacocoTestReport
}

def isNonStable = { String version ->
  def stableKeyword = ['RELEASE', 'FINAL', 'GA'].any { it -> version.toUpperCase().contains(it) }
  def regex = /^[0-9,.v-]+(-r)?$/
  return !stableKeyword && !(version ==~ regex)
}

tasks.named("dependencyUpdates").configure {
  rejectVersionIf {
    isNonStable(it.candidate.version) && !isNonStable(it.currentVersion)
    }
}

check {
    dependsOn "installKotlinterPrePushHook"
}