build.gradle

plugins {
    id 'java'
    id "com.diffplug.gradle.spotless" version "3.27.0"
}

group 'com.adscore'
version '1.0.0'

sourceCompatibility = 1.8
 
repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    implementation 'com.adscore:adscore-client-libraries:1.0.4'
}

spotless {
    java {
        target fileTree(project.projectDir) {
            include '**/*.java'
            // exclude assertj generated classes
            exclude 'build/generated-src/**/*.*'
        }
        importOrder 'java', 'javax', 'org', 'com', 'co', ''
        removeUnusedImports()

        googleJavaFormat()
    }
}

java {
    withJavadocJar()
    withSourcesJar()
}

javadoc {
    if(JavaVersion.current().isJava9Compatible()) {
        options.addBooleanOption('html5', true)
    }
}

jar {
    manifest {
        attributes 'Main-Class': 'com.adscore.signature.sample.SignatureVerifierSampleMain'
    }
    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}